Ayuda con Excel

[sebax2303]

Buenas tardes amigos, espero que puedan darme una mano.
Tengo un excel con 20975 filas, lo que son algo asi como 420 hojas impresas, necesito que esa fila enorme, se vaya distribuyendo por hoja. No se si me explico

por ejemplo:
ahora tengo asi:
1
2
3
4
5
...
2975

Lo que necesito es que por ejemplo que en una hoja me haga 4 columnas con esos numeros, ordenados de menor a mayor y lo haga asi:

hoja 1

Código:

1       7        13    19 
2       8        14     20
3       9        15     21
4       10      16     22
5       11      17     23
6       12      18     24

hoja 2

Código:

25     31    37     43
26     32    38     44
27     33    39     45
28     34    40     46
29     35    41     47
30     36    42     48

y asi hasta el final..

espero que no sea imposible..algun macro debe existir o algo..

espero haber sido claro, xq no se bien como explicar esto que me pidieron..

desde ya muchas gracias

[SidV]

Seba, usa el grabador de Macros para 2 paginas...
Y despues replicalo editando el codigo VBA que se genera para dicho macro. :)

Saludos

[mrocf]

Hola! seba.
Incorpora la siguiente macro:

Código vb:

Sub Re_Ordenar()
Dim ii As Long, jj As Integer
 
'Define el número de filas por columna
Const FpC As Integer = 6
 
Application.ScreenUpdating = False
[b:g].Delete Shift:=xlToLeft
ActiveSheet.ResetAllPageBreaks
 
'Copia la hoja activa y trabaja sobre esta copia
ActiveSheet.Copy After:=Sheets(1)
 
For ii = 1 To [a1].End(xlDown).Row Step 4 * FpC
  For jj = 1 To 7 Step 2
    Cells(ii + FpC * (jj - 1) / 2, 1).Resize(FpC, 1).Cut Cells((ii + 3) / 4, jj)
  Next jj
Next ii
 
For ii = FpC To [a65536].End(xlUp).Row - 1 Step FpC
  ActiveSheet.HPageBreaks.Add Before:=Cells(ii + 1, 1)
Next ii
 
Rows([a65536].End(xlUp).Offset(1).Row & ":65536").Delete Shift:=xlUp
Application.ScreenUpdating = True
End Sub
 

Tres cosas importantes:

a) Estoy suponiendo que tus datos están en la columna "A" comenzando desde la celda [A1].

b) La línea:
Const FpC As Integer = 6

define "6" filas por columna al igual que has mostrado en tu ejemplo.
Si quieres modificar este dato a otra cantidad, simplemente cambias ese número.

c) A los efectos de reiterar el procedimiento tantas veces como lo requieras, hago una copia de la hoja en cuestión y trabajo sobre ella.

Saludos, Cacho.