Diferencia de fechas y horas

[Gaug]

Hola que tal,

Tengo una función que toma 4 parámetros, Fecha y Hora inicial ; Fecha y Hora final y me da la diferencia en horas pero en formato decimal, es decir si la diferencia es de 12:30 hrs me trae 12.5 y así sucesivamente. Pero no siempre me trae las diferencias correctas hay algunos casos en que me las trae mal como por ejemplo:

Del '20120712' con hora 1240 osea (12:40) al mismo día '20120712' pero de las 1600 osea (16:00) trae la diferencia mal, pero si la hora final cambia a 1610 (16:10) lo trae correctamente, ¿alguna idea del por qué? les dejo el código para ver si pueden encontrar algún error que yo no.

Muchas gracias de antemano.

Código SQL:

CREATE FUNCTION [dbo].[HoraInicialint]
 
(   @HISAP2 nvarchar(10), 
    @HFSAP2 nvarchar(10),
    @FISAP DateTIME ,
    @FFSAP DATEtime 
     )
 
RETURNS nvarchar(10)
AS 
BEGIN
DECLARE @HIFF VARCHAR (10)
DECLARE @HFFF VARCHAR (10)
DECLARE @DifDIas nvarchar(10)
DECLARE @HP1 nvarchar (10)
DECLARE @HP2 nvarchar (10)
DECLARE @Salida nVarchar(20)
DECLARE @HISAPV VARCHAR (10)
DECLARE @HFSAPV VARCHAR (10)
DECLARE @HISAP INT
DECLARE @HFSAP INT
 
 
    --COnversiond e valores hora  a int ----------------------------------------------
    SET @HISAPV = CONVERT(FLOAT,@HISAP2 )
    SET @HFSAPV = CONVERT(FLOAT,@HFSAP2 )
    SET @HISAP = CONVERT(INT,@HISAPV)
    SET @HFSAP = CONVERT(INT,@HFSAPV)
    
    SET @HISAP2 = ISNULL(@HISAP2,01) 
    SET @HFSAP2 = ISNULL(@HFSAP2,01)
    SET @FISAP = ISNULL(@FISAP,0)
    SET @FFSAP = ISNULL(@FFSAP,0) 
    
    
    
    -- COnversion de hora inicial
    IF LEN(@HISAP) = 4 
    SET @HIFF =  CONVERT(Nvarchar,@HISAP)
 
    IF LEN(@HISAP) = 1
    SET @HIFF = ('000'+ CONVERT(Nvarchar,@HISAP))
 
    IF LEN(@HISAP) = 2
    SET @HIFF = ('00'+ CONVERT(Nvarchar,@HISAP))
 
    IF LEN(@HISAP) = 3
    SET @HIFF = ('0'+ CONVERT(Nvarchar,@HISAP))
 
    -- COnversion de hora FINAL
    IF LEN(@HFSAP) = 4
    SET @HFFF =  CONVERT(Nvarchar,@HFSAP)
 
    IF LEN(@HFSAP) = 1
    SET @HFFF = ('000'+ CONVERT(Nvarchar,@HFSAP))
 
    IF LEN(@HFSAP) = 2
    SET @HFFF = ('00'+ CONVERT(Nvarchar,@HFSAP))
 
    IF LEN(@HFSAP) = 3
    SET @HFFF = ('0'+ CONVERT(Nvarchar,@HFSAP))
    
    
    -- Conversion y calculo de horas ----------------------------------------
    
    
    IF DATEDIFF(DAY,@FISAP,@FFSAP) >=1
    BEGIN
        SET @DifDIas = ((DATEDIFF(DAY,@FISAP,@FFSAP)*2400) - @HISAP )  + @HFSAP  
            IF LEN(@DifDIas) = 1
                SET @DifDIas = ('000'+ CONVERT(Nvarchar,@DifDIas))
            IF LEN(@DifDIas) = 2
                SET @DifDIas = ('00'+ CONVERT(Nvarchar,@DifDIas))
            IF LEN(@DifDIas) = 3
                SET @DifDIas = ('0'+ CONVERT(Nvarchar,@DifDIas))            
            IF LEN(@DifDIas) = 4                                            
                SET @DifDIas =  CONVERT(Nvarchar,@DifDIas)                  
                SET @HP1 = LEFT(@DifDias,2)
            IF LEN(@DifDIas) = 5 
                SET @HP1 = LEFT(@DifDias,3)
            IF (@DifDIas > = 100 ) -- SI es mayor a una hora, se le suma el dia completo 
                BEGIN
                    SET @HP2 = RIGHT(@DifDias,2)
                    IF @HP2 > = 61
                    BEGIN
                        SET @HP2 = @HP2 -40
                        SET @Salida =   CONVERT(FLOAT,@HP1) + ROUND((CONVERT(FLOAT, @HP2))/60,2 ) 
                    END
                    IF @HP2 <= 60
                        SET @Salida =   CONVERT(FLOAT,@HP1) + ROUND((CONVERT(FLOAT, @HP2))/60,2 ) 
                        --Set @Salida =  @HP2--ROUND((CONVERT(FLOAT, @HP2))/60,2 )--@DifDIas--HP2
                END
            IF (@DifDIas < = 99 )-- si es menor de una hora, no toma en cuenta el dia que paso
                BEGIN
                    SET @HP2 = RIGHT(@DifDias,2)
                    SET @Salida =  ROUND((CONVERT(FLOAT, (@HP2-40)))/60,2 )
                END
                
    END
    IF  DATEDIFF(DAY,@FISAP,@FFSAP) = 0 --and  DATEDIFF(day,@FISAP,@FFSAP) >= 0
    BEGIN
        SET @DifDIas = (CONVERT(FLOAT,@HFSAP) - CONVERT(FLOAT,@HISAP))
        IF @DifDIas NOT LIKE '%-%'
            BEGIN
                IF LEN(@DifDIas) = 4
                    SET @DifDIas =  CONVERT(Nvarchar,@DifDIas)
                IF LEN(@DifDIas) = 1
                    SET @DifDIas = ('000'+ CONVERT(Nvarchar,@DifDIas))
                IF LEN(@DifDIas) = 2
                    SET @DifDIas = ('00'+ CONVERT(Nvarchar,@DifDIas))
                IF LEN(@DifDIas) = 3
                    SET @DifDIas = ('0'+ CONVERT(Nvarchar,@DifDIas)) 
            SET @HP1 = LEFT(@DifDias,2)
            SET @HP2 = RIGHT(@DifDias,2)
            IF @HP2 <= 60
                SET @Salida =  CONVERT(FLOAT,@HP1)+ ROUND((CONVERT(FLOAT, @HP2))/60,2 )-- 
            IF @HP2 >= 61
                BEGIN
                    SET @HP2 = @HP2 -40
                    SET @Salida = CONVERT(FLOAT,@HP1) + ROUND((CONVERT(FLOAT, @HP2))/60,2 )
                END
            END -- endIF @DifDIas NOT LIKE
    END
    
    
    
    IF DATEDIFF(DAY,@FISAP,@FFSAP) <=-1
    BEGIN
        SET @DifDIas = ((DATEDIFF(DAY,@FFSAP,@FISAP)*2400) -  @HFSAP )  +   @HISAP
            IF LEN(@DifDIas) = 1
                SET @DifDIas = ('000'+ CONVERT(Nvarchar,@DifDIas))
            IF LEN(@DifDIas) = 2
                SET @DifDIas = ('00'+ CONVERT(Nvarchar,@DifDIas))
            IF LEN(@DifDIas) = 3
                SET @DifDIas = ('0'+ CONVERT(Nvarchar,@DifDIas))            
            IF LEN(@DifDIas) = 4                                            
                SET @DifDIas =  CONVERT(Nvarchar,@DifDIas)                  
                SET @HP1 = LEFT(@DifDias,2)
            IF LEN(@DifDIas) = 5 
                SET @HP1 = LEFT(@DifDias,3)
            IF LEN(@DifDIas) = 6 
                SET @HP1 = LEFT(@DifDias,4)
            IF (@DifDIas > = 100 ) -- SI es mayor a una hora, se le suma el dia completo 
                BEGIN
                    SET @HP2 = RIGHT(@DifDias,2)
                    IF @HP2 > = 61
                    BEGIN
                        SET @HP2 = @HP2 -40
                        SET @Salida =   (CONVERT(FLOAT,@HP1) + ROUND((CONVERT(FLOAT, @HP2))/60,2 ) )*-1
                    END
                    IF @HP2 <= 60
                        SET @Salida =   (CONVERT(FLOAT,@HP1) + ROUND((CONVERT(FLOAT, @HP2))/60,2 ) )*-1
                        --Set @Salida =  @HP2--ROUND((CONVERT(FLOAT, @HP2))/60,2 )--@DifDIas--HP2
                END
            IF (@DifDIas < = 99 )-- si es menor de una hora, no toma en cuenta el dia que paso
                BEGIN
                    SET @HP2 = RIGHT(@DifDias,2)
                    SET @Salida = ( ROUND((CONVERT(FLOAT, (@HP2-40)))/60,2 ))*-1
                END
                
    END
RETURN @Salida
 END
 

[Libras]

Mucho codigo!!! :S que necesitas hacer? igual y se puede con menos codigo ;)

[Gaug]

Pues lo explique brevemente arriba del codigo sacar la diferencia en decimal de una fecha y hora inicial y fecha y hora final

Ejemplo:

De 20120814 a las 1530 (15:30 hrs) hasta el 20120815 400 (04:00 hrs) son 12:30 hrs y quiero que me devuelva 12.5, el código lo hace en la mayoría de los casos de manera correcta, pero en algunos casos no.

[Andres95]

De acuerdo con Libras... toda esa funcionalidad ya esta codificada y probada en la funcion DATEDIFF...

solo hay que utilizarla de la forma que mejor nos convenga.. por ejemplo..

Código:

CREATE FUNCTION [dbo].[HoraInicialint2](   
    @FISAP DATETIME 
    ,@FFSAP DATETIME 
)
 
RETURNS NVARCHAR(10)
AS 
BEGIN
  RETURN CAST(CAST((DATEDIFF(MINUTE,0, @FFSAP) - 
                  DATEDIFF(MINUTE,0, @FISAP))/60.00 AS DECIMAL(9,6)) AS VARCHAR)
END
GO

SELECT dbo.[HORAINICIALINT2]('20120712 12:40', '20120712 16:00') [DIFERENCIA EN HRAS]
SELECT dbo.[HORAINICIALINT2]('20120712 12:40', '20120712 16:10') [DIFERENCIA EN HRAS]
SELECT dbo.[HORAINICIALINT2]('20120710 12:40', '20120712 16:00') [DIFERENCIA EN HRAS]

--

Y el resultado:

Código:

DIFERENCIA EN HRAS
------------------
3.333333

DIFERENCIA EN HRAS
------------------
3.500000

DIFERENCIA EN HRAS
------------------
51.333333

Saludos!

[Gaug]

Hola que tal, me funciona correctamente el código que acabas de poner, el problema es que sólo estas enviando 2 parametros tipo datetime, y lo que quisiera que haga es que tome 4 parametros, 2 datetime para la fecha y 2 nvarchar para las horas (1610, 1600, etc) y que haga la diferencia, no sé si se pueda modificar tu función para que acepte los 4 parametros.

Saludos.

[Andres95]

Si, si se puede.. aunque dejarla genérica te da el beneficio de reutilizarla en cualquier otra aplicación y/o proceso ya que tendría una funcionalidad especifica...

El resto es solo manejo de cadenas que no tienen que ver con la funcionalidad principal.. p.ejemplo..

Código:

DECLARE @HISAP2 NVARCHAR(10) = '420'
       ,@FISAP DATETIME = '20120710'
       
SET @hisap2 = RIGHT('0000' + @hisap2, 4)

SELECT CAST( CONVERT(VARCHAR, @fisap,112) 
             + ' ' 
             + SUBSTRING(@hisap2,1,2) 
             + ':' 
             + SUBSTRING(@HISAP2,3,2)  AS DATETIME) [FISAP]

Y el resultado:

Código:

FISAP
-----------------------
2012-07-10 04:20:00.000

Saludos!

[Libras]

Muy buen aporte Andres95 :)

[Gaug]

Antes que nada muchas gracias por tu respuesta, adapte tu código al anterior y me dio esto:

Código SQL:

ALTER FUNCTION [dbo].[HoraInicialINT]
 
(   @HISAP2 nvarchar(10), 
    @HFSAP2 nvarchar(10),
    @FISAP DateTIME ,
    @FFSAP DATEtime 
     )
 
RETURNS nvarchar(10)
AS 
BEGIN
 
-- COnversion de horaS
       
SET @hisap2 = RIGHT('0000' + @hisap2, 4)
SET @HFSAP2 = RIGHT('0000' + @HFSAP2, 4)
 
SET @FISAP = CAST( CONVERT(VARCHAR, @fisap,112) 
             + ' ' 
             + SUBSTRING(@hisap2,1,2) 
             + ':' 
             + SUBSTRING(@HISAP2,3,2)  AS DATETIME) 
 
SET @FFSAP = CAST( CONVERT(VARCHAR, @FFSAP,112) 
             + ' ' 
             + SUBSTRING(@HFSAP2,1,2) 
             + ':' 
             + SUBSTRING(@HFSAP2,3,2)  AS DATETIME) 
 
  RETURN CAST(CAST((DATEDIFF(MINUTE,0, @FFSAP) - 
                  DATEDIFF(MINUTE,0, @FISAP))/60.00 AS DECIMAL(9,6)) AS VARCHAR)
END
GO
 

Pero al usar el siguiente query:

Código SQL:

SELECT dbo.[HORAINICIALINT]('20120710' ,'1240', '20120712', '1600') [DIFERENCIA EN HRAS]
 

Me devuelve este error:

The conversion of a varchar data type to a datetime data type resulted in an out-of-range value.

¿Alguna idea de que esté mal en la función?

Saludos y gracias por la ayuda.

[Libras]

lo que esta mal es el formato de fecha que estas manejando, revisa como envias los parametros y como se estan convirtiendo los datos....

[Andres95]

checa el orden de los parámetros que definiste en la función..
primero se espera las horas y luego las fechas..



Saludos!

[Gaug]

Es verdad haha que tonto de mi parte, muchas gracias a ambos ya quedó! se los agradezco en verdad.