porque no borra este código?

[niconico]

Tengo un código (no es mío yo simplemente lo he adapatado) con el cual cualquier modificación que haga en la celda a1 o a2 de la hoja 1 se vuelca automáticamente a la celda a1 o a2 de la hoja 2, y viceversa. El problema que tengo es cuando borro las dos celdas a la vez, si borro una sola me la borra también en la otra hoja pero si borro las dos a la vez sólo me borra una, y esa siempre es a1, es como si cuando seleccionas las dos celdas y las borras no leyera el segundo if.
hoja1:

Código:

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Row = 1 And Target.Column = 1 Then
    Hoja2.Range("A1") = Range("A1")
End If
If Target.Row = 2 And Target.Column = 1 Then
    Hoja2.Range("A2") = Range("A2")
End If
End Sub

hoja2

Código:

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Row = 1 And Target.Column = 1 Then
    Hoja1.Range("A1") = Range("A1")
End If
If Target.Row = 2 And Target.Column = 1 Then
    Hoja1.Range("A2") = Range("A2")
End If
End Sub

muchas gracias

[potypoty]

No es que no lea el segundo if, sino que el código que tienes se basa en la primera celda seleccionada que cumpla esas condiciones, en este caso A1. Bueno, yo he llegado a esa conclusión con los programas que he hecho y con pruebas con el tuyo. Es decir. tú cambias la celda A1 y el target se queda con 1 1. Aunque selecciones varias a la vez el encuentra la primera que cumple (A1) y ejecuta el código, que como es que cuando una celda cambie, sólo se ejecutará una vez y por ello, nunca cambiará la segunda. Tendrás que hacerte otra macro si quieres conseguir borrar todas a la vez.
Voy ha echar un vistazo por ahí haber si se me ocurre algo para mejorarlo.
Un saludo.

[niconico]

muchas gracias espero que me puedas ayudar

[niconico]

La solución me la ha dado KL,
hoja1

Código:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rng As Range
    On Error Resume Next
    Set rng = Intersect(Target, [A1:A10])
    On Error GoTo 0
    If rng Is Nothing Then Exit Sub
    Application.EnableEvents = False
    Hoja2.Range(rng.Address).Value = rng.Value
    Application.EnableEvents = True
End Sub

hoja2

Código:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rng As Range
    On Error Resume Next
    Set rng = Intersect(Target, [A1:A10])
    On Error GoTo 0
    If rng Is Nothing Then Exit Sub
    Application.EnableEvents = False
    Hoja1.Range(rng.Address).Value = rng.Value
    Application.EnableEvents = True
End Sub