unir 2 tablas y repetir N veces los regitros

[Vicmon20]

Buen dia,
Reciban un cordial saludo,

EXCEL....
Tengo el siguiente caso;

Tengo 2 Tablas con los siguientes campos...

CVE_Cliente NOM_Cliente
1A Tornillo S.A.
1B La Maquinita
2C El Porvenir
2D El Patito S.A.
3A La Fabrica

CVE_Vendedor NOM_Vendedor
AD Alex Diaz
VM Vic Montes
BM Benito Mendez
JM Jose Montiel
IT Iker Tenor

Lo que requiero realizar es lo siguiente (repertir el cliente tantas veces como vendedores):
CVE_Cliente NOM_Cliente CVE_Vendedor NOM_Vendedor
1A Tornillo S.A. AD Alex Diaz
1A Tornillo S.A. VM Vic Montes
1A Tornillo S.A. BM Benito Mendez
1A Tornillo S.A. JM Jose Montiel
1A Tornillo S.A. IT Iker Tenor

1B La Maquinita AD Alex Diaz
1B La Maquinita VM Vic Montes
1B La Maquinita BM Benito Mendez
1B La Maquinita JM Jose Montiel
1B La Maquinita IT Iker Tenor

Agradeceria sus comentarios, su orientacion, para realizar este proyecto.
Si fueran pocos clientes quizas con copiar, pegar pero tengo una relacion de mas de 600 clientes y no es practico.

¿Cómo podria agregar imagenes para que se pudiera ver mejor lo que necesito?

Gracias, de antemano por su tiempo, y atención

[Vicmon20]

Hola!!
Buenos dias, desde la Cd de México...

¿Cómo puedo agregar un par de imagenes para ilustrar mejor lo que requiero?

GRACIAS!!

[Vicmon20]

Hola, buenos dias...

aun no, he conseguido realizar la tarea...

¿alguna idea?
¿se podria hacer con alguna formular?
¿con algo deVB?

Gracias!

[mrocf]

Iniciado por Vicmon20

¿Cómo puedo agregar un par de imagenes para ilustrar mejor lo que requiero?

Mmmmmmm...
Las imágenes se suben a los Foros de Powerpoint o similares. En los Foros de Excel se muestran archivos de Excel (si quieres que se te comprenda, claro).
________

De todos modos puedes hacer lo siguiente:

a) Click derecho en la solapa de la hoja que contiene las tablas en cuestión.

b) Selecciona: Ver código.

c) En la ventana que se te abrirá, copia y pega el siguiente código:

Código vb:

Sub NuevaTabla()
'------------------
'by Cacho Rodríguez
'------------------
Dim Rng1 As Range, Rng2 As Range, C As Range, D As Range
Dim Mat, Q&
 
On Error Resume Next
Set Rng1 = Application.InputBox("Selecciona la celda que contiene al título: CVE_Cliente", Type:=8)
If Err.Number > 0 Then Exit Sub
Set Rng1 = Range(Rng1.Offset(1), Rng1.End(xlDown))
 
Set Rng2 = Application.InputBox("Selecciona la celda que contiene al título: CVE_Vendedor", Type:=8)
If Err.Number > 0 Then Exit Sub
Set Rng2 = Range(Rng2.Offset(1), Rng2.End(xlDown))
On Error GoTo 0
 
ReDim Mat(1 To Rng1.Count * Rng2.Count, 1 To 4)
 
For Each C In Rng1
  For Each D In Rng2
    Q = 1 + Q
    Mat(Q, 1) = C.Value
    Mat(Q, 2) = C.Offset(, 1).Value
    Mat(Q, 3) = D.Value
    Mat(Q, 4) = D.Offset(, 1).Value
  Next
Next
 
Worksheets.Add.[a1].Resize(Q, 4) = Mat
Erase Mat: Set Rng1 = Nothing: Set Rng2 = Nothing
End Sub
 

d) Cierra las ventanas del ambiente Visual Basic for Application (VBA) en el que te encuentras y retorna al Excel.

e) Ejecuta la macro recién incorporada: NuevaTabla.

f) Al cabo de unos instantes terminarás obteniendo lo solicitado: ¿Lo podrías verificar?...

Saludos, Cacho R.