Convertir Formula en Resultado

[mauro_bernal_rios]

Buenas Tardes gente.

Esta vez vengo con una duda un poco complicada.

Tengo una tabla DATOS y en ella existe una columna llamada FORMULA que guarda literalmente una fórmula algebraicas.

Por ej:
SELECT FORMULA from DATOS

FORMULA:
54,92+83,55+356,48+97,95+0+0
25,29+33,42+311,92+89,42+0+0
0+1589,63+0+124,34+300+0
25,29+33,42+311,92+89,42+0+0
69,85+116,97+267,36+92,76+0+0
0+911,38+0+124,34+60+0



Quisiera hacer un
SELECT FORMULA,RESULTADO from DATOS

Donde RESULTADO sería el resultado de esa operación antes descripta.

Alguna idea?

Por cierto trabajo con MICROSOFT SQL SERVER 2005 SP3

[flaviovich]

Solo para SQL 2005 o superior:

Código SQL:

DECLARE @datos TABLE(
    formula VARCHAR(50)
)
INSERT INTO @datos VALUES('54,92+83,55+356,48+97,95+0+0')
INSERT INTO @datos VALUES('25,29+33,42+311,92+89,42+0+0')
 
SELECT formula, SUM(CAST(REPLACE(VALUE,',','.') AS NUMERIC(20,2)))
FROM @datos d
CROSS APPLY dbo.Split(d.formula,'+') S
GROUP BY formula
 

[flaviovich]

La funcion Split la encuentras aqui: http://www.devx.com/tips/Tip/20009

[royrojas]

Con una funcion SPLIT se podria hacer eso que quieres.

Paso 1. Creamos la funcion Split

Código:

CREATE FUNCTION SPLIT
(
 @s nvarchar(max),
 @splitChar nchar(1)
)
returns @t table (id int identity(1,1), val nvarchar(max))
as
begin

declare @i int, @j int
select @i = 0, @j = (len(@s) - len(replace(@s,@splitChar,'')))

;with cte 
as
(
 select
  i = @i + 1,
  s = @s, 
  n = substring(@s, 0, charindex(@splitChar, @s)),
  m = substring(@s, charindex(@splitChar, @s)+1, len(@s) - charindex(@splitChar, @s))

 union all

 select 
  i = cte.i + 1,
  s = cte.m, 
  n = substring(cte.m, 0, charindex(@splitChar, cte.m)),
  m = substring(
   cte.m,
   charindex(@splitChar, cte.m) + 1,
   len(cte.m)-charindex(@splitChar, cte.m)
 )
 from cte
 where i <= @j
)
insert into @t (val)
select pieces
from 
(
 select 
 ltrim(rtrim(case when i <= @j then n else m end)) pieces
 from cte
) t
where
 len(pieces) > 0
option (maxrecursion 0)

return

end

GO

Y luego la invocas

select SUM(cast(val as decimal(10,2))) from dbo.SPLIT('54.2 + 83 + 356 + 97','+')

Si bien aqui lo hace para esta linea, lo ideal seria que la misma funcion retorne ya el valor de la suma. Entonces en ese caso solamente modificas la funcion para que en lugar de que te retorne una tabla, te retorne un decimal con el resultado.

y solamente harias algo como asi

SELECT FORMULA, dbo.SumaFormula(FORMULA) as RESULTADO from DATOS

[mauro_bernal_rios]

Se me había ocurrido hacerlo con SPLIT, pero en mi caso soy externo y no quería meter ninguna función. Pero veo que no queda otra...

Muchas Gracias... Ahora... a probar !!!

[flaviovich]

Otra opcion podria ser usar una tabla temporal, y ahi ir separando en columnas los sumandos si la cantidad de estos es siempre la misma, en tu caso 6 columnas.