Procedimiento almacenado

[ruben_zer0]

Hola a todos, ojala me pudieran ayudar con esto:
tengo el siguiente Store Procedure:

ALTER PROCEDURE sp_prueba
@ids nvarchar(1000)
as
declare @nombres nvarchar(1000)
set @nombres=''
select @nombres= @nombres + nombre + ',' from Cliente where cast(id_cliente as nvarchar) in (@ids)
select @nombres
------------------------------------------------------------------------------------------------------
ahora para ejecutarlo lo siguente:

exec sp_prueba '''1'',''2''' ó exec sp_prueba '1,2'

y no me trae ningun registro...
y si solo le mando un valor en el parametro:
exec sp_prueba '1'

si me arroja registros de resultado
alguien podria ayudarme, muchas gracias

[Andres95]

porque supongo que no tienes clientes cuyo id sea = '1,2'



en realidad sql no lo toma como una lista sino como una variable con ese valor, por lo que tienes que convertirlo explicitamente a una tabla. Mas o menos seria asi:

Código:

ALTER PROCEDURE SP_PRUEBA
@IDS NVARCHAR(1000)
AS
DECLARE @NOMBRES NVARCHAR(1000)

SET @NOMBRES=''

DECLARE @CLIENT_IDS TABLE (CLIENTEID INT)

WHILE PATINDEX('%,%',@IDS)>0
BEGIN
	INSERT INTO @CLIENT_IDS (CLIENTEID) 
    VALUES (ISNULL(LEFT(@IDS,PATINDEX('%,%',@IDS)-1),0))

	SET @IDS = RIGHT(@IDS,LEN(@IDS)-PATINDEX('%,%',@IDS))
END

INSERT INTO @CLIENT_IDS(CLIENTEID) 
VALUES (ISNULL(@IDS,0))

SELECT @NOMBRES = @NOMBRES + NOMBRE + ',' 
FROM   @CLIENT_IDS I
INNER JOIN
      CLIENTE  C
ON    I.CLIENTEID = C.ID_CLIENTE

SELECT @NOMBRES

GO

Saludos!

[flaviovich]

Para no splitear el parámetro, no sería mejor que trabaje la consulta dinámicamente?

Código SQL:

SET @SQL = 'declare @nombres varchar(1000)
select @nombres= @nombres + nombre + '',''
from Cliente
where id_cliente in (' + @ids + ')
select @nombres'
EXEC sp_executesql @SQL
 

ruben_zer0, por qué usas nvarchar y no vachar?

[Andres95]

si, es otra opcion...




en lo personal, prefiero evitar lo mas posible el sql dinamico..



Saludos!

[Andres95]

otra alternativa (para el que le pueda servir) es hacerlo con XML...(si tienes version 2000)

Código:

EXECUTE DBO.SP_PRUEBA @Id_XML = '<r><CUST id = "1" /><CUST id = "2" /></r>'


ALTER PROCEDURE SP_PRUEBA
    @Id_XML NVARCHAR(4000)
AS
DECLARE @NOMBRES NVARCHAR(1000)
DECLARE @idoc INT


----------------------------------------------------------
EXECUTE sp_xml_preparedocument @idoc OUTPUT, @Id_XML  
----------------------------------------------------------

SET @NOMBRES=''

SELECT       @NOMBRES = @NOMBRES + NOMBRE + ',' 
FROM         OPENXML (@idoc, '/r/CUST',1)  WITH ([ID_CLIENTE] INT '@id') AS I
INNER JOIN  CLIENTE C  
ON          I.ID_CLIENTE = C.ID_CLIENTE


----------------------------------------------------------
EXEC sp_xml_removedocument @idoc  
----------------------------------------------------------

SELECT @NOMBRES

GO

Saludos!

[ruben_zer0]

Gracias a todos por sus respuestas, realmente estoy haciendo un query dinamico y le anexe lo que puso andes95, cortando la cadena y guardando en una tabla temporal.
Gracias y saludos!

[ruben_zer0]

Iniciado por ruben_zer0

Gracias a todos por sus respuestas, realmente estoy haciendo un query dinamico y le anexe lo que puso andres95, cortando la cadena y guardando en una tabla temporal.
Gracias y saludos!

[Andres95]

De nada...



Saludos!