Convertir cantidad a letras SQL SERVER 2005

[dolorosaclaridad]

He investigado y no se recomienda que esta lógica la tenga la Base de datos, sin embargo por tema de Crystal Report (VS 2005) me veo en la obligacion de traermelo desde la BD.

Alguien sabe de alguna función para convertir una cantidad en palabras?, por ejemplo:

10125450 a "diez millones ciento veinticinco mil cuatrocientos cincuenta".

Agradecido de Antemano.

[iislas]

Checa esto:

Alguna vez publique esta rutina para SQL Server 2000, verifica si te sirve:


CREATE PROCEDURE sp_Num2Let @Numero NUMERIC(20,2) AS
BEGIN
SET NOCOUNT ON
DECLARE @lnEntero INT,
@lcRetorno VARCHAR(512),
@lnTerna INT,
@lcMiles VARCHAR(512),
@lcCadena VARCHAR(512),
@lnUnidades INT,
@lnDecenas INT,
@lnCentenas INT,
@lnFraccion INT
SELECT @lnEntero = CAST(@Numero AS INT),
@lnFraccion = (@Numero - @lnEntero) * 100,
@lcRetorno = '',
@lnTerna = 1
WHILE @lnEntero > 0
BEGIN /* WHILE */
-- Recorro terna por terna
SELECT @lcCadena = ''
SELECT @lnUnidades = @lnEntero % 10
SELECT @lnEntero = CAST(@lnEntero/10 AS INT)
SELECT @lnDecenas = @lnEntero % 10
SELECT @lnEntero = CAST(@lnEntero/10 AS INT)
SELECT @lnCentenas = @lnEntero % 10
SELECT @lnEntero = CAST(@lnEntero/10 AS INT)
-- Analizo las unidades
SELECT @lcCadena =
CASE /* UNIDADES */
WHEN @lnUnidades = 1 AND @lnTerna = 1 THEN 'UNO ' + @lcCadena
WHEN @lnUnidades = 1 AND @lnTerna <> 1 THEN 'UN ' + @lcCadena
WHEN @lnUnidades = 2 THEN 'DOS ' + @lcCadena
WHEN @lnUnidades = 3 THEN 'TRES ' + @lcCadena
WHEN @lnUnidades = 4 THEN 'CUATRO ' + @lcCadena
WHEN @lnUnidades = 5 THEN 'CINCO ' + @lcCadena
WHEN @lnUnidades = 6 THEN 'SEIS ' + @lcCadena
WHEN @lnUnidades = 7 THEN 'SIETE ' + @lcCadena
WHEN @lnUnidades = 8 THEN 'OCHO ' + @lcCadena
WHEN @lnUnidades = 9 THEN 'NUEVE ' + @lcCadena
ELSE @lcCadena
END /* UNIDADES */
-- Analizo las decenas
SELECT @lcCadena =
CASE /* DECENAS */
WHEN @lnDecenas = 1 THEN
CASE @lnUnidades
WHEN 0 THEN 'DIEZ '
WHEN 1 THEN 'ONCE '
WHEN 2 THEN 'DOCE '
WHEN 3 THEN 'TRECE '
WHEN 4 THEN 'CATORCE '
WHEN 5 THEN 'QUINCE '
ELSE 'DIECI' + @lcCadena
END
WHEN @lnDecenas = 2 AND @lnUnidades = 0 THEN 'VEINTE ' + @lcCadena
WHEN @lnDecenas = 2 AND @lnUnidades <> 0 THEN 'VEINTI' + @lcCadena
WHEN @lnDecenas = 3 AND @lnUnidades = 0 THEN 'TREINTA ' + @lcCadena
WHEN @lnDecenas = 3 AND @lnUnidades <> 0 THEN 'TREINTA Y ' + @lcCadena
WHEN @lnDecenas = 4 AND @lnUnidades = 0 THEN 'CUARENTA ' + @lcCadena
WHEN @lnDecenas = 4 AND @lnUnidades <> 0 THEN 'CUARENTA Y ' + @lcCadena
WHEN @lnDecenas = 5 AND @lnUnidades = 0 THEN 'CINCUENTA ' + @lcCadena
WHEN @lnDecenas = 5 AND @lnUnidades <> 0 THEN 'CINCUENTA Y ' + @lcCadena
WHEN @lnDecenas = 6 AND @lnUnidades = 0 THEN 'SESENTA ' + @lcCadena
WHEN @lnDecenas = 6 AND @lnUnidades <> 0 THEN 'SESENTA Y ' + @lcCadena
WHEN @lnDecenas = 7 AND @lnUnidades = 0 THEN 'SETENTA ' + @lcCadena
WHEN @lnDecenas = 7 AND @lnUnidades <> 0 THEN 'SETENTA Y ' + @lcCadena
WHEN @lnDecenas = 8 AND @lnUnidades = 0 THEN 'OCHENTA ' + @lcCadena
WHEN @lnDecenas = 8 AND @lnUnidades <> 0 THEN 'OCHENTA Y ' + @lcCadena
WHEN @lnDecenas = 9 AND @lnUnidades = 0 THEN 'NOVENTA ' + @lcCadena
WHEN @lnDecenas = 9 AND @lnUnidades <> 0 THEN 'NOVENTA Y ' + @lcCadena
ELSE @lcCadena
END /* DECENAS */

-- Analizo las centenas
SELECT @lcCadena =
CASE /* CENTENAS */
WHEN @lnCentenas = 1 AND @lnUnidades = 0 AND @lnDecenas = 0 THEN 'CIEN ' +
@lcCadena
WHEN @lnCentenas = 1 AND NOT(@lnUnidades = 0 AND @lnDecenas = 0) THEN
'CIENTO ' + @lcCadena
WHEN @lnCentenas = 2 THEN 'DOSCIENTOS ' + @lcCadena
WHEN @lnCentenas = 3 THEN 'TRESCIENTOS ' + @lcCadena
WHEN @lnCentenas = 4 THEN 'CUATROCIENTOS ' + @lcCadena
WHEN @lnCentenas = 5 THEN 'QUINIENTOS ' + @lcCadena
WHEN @lnCentenas = 6 THEN 'SEISCIENTOS ' + @lcCadena
WHEN @lnCentenas = 7 THEN 'SETECIENTOS ' + @lcCadena
WHEN @lnCentenas = 8 THEN 'OCHOCIENTOS ' + @lcCadena
WHEN @lnCentenas = 9 THEN 'NOVECIENTOS ' + @lcCadena
ELSE @lcCadena
END /* CENTENAS */
-- Analizo la terna
SELECT @lcCadena =
CASE /* TERNA */
WHEN @lnTerna = 1 THEN @lcCadena
WHEN @lnTerna = 2 AND (@lnUnidades + @lnDecenas + @lnCentenas <> 0) THEN
@lcCadena + ' MIL '
WHEN @lnTerna = 3 AND (@lnUnidades + @lnDecenas + @lnCentenas <> 0) AND
@lnUnidades = 1 AND @lnDecenas = 0 AND @lnCentenas = 0 THEN @lcCadena + '
MILLON '
WHEN @lnTerna = 3 AND (@lnUnidades + @lnDecenas + @lnCentenas <> 0) AND
NOT (@lnUnidades = 1 AND @lnDecenas = 0 AND @lnCentenas = 0) THEN @lcCadena
+ ' MILLONES '
WHEN @lnTerna = 4 AND (@lnUnidades + @lnDecenas + @lnCentenas <> 0) THEN
@lcCadena + ' MIL MILLONES '
ELSE ''
END /* TERNA */
-- Armo el retorno terna a terna
SELECT @lcRetorno = @lcCadena + @lcRetorno
SELECT @lnTerna = @lnTerna + 1
END /* WHILE */
IF @lnTerna = 1
SELECT @lcRetorno = 'CERO'
SELECT RTRIM(@lcRetorno) + ' CON ' + LTRIM(STR(@lnFraccion,2)) + '/100'
END


GO

[Libras]

bien dicen el que busca encuentra :), hice una busqueda en google "convert number to word sql server" y aparecen varios resultados que funcionan por ejemplo este:

Código SQL:

DECLARE @NUMBER INT
 SET @NUMBER=10125450
   
 DECLARE @RESULT VARCHAR(100), @word VARCHAR(100), @GROUP VARCHAR(100)  
 DECLARE @i INT, @j INT, @m INT, @digit VARCHAR(2), @cn VARCHAR(20)  
  
 IF @NUMBER = 0 print 'Zero'  
  
 SELECT @RESULT = '', @word = '', @GROUP = ''  
   
 SET @cn = @NUMBER  
 SET @cn = REPLACE(@cn,',','')  
 SET @m = LEN(@cn) % 3   
 IF @m > 0 SET @cn = REPLICATE('0',3-@m) + @cn    -- Left pad with zeroes to a multiple of 3  
  
 SET @i = 1  
 SET @j = LEN(@cn)-@i+1  
 SET @m = @i % 3  
 WHILE @i <= LEN(@cn)  
 BEGIN  
  -- @i is 1 origin index into numeric string while @m = @i modulo 3  
  -- If the middle digit of each group of 3 is a '1' then this is a 'Ten' or a '...teen'  
  IF @m = 2 AND SUBSTRING(@cn,@i,1) = '1'   
  BEGIN  
   SET @digit = SUBSTRING(@cn,@i,2)  
   -- Skip rightmost digit of 3 if processing teens   
   SET @i = @i + 1  
  END  
  ELSE   
   SET @digit = SUBSTRING(@cn,@i,1)  
  
  SET @word =   
  CASE   
   WHEN @m = 0 THEN         -- Rightmost digit of group of 3  
    CASE @digit   
     WHEN '0' THEN ''  
     WHEN '1' THEN 'One'  
     WHEN '2' THEN 'Two'  
     WHEN '3' THEN 'Three'  
     WHEN '4' THEN 'Four'  
     WHEN '5' THEN 'Five'  
     WHEN '6' THEN 'Six'  
     WHEN '7' THEN 'Seven'  
     WHEN '8' THEN 'Eight'  
     WHEN '9' THEN 'Nine'  
    END +   
    CASE   
     WHEN (@GROUP <> '' OR @digit <> '0') AND (@j+2) / 3 = 2 THEN ' Thousand'  
     WHEN (@GROUP <> '' OR @digit <> '0') AND (@j+2) / 3 = 3 THEN ' Million'  
     WHEN (@GROUP <> '' OR @digit <> '0') AND (@j+2) / 3 = 4 THEN ' Billion'  
     ELSE ''  
    END  
   WHEN LEN(@digit) = 2 THEN       -- Special case when middle digit is a '1'  
    CASE @digit   
     WHEN '10' THEN 'Ten'  
     WHEN '11' THEN 'Eleven'  
     WHEN '12' THEN 'Twelve'  
     WHEN '13' THEN 'Thirteen'  
     WHEN '14' THEN 'Fourteen'  
     WHEN '15' THEN 'Fifteen'  
     WHEN '16' THEN 'Sixteen'  
     WHEN '17' THEN 'Seventeen'  
     WHEN '18' THEN 'Eighteen'  
     WHEN '19' THEN 'Nineteen'  
    END +  
    CASE   
     WHEN (@GROUP <> '' OR @digit <> '00') AND (@j+2) / 3 = 2 THEN ' Thousand'  
     WHEN (@GROUP <> '' OR @digit <> '00') AND (@j+2) / 3 = 3 THEN ' Million'  
     WHEN (@GROUP <> '' OR @digit <> '00') AND (@j+2) / 3 = 4 THEN ' Billion'  
     ELSE ''  
    END  
   WHEN @m = 2 THEN         -- Middle digit of group of 3  
    CASE @digit   
     WHEN '2' THEN 'Twenty'  
     WHEN '3' THEN 'Thirty'  
     WHEN '4' THEN 'Forty'  
     WHEN '5' THEN 'Fifty'  
     WHEN '6' THEN 'Sixty'  
     WHEN '7' THEN 'Seventy'  
     WHEN '8' THEN 'Eighty'  
     WHEN '9' THEN 'Ninety'  
     ELSE ''  
    END  
   WHEN @m = 1 THEN         -- Leftmost digit of group of 3  
    CASE @digit   
     WHEN '0' THEN ''  
     WHEN '1' THEN 'One'  
     WHEN '2' THEN 'Two'  
     WHEN '3' THEN 'Three'  
     WHEN '4' THEN 'Four'  
     WHEN '5' THEN 'Five'  
     WHEN '6' THEN 'Six'  
     WHEN '7' THEN 'Seven'  
     WHEN '8' THEN 'Eight'  
     WHEN '9' THEN 'Nine'  
    END +   
    CASE WHEN @digit <> '0' THEN ' Hundred' ELSE '' END  
  END  
  
  SET @GROUP = @GROUP + RTRIM(@word)      -- Group value  
  
  IF @word <> ''   
  BEGIN  
   DECLARE @prefix VARCHAR(20)  
   IF CHARINDEX(' ',@word) > 0 SET @prefix = LEFT(@word,CHARINDEX(' ',@word)) ELSE SET @prefix = @word   
   IF RIGHT(@RESULT,2) = 'ty' AND @prefix IN ('One','Two','Three','Four','Five','Six','Seven','Eight','Nine')  
    SET @RESULT = @RESULT + '-' + LTRIM(@word)   
   ELSE  
    SET @RESULT = @RESULT + ' ' + LTRIM(@word)   
  END  
  -- The following needs to be outside of a UDF to work:  
  --IF @debug = 1 SELECT @cn as 'Number', @i as '@i', @j as '@j', @m as '@m', @digit as '@digit', CAST(replace(@group,' ','`') AS CHAR(30)) as '@group', @word as '@word', @result as '@result'  
  SET @i = @i + 1  
  SET @j = LEN(@cn)-@i+1  
  SET @m = @i % 3   
  IF @m = 1 SET @GROUP = ''        -- Clear group value when starting a new one  
  
 END  
  
 IF @RESULT = '' SET @RESULT = '0'  
 print @RESULT
 

Aqui el link de donde saque ese codigo

http://www.sqlservercentral.com/Foru...134-149-1.aspx

Nada mas cambia las palabras de ingles al español y listo tienes tu funcion :)

Saludos!

[dolorosaclaridad]

muchas gracias por las respuestas, todo lo deje en un SP, y el luego cuando lo necesito ejecuto el SP. saludos