buscar con marcro en excel

[pablobaez]

hola tengo un codigo que busca un campo atravez de un input

Código:

Sub BUSCAR_PRODUCTO()
On Error Resume Next

palabra_a_buscar = LCase(InputBox("Palabra (o parte de la palabra) a buscar", "Pregunta"))
If palabra_a_buscar = "" Then
MsgBox "Ingresar Datos", vbCritical
Else
Range("A2").Select
Do While Not IsEmpty(ActiveCell)
    If InStr(LCase(ActiveCell), palabra_a_buscar) > 0 Then
        celda = ActiveCell.Address
        Range("h3").Select
        Do While Not IsEmpty(ActiveCell)
            ActiveCell.Offset(1, 0).Select
        Loop
        ActiveCell = Range(celda).Offset(0, 2)
        Range(celda).Select
    End If
    ActiveCell.Offset(1, 0).Select
Loop
mensaje = MsgBox("Búsqueda finalizada", vbOKOnly, "Final")
End If
Range("H2").Activate
End Sub

pero no se como hacer para que me busque mas campo del registro

[Monimo]

es decir quieres varios inputs del mismo registro?

[pablobaez]

no, es como el metodo buscar , pero en macro, este codigo me trae una colunma yo quiero mas de una colunma como resultado

[mrocf]

Hola! Pablo.
La macro que muestras busca a lo largo de la columna A (a partir de la celda A2) el contenido de lo ingresado en el InputBox.

Una vez encontrado el texto, traslada el correspondiente valor de la columna C, a una lista que armas en la columna H, y a partir de la celda H3.

De modo que te falta comentar:

a) ¿Que otras celdas deseas copiar, además de la C?; y
b) ¿Donde deseas que sean copiadas? ¿A la derecha de H?

Saludos, Cacho.

[pablobaez]

si yo modifico esta sentecia

Código:

ActiveCell = Range(celda).Offset(0, 2)

a
ActiveCell = Range(celda).Offset(0, 3)

puedo obtener otro campo del registro, el tema es que que no puedo mostrar mas de dos campo a la vez yo creo que tengo que hacer una especie de arreglo he ir sumando estas opciones pero no se como

gracias por constestar

[mrocf]

Hola! Pablo.
Es una lástima que no hayas respondido a ninguna de mis dos preguntas.

De modo que voy a mostrarte la siguiente variante:

Código:

Sub BUSCAR_PRODUCTO()
Dim palabra_a_buscar As String, colH As Range, LR As Long, C As Range

palabra_a_buscar = InputBox("Palabra (o parte de la palabra) a buscar", "Pregunta")
If palabra_a_buscar = "" Then
  MsgBox "Ingresar Datos", vbCritical: Exit Sub
End If

Application.ScreenUpdating = False
Set colH = [H3]: Set C = [a2]
If Not IsEmpty(colH) Then Set colH = Range("H" & Rows.Count).End(xlUp).Offset(1)
LR = Range("A" & Rows.Count).End(xlUp).Row

Do Until C Is Nothing
If C.Row > LR Then Exit Do

If InStr(C, palabra_a_buscar) = 0 Then _
  Set C = Range(C, "A" & LR).Find(What:=palabra_a_buscar, _
  LookIn:=xlValues, LookAt:=xlPart, SearchDirection:=xlNext)
 
If Not C Is Nothing Then
  Union(Cells(C.Row, "C"), Cells(C.Row, "E")).Copy colH
  Set colH = colH.Offset(1)
End If
Set C = C.Offset(1)
Loop

Application.ScreenUpdating = True
MsgBox "Búsqueda finalizada", vbOKOnly, "Final"
End Sub

Como observarás: este código es mucho más eficiente que el que mostraras puesto que no requiere recorrer -una a una- las celdas de la columna A.

Por otro lado y mediante:
Cells(C.Row, "C")
Cells(C.Row, "E")
estoy copiando el contenido de las columnas "C" y "E".

Entonces advertirás que es muy sencillo incorporar o quitar columnas.
Saludos, Cacho.

[pablobaez]

super ,, muchas gracias,, era lo que andaba buscado y disculpa si no respodi bien tus preguntas

gracias

[mrocf]

¡¡Me alegra que te haya sido de utilidad!!

Y con referencia a la falta de respuestas te comento: cuando ello ocurre, uno debe "imaginar" aquello que debió ser respondido.

Y como lo imaginado -eventualmente- podría no ajustarse a la realidad, entonces uno termina perdiendo el tiempo al sugerir algo no aplicable, mientras que quien pregunta termina sin una sugerencia adecuada... ¿Se entiende?

Saludos y hasta la próxima.
Cacho.