Access: Restringir acceso con contraseña

[elnavegante]

Hola estimados me encuentro creando una base de datos en access y buscando en internet encontre la forma de autorizar el acceso mediante contraseñas y nombres de usuarios, lo que necesitaria es deshabilitar la opción alt+abrir para poder ver todo el contenido de la base de datos o sea que no la puedan modificar más. Esto es posible desde ya muchas gracias! una abrazo

[Taribo007]

Aqui tienes dos funciones para habilitar/desabilitar esa opcion:

'************************************************* ********************
Option Compare Database
Option Explicit
Function ap_DisableShift()

On Error GoTo errDisableShift

Dim db As Database
Dim prop As Property
Const conPropNotFound = 3270

Set db = CurrentDb()

db.Properties("AllowByPassKey") = False

Exit Function

errDisableShift:

If Err = conPropNotFound Then
Set prop = db.CreateProperty("AllowByPassKey", _
dbBoolean, False)
db.Properties.Append prop
Resume Next
Else
MsgBox Err.Number & " / " & Err.Description, vbInformation + vbOKOnly, "A V I S O"
Exit Function
End If

End Function
'================================================= ===========
Function ap_EnableShift()

On Error GoTo errEnableShift

Dim db As Database
Dim prop As Property
Const conPropNotFound = 3270

Set db = CurrentDb()
db.Properties("AllowByPassKey") = True

Exit Function

errEnableShift:

If Err = conPropNotFound Then
Set prop = db.CreateProperty("AllowByPassKey", _
dbBoolean, True)
db.Properties.Append prop
Resume Next
Else
MsgBox Err.Number & " / " & Err.Description, vbInformation + vbOKOnly, "A V I S O"
Exit Function
End If

End Function
'************************************************* **********************

Y aqui un ejemplo:

http://accessbuho.mvps.org/ficheros/quitaponshift.zip

Un saludo

[elnavegante]

Gracias por tu rápida respuesta, me encuentro muy agradecido! Me solucionaste un gran problema, mil gracias y un fuerte abrazo!