consulta sobre lista en excel

[julita_punch]

hola amigos
tengo una lista de nombres de mi agenda en excel asi:
1. María
2. Julia
3. Bertha
4. Paula
5. Petra

hay alguna opcion que me permita convertir esa lista de mi agenda a esto:

María; Julia; Bertha; Paula; Petra

Gracias

[3pies]

Si sabes hacer macros, puedes utilizar algo como esto:

Código:

Sub unir_correos()
'nos situamos en la 1ª celda con datos
Range("A1").Select
'hasta que no encuentre una celda vacía...
Do While Not IsEmpty(ActiveCell)
    'que vaya añadiendo lo que encuentre, a una variable,
    'y separaremos cada dato con un punto y coma
    emails = emails & ";" & ActiveCell
    'bajamos una fila
    ActiveCell.Offset(1, 0).Select
'seguimos con el bucle
Loop
'Hacemos un arreglo, pues al principio, delante
'de la primera cuenta de correo, nos saldrá una coma
emails = Mid(emails, 2)
'escribimos el dato que necesitamos en la
'celda de abajo
ActiveCell = emails
End Sub

De nada

[jlsoutoz]

3Pies!!

exelente script y muy bien explicado!!!

Felicidades

[caesar.l]

Concuerdo con jlsoutoz esta de lujo esa macro

[3pies]

Ese macro lo uso yo, para enviar un boletín de novedades a mis usuarios. Como intuyo que julita_punch lo quiere para emailearse con sus contactos, por eso le puse el nombre de unir_correos()

Es que sino, no entiendo para que quiere unir los nombres con un punto y coma ;)

[julita_punch]

Iniciado por 3pies

Ese macro lo uso yo, para enviar un boletín de novedades a mis usuarios. Como intuyo que julita_punch lo quiere para emailearse con sus contactos, por eso le puse el nombre de unir_correos()

Es que sino, no entiendo para que quiere unir los nombres con un punto y coma ;)

Hola 3pies
asi es
lo quiero para mandar correos a mis amigos de un solo tiro
y ahora ya estoy buscando info sobre macros

gracias por el dato

por cierto y si un nombre de correo lo vuelvo a repetir pero con otro nombre distinto de la persona dueña
como haria para evitarlo

gracias ¡¡¡¡

[3pies]

Si se supone que los emails no los tendrás repetidos, pero es probable que sí tengas alguno de los nombres, ¿qué sentido tiene separar con puntos y comas los nombres, si no nos sirve para nada?.

Cuando envías un email, lo harás a una serie de direcciones de correo, no a unos nombres (ojo, estamos hablando de coger datos de excel, para pegarlos en Outlook, no estamos hablando de coger la libreta de direcciones de outlook, y seleccionar allí los nombres, que eso es distinto). No sé si me he explicado...

[julita_punch]

mmmm
es que existe la posibilidad de que repita el mismo correo
como haria para que esto no pase?
o si pasase como haria para depurar?

porque cuando pasaba eso lo ordenaba en orden alfabetico y revisaba la lista y simplemente eliminaba los repetidos

pero me gustaria aprender la forma correcta

gracias

[julita_punch]

aprendi a hacer lo de macro ¡¡¡¡
gracias 3 pies

gracias a tu aporte mas este enlace

gracias '''¡¡¡

[julita_punch]

amiguitos
existe la posibilidad de que se anule un nombre propio o un nombre de correo repetido en una lista?
es decir

1. María
2. Julia
3. Bertha
4. Paula
5. Petra
6. Julia
Julia

como haria para que esto no pase?
o si pasase como haria para depurar?

porque cuando pasaba eso lo ordenaba en orden alfabetico y revisaba la lista y simplemente eliminaba los repetidos

pero me gustaria aprender la forma correcta

gracias

[3pies]

Supongo que en tu ejemplo, quieres controlar cuentas de correo electrónico duplicadas, y no nombres duplicados, porque puedes tener 2 o más usuarios con el mismo nombre y ser personas diferentes (email diferentes, por tanto).

Échale un vistazo a este tema: http://www.forosdelweb.com/f90/encon...-excel-730932/

[mrocf]

Hola!
La propuesta del amigo "3pies" es útil cuando se desea "armar" una lista de correo con datos consecutivos: desde una cierta celda hasta el final de la lista.

Pero imaginemos que lo que se desea es mandar un correo a las siete direcciones ubicadas en E3, E5:E7, E12, E18 y E31...

Para esta instancia lo que haríamos es seleccionar esas celdas (asumo que todos sabemos seleccionar celdas no contiguas) y aplicar algo así:

Código PHP:

  Option Explicit
Dim c As Range

Sub Mailing()
Dim MailingList() As String, i As Byte
ReDim MailingList(1 To eAddresses(Selection))
For Each c In Selection
  i = i + 1
  MailingList(i) = c
Next c
InputBox "Direcciones de correo seleccionadas:", "Mailing", Join(MailingList, "; ")
End Sub

Function eAddresses(r As Range) As Byte
For Each c In r.Areas
  eAddresses = eAddresses + c.Rows.Count
Next c
End Function 
   

El procedimiento termina ofreciéndonos un cuadro con las direcciones ya listas para copiarlas y pegarlas en el programa de correo.

Saludos, Cacho.

[3pies]

Iniciado por julita_punch

aprendi a hacer lo de macro ¡¡¡¡
gracias 3 pies

gracias a tu aporte mas este enlace

gracias '''¡¡¡

Ese enlace es de mi blog de excel

[julita_punch]

hola 3pies
lo sospechaba porque vi el enlace de trucos de cocina
muy bueno el tuto ¡¡¡

pero asi como con el macro pude convertir mi lista de excel
1. [email protected]
2. [email protected]
3. [email protected]
4. [email protected]
5. [email protected]

a esto
[email protected]; [email protected]; [email protected]; [email protected]; [email protected]


como le haria si de word pego a excel
[email protected], [email protected], [email protected], [email protected], [email protected]

y quiero convertirlo a una lista normal
1. [email protected]
2. [email protected]
3. [email protected]
4. [email protected]
5. [email protected]

gracias

[mrocf]

Una opción para pasar de
[email protected], [email protected], [email protected], [email protected], [email protected]

a
[email protected]
[email protected]
[email protected]
[email protected]
[email protected]

es el siguiente código:

Código PHP:

  Sub DeTextoA_Lista()
Dim Ce1 As Range, Ce2 As Range, MyLst As Variant, i As Byte
On Error Resume Next
 
Rem Ce1 es asociado a la celda seleccionada
Set Ce1 = Application.InputBox("Seleccione la celda en la que se encuentra " & _
  "el texto a procesar", Type:=8)
If Ce1 Is Nothing Then Exit Sub
 
Rem Ce2 es asociado a la celda seleccionada
Set Ce2 = Application.InputBox("Seleccione la celda a partir de la cual " & _
  "desea colocar la lista", Type:=8)
If Ce2 Is Nothing Then Exit Sub
On Error GoTo 0
 
Rem Asigno al variant MyLst las direcciones de correo.
Rem MyLst será un vector debido a la función Split
Rem WorksheetFunction.Substitute elimina los inter-espacios
Rem Split es la base principal de este código
MyLst = Split(WorksheetFunction.Substitute(Ce1, " ", ""), ",")
 
Rem Paso las componentes de MyLst a las celdas de la hoja
Rem LBound brinda el menor subíndice del vector MyLst
Rem UBound brinda el mayor sub índice del vector MyLst
For i = LBound(MyLst) To UBound(MyLst)
  Ce2.Offset(i - LBound(MyLst)) = MyLst(i)
Next i
 
Rem Interrumpo las asociaciones de las variables de objeto Ce1 y Ce2
Set Ce1 = Nothing
Set Ce2 = Nothing
End Sub 
   

Saludos, Cacho.

[julita_punch]

muchas gracias mrocf
me salio perfecto ¡¡¡¡

y
si pegase de word a excel

[email protected]
[email protected]
[email protected]
[email protected]
[email protected]
[email protected]

hay algun macro que de la lista que pegue de word a excel
me permita ver el resultado asi como lo muestro?

o sea
toda la lista esta en negro
la lista la ordeno alfabeticamente con el excel
y los correos repetidos (o los nombres, segun el caso) me lo muestre de otro color para ver dicha repeticion?


gracias

[mrocf]

Una opción podría ser:

Código PHP:

  Sub DistingueEmailRepetidos()
Rem Seleccionar alguna celda del conjunto de direcciones de correo
Rem a controlar.
Rem Luego de ello: ejecutar la presente macro.
Dim Tmp As String, MyForm As String
With Intersect(ActiveCell.CurrentRegion, ActiveCell.EntireColumn)
  .FormatConditions.Delete: Tmp = .Cells(1)
  .Cells(1).Formula = "= COUNTIF(" & .Address & ", " & _
    ActiveCell.Address(False, False) & ") > 1"
  MyForm = .Cells(1).FormulaLocal: .Cells(1) = Tmp
  .FormatConditions.Add Type:=xlExpression, Formula1:=MyForm
  .FormatConditions(1).Font.Bold = True
  .FormatConditions(1).Interior.ColorIndex = 22
End With
End Sub 
   

Saludos, Cacho.

[julita_punch]

muchas gracias amiguito ¡¡¡¡

[mrocf]

Fue un gusto ayudarte.