Excel con vbasic

[daviky]

necesito saber como capturar el numero de fila en el que se encuentra el cursor.
tengo un problema con una macro, estoy haciendo una busqueda de celdas que contengan el numero 2 por dar un ejemplo, y colocarlas a un lado cada una de estas celdas.
En esta macro doy un rango de a1 a a10 y busco el valor 2 todo va bien pero si el numero 2 se repite, la macro termina y es que comparo el valor inicial de la busqueda con cada busqueda siguiente y si son iguales termina, funciona si dentro de mi rango no hay dos veces el numero 2. Me parece que si pudiera saber cual es el numero de fila de la primera celda que encuentra podria validarlo y hacer que termine si vuelve a pasar por esta fila pero no encuentro como capturar el numero de fila activo en una variable.

Les dejo mi macro para ver si alguien puede ayudar. En la hoja 1 escriban los siguientes numeros desde la fila 1 hasta la fila 10: "5, 32, 25, 15, 2, 1, 8, 26, 9, 4". En la celda "H2" y "H3" escriban cualquier cosa para que funcione la referencia relativa al momento de hacer la copia. Como verán funciona, ha copiado "32,25,2,26", ahora cambien el valor 15 por 32, no funciona, solo copia 32 y 25.

Ojala puedan ayudarme con este problemita, gracias.


' defino el objeto c para q almacene la coincidencia
Set c = Hoja1.Range("a1:a10").Find(2, LookIn:=xlValues)
' si no hay coincidencia no hace nada
If c Is Nothing Then

Else
'guardo el primer valor de la coincidencia
aux = c.Value
'entra en loop para hacer las copias
Do
c.Select
Selection.Copy
Range("H2").Select
Selection.End(xlDown).Select
ActiveCell.Offset(1, 0).Range("A1").Select
ActiveSheet.Paste
Application.CutCopyMode = False

'entraga el nuevo valor encontrado a c
Set c = Hoja1.Range("a1:a10").FindNext(c)

'compara si este nuevo valor es la primera coincidencia
If aux = c.Value Then
Exit Do
End If
Loop
End If

[Monimo]

Mm yo lo que haría sería mas bien recorrer celda por celda, en lugar de hacer un find.

pero si te sirve:

Activecell.row te da el numero del renglon de la celda activa

[Monimo]

Activecell.row

[David]

Hola, daviky.

Traslado el tema a una sección donde encaja mejor.
Tema trasladado desde la sección de Ayuda General.

Saludos.

[mrocf]

Hola! daviky.
Tu código está más que bien concebido pues es lo ideal para cuando se tienen decenas de miles de datos en la columna A.

Tu error es "mínimo". En efecto:

En lugar de:
aux = c.Value

debe ser:
aux = c.Address

Y en lugar de:
If aux = c.Value Then

debe ser:
If aux = c.Address Then

O sea: en lugar de terminar el código ante una repetición del valor, lo debes terminar ante una repetición de la referencia de la celda inicial.

Te muestro -entonces- una posible depuración, aunque el código que has elaborado resulta operativo con aquellas pequeñas correcciones:

Código vb:

Dim C As Range, Aux As String
' defino el objeto c para q almacene la coincidencia
Set C = Hoja1.Range("a1:a10").Find(2, LookIn:=xlValues, LookAt:=xlPart)
' si no hay coincidencia no hace nada
If C Is Nothing Then
  Exit Sub
End If
'guardo el primer valor de la coincidencia
Aux = C.Address
'entra en loop para hacer las copias
 
Do
  C.Copy [H2].End(xlDown).Offset(1)
' entrega el nuevo valor encontrado a c
  Set C = Hoja1.Range("a1:a10").FindNext(C)
Loop Until Aux = C.Address
 

Saludos, Cacho.