Como concatener datos de una columna en archivo excel que se repite

[CURIBER]

buenos dias amigos tengo el siguiente problema :
tengo una archivo excel que contiene mas de 3500 datos en una columna (columna A) pero de esos datos la gran mayoria se repiten N cantidad de veces por lo tanto la cantidad real de datos es 1250 aprox y cada dato de la columna A tiene asociado otro dato que esta en la columna C.... ahora bien que es lo que necesito hacer.... es dejar en una hoja nueva los datos de la columna A (sin repetir) asociados a los datos de la columna C, pero todos (concatenados)

para ver si me explico mejor les dejo este ejemplo
ESTE ES EL ARCHIVO QUE TENGO

_____A___________B____________C____
1 | X | ZZ
2 | X | XX
3 | X | QQ
4 | X | ÑÑ
5 | X | YY
1 | X | RR
1 | X | TT
3 | X | WW
2 | X | SS
5 | X | FF
2 | X | GG
1 | X | HH
3 | X | JJ
4 | X | KK
5 | X | MM


NECESITO QUEDE DE ESTA FORMA

_____A__________B_____________C____
1 | X | ZZ;RR;TT;HH
2 | X | XX;SS;GG
3 | X | QQ;WW;JJ
4 | X | ÑÑ;KK
5 | X | YY;FF;MM



PORFAVOR ME DEJEN SIN RESPUESTA

PD: LA SOLUCION QUE ENCONTRE ES MEDIANTE UNA TABLA DINAMICA PERO COMO DEBO UTILIZAR LOS DATOS NO ME AYUDA DE MUCHO


GRACIAS POR SU VALIOSA AYUDA

[mrocf]

Hola! CURIBER. Sigue los siguientes pasos:

a) Haz click derecho en la solapa de la hoja en la que deseas el efecto y selecciona: Ver código;

b) En la ventana que se te abrirá, copia y pega lo siguiente:

Código PHP:

  Sub Concatenar()
Dim Mat1, Vec1, Mat2
Dim Rng As Range, i As Long, j As Long, TC As Long, Q As Long
 
On Error Resume Next
Set Rng = Application.InputBox("Selecciona el rango a procesar" & vbLf & "(por ejemplo: B2:D17)", "Resumen por concatenación", Type:=8)
If Rng Is Nothing Then Exit Sub
 
Mat1 = Rng
Q = UBound(Mat1, 1)
ReDim Vec1(1 To Q, 1 To 1)
ReDim Mat2(1 To Q, 1 To 2)
 
For i = 1 To Q
  j = WorksheetFunction.Match(Mat1(i, 1), Vec1, 0)
  If Err.Number > 0 Then
    Err.Clear
    TC = 1 + TC: j = TC
    Vec1(j, 1) = Mat1(i, 1)
    Mat2(j, 1) = Mat1(i, 2)
  End If
  Mat2(j, 2) = IIf(Mat2(j, 2) = Empty, "", Mat2(j, 2) & ";") & Mat1(i, 3)
Next i
 
On Error GoTo 0
With Rng.Parent.Cells(Rng(1).Row, Rng(1).Column + 10)
  .Offset(, 1).Resize(100 + Q, 3).Delete
  .Offset(, 1).Resize(TC) = Vec1
  .Offset(, 2).Resize(TC, 2) = Mat2
  .Offset(, 1).CurrentRegion.Sort Key1:=.Offset(, 1), Order1:=xlAscending, Header:=False
  .Offset(, 1).Resize(Q, 3).Columns.AutoFit
  Application.Goto .Offset(, -2), True
End With
End Sub 
   

c) Cierra esa ventana del ambiente Visual Basic for Application en el que te encuentras, y retorna al Excel.

d) Ejecuta la macro recién incorporada: Concatenar.

e) La macro te solicita que selecciones el rango de tres columnas con los datos a procesar. Al cabo de unos instantes: ¡obtendrás lo pedido!

¿Te sirve la idea?...
Saludos, Cacho R.

[CURIBER]

estimado no se si me exprese mal (lo mas probable...)
al ejecutar la rutina el resultado es el siguiente
deja como 5 columnas en blanco y luego ordena de manor a mayor el listado con su respectivo dato en la columna siguiente.
y lo que necesito es el dato de la columna a que se registre una sola vez y en la columna siguiente concatenados todos los datos que tengan relacion al dato de la columna a

ESTE ES EL ARCHIVO QUE TENGO

A | B | C
1 | X | ZZ
2 | X | XX
3 | X | QQ
4 | X | ÑÑ
5 | X | YY
1 | X | RR
1 | X | TT
3 | X | WW
2 | X | SS
5 | X | FF
2 | X | GG
1 | X | HH
3 | X | JJ
4 | X | KK
5 | X | MM

este es el resultado que me entrega al correr la rutina que me indicas

A | B | C
1 | X | ZZ
1 | X | RR
1 | X | TT
1 | X | HH
2 | X | XX
2 | X | SS
2 | X | GG
3 | X | QQ
3 | X | WW
3 | X | JJ
4 | X | ÑÑ
4 | X | KK
5 | X | YY
5 | X | FF
5 | X | MM

este es el resultado que busco (el separador no necesariamente debe ser ; perfectamente puede ser otro)

A | B | C
1 | X | ZZ;RR;TT;HH
2 | X | XX;SS;GG
3 | X | QQ;WW;JJ
4 | X | ÑÑ;KK
5 | X | YY;FF;MM


este listado me serviria si fueran pocos los datos pero tal como lo indique en la pregunta la planilla tiene aprox 3500 datos en la columna A repetidos N cantidad de veces lo que da como resultado real que el listado real de datos de la columna A es de 1300 datos aprox.


agradesco tu interes y ojala puedas ayudarme con este "problemita" que hasta hoy estoy generando manualmente con la demora que tu te puedes imaginar(no he terminado ni la 1/4 parte de la cartera aun

[mrocf]

Hola! CURIBER.
La macro está "recontra" probada y hace lo que necesitas.

Por lo tanto sólo me resta imaginar que has tenido problemas en la implementación del código.

Para analizar lo que has hecho: sube tu archivo a un servidor y publica su enlace. La idea será mirarlo y descubrir que es lo que te ha faltado o te ha "sobrado" (jajajaja).

Saludos, Cacho R.

[CURIBER]

estimado y GRAN GURU Y MAESTRO ... efectivamente era yo el equivocado agradesco tu ENORME Y VALIOSA AYUDA...

DE VERDAD NO SBES CUANTO ME AYUDASTE



MIL PERO MIL GRACIAS