VB6.0 SP6 y MySQL

[edjosephgr]

Buenas Tardes amigos,

Aqui recurro a ustedes despues de indagar fuertemente por internet y no conseguir solucion a mi problema. Espero que alguno de ustedes me pueda ayudar :D

Les comento; en mi PC tengo instalado el WampServer 1.7.3 (mysql, apache, phpmyadmin) con el que sirvo mi pagina web, con su base de datos y todo.

Ahora necesito conectarme a esa base de datos desde VB6 y ni remota idea como hacerle :(

Mis datos: Server: localhost, User: root, pass: 123456, DB: sms
DB: tabla: send, Campos: id, tlf, msj, stad

Necesito conectarme desde visual a esa db consultar de la tabla "send" los registros que el campo "stad" sean igual a 0 y montarlos en un grid.

Esa aplicacion la tengo hecha con una db de access exactamente igual, y loq hago es con un timer cada 5 segundos pasar por un registro q "stad" sea igual a cero, cambiarlo a uno (1) y guardar, quiero hacer lo mismo pero con la db q mencione al principio de mysql.

Les Agradeceria un mundo que me puedan orientar en este caso plz ;)

[fradve]

Lo primero que tienes que hacer es descargarte el control ODBC de la pagina de mysql.

El código para que te puedas conectar es:

Código vb:

Dim cn As ADODB.Connection
Dim res As ADODB.Recordset
Dim conexion As String
 
Private Sub Form_Load()
    
    Set cn = New ADODB.Connection
    conexion = "driver={MySQL ODBC 3.51 Driver};" _
                        & "SERVER=localhost;" _
                        & "DATABASE=sms;" _
                        & "UID=root;PWD=123456;OPTION=3"
                            
    cn.ConnectionString = conexion
    cn.Open
    
    Set res = New ADODB.Recordset
    With res
        .ActiveConnection = cn
        .CursorLocation = adUseClient
        .CursorType = adOpenStatic
        .LockType = adLockOptimistic
    End With
    
    res.Open "SELECT id, tlf, msj, stad FROM send WHERE stad=0"
    Set DataGrid1.DataSource = res
End Sub
 

La otra parte ya la puedes hacer tú. Cualquier duda posteala...

[edjosephgr]

Muchas gracias amigo, la verdad me funciono perfecto, y logre cargar los datos.
No Obstante me declaro ignorante en esto. siempre he usado el controldata y esto es bastante diferente.

Espero me puedas continuar ayudando, te agradeceria mucho si ahora me puedes explicar, como hago para vincular con campos: por ejemplo yo hice esto despues del codigo que me dejastes del load del formulario:

Label1.Caption = res.Fields("id")
Text1.Text = res.Fields("tlf")
Text2.Text = res.Fields("msj")
Check1.Value = res.Fields("stad")

y bien, en los campos me salen los datos, PEEERO hice un boton que le puse:

Private Sub Command1_Click()
On Error GoTo fail
res.MoveNext

fail:
If Err.Number = "3021" Then
res.Requery
End If
End Sub

Esto hace que se mueva al siguiente registro, perfecto en el datagrid se ve que el registro se mueve, y cuando llega al ultimo que no consigue mas, se carga de nuevo y no da el error 3021 (H) jejeje ingenioso xD el problema esta que en los text no se mueve :(

Otra cosita si no es mucho exigir jejeje.. necesito es modificar el campo stad que carga en el check1 (la consulta carga solo los q valen cero (0)) que cuando tenga dicho registro activo, tildar el check y que lo guare (osea q el campo stad de ese registro se cambie a 1 en la db)

Gracias de antemano men.

[edjosephgr]

Bueno logre solucionar mi problema haciendo esto:

res.Fields("stad") = Check1.Value
res.MoveNext
If (res.RecordCount <> 0) Then
Label2.Caption = res.Fields("id")
Text1.Text = res.Fields("tlf")
Text2.Text = res.Fields("msj")
Check1.Value = res.Fields("stad")
Else
Label2.Caption = ""
Text1.Text = ""
Text2.Text = ""
Check1.Value = 0
End If

No se si sea la mejor practica pero funciona. Si tienen aguna sugerencia agradecido :)

[fradve]

Luego del codigo del load puedes colocar lo siguiente que creo es la mejor manera de hacerlo ya que asocias la caja de texto al recorset así como al registro correspondiente, entonces tu code quedaría así:

Código vb:

Dim cn As ADODB.Connection
Dim res As ADODB.Recordset
Dim conexion As String
 
Private Sub Form_Load()
    
    Set cn = New ADODB.Connection
    conexion = "driver={MySQL ODBC 3.51 Driver};" _
                        & "SERVER=localhost;" _
                        & "DATABASE=sms;" _
                        & "UID=root;PWD=123456;OPTION=3"
                            
    cn.ConnectionString = conexion
    cn.Open
    
    Set res = New ADODB.Recordset
    With res
        .ActiveConnection = cn
        .CursorLocation = adUseClient
        .CursorType = adOpenStatic
        .LockType = adLockOptimistic
    End With
    
    res.Open "SELECT id, tlf, msj, stad FROM send WHERE stad=0"
    Set DataGrid1.DataSource = res
    
    Set Label1.DataSource = res
    Label1.DataField = "id"
    
    Set Text1.DataSource = res
    Text1.DataField = "tlf"
    
    Set Text2.DataSource = res
    Text2.DataField = "msj"
 
    Set Check1.DataSource = res
    Check1.DataField = "stad"
End Sub
 

Y con los botones de navegación que has hecho, notarás que solo necesitas realizar el res.movenext o res.moveprevious y solo cambia el valor del control, ya sea el label, caja de texto o el check. Pruebalo y comentas los resultados

[UID]

Hola :D La verdad gracias por esa respuesta... estoy aprendiendo a como usar mysql con visual basic.. yo estuve trabajando con access mucho tiempo pero pues ya se me medio olvido jajajaaja.. el punto es... estoy siguiendo el ejemplo que pusiste que por cierto muy bueno la verdad Entonces yo hice esto:

Código:

Dim cn As ADODB.Connection
Dim res As ADODB.Recordset
Dim conexion As String
 
Public Sub Conectando()
Set cn = New ADODB.Connection
    conexion = "driver={MySQL ODBC 5.1 Driver};" _
                        & "SERVER=localhost;" _
                        & "DATABASE=instrumentos;" _
                        & "UID=root;PWD=edno1982;OPTION=3"
                            
    cn.ConnectionString = conexion
    cn.Open
    
    Set res = New ADODB.Recordset
    With res
        .ActiveConnection = cn
        .CursorLocation = adUseClient
        .CursorType = adOpenStatic
        .LockType = adLockOptimistic
    End With
    
End Sub

Private Sub Command1_Click()

res.Close
res.Open "SELECT Nombre, Apellidos, Ficha, Contrato FROM usuarios  where Ficha=" + Text2.Text
 Set DataGrid1.DataSource = res
 
 End Sub

Private Sub Form_Load()
    Call Conectando
   
    res.Open "SELECT Nombre, Apellidos, Ficha, Contrato FROM usuarios"
    Set DataGrid1.DataSource = res


    
End Sub

En donde tengo el problema es en el boton:

Código:

Private Sub Command1_Click()

res.Close
res.Open "SELECT Nombre, Apellidos, Ficha, Contrato FROM usuarios  where Ficha=" + Text2.Text
 Set DataGrid1.DataSource = res
 
 End Sub

Aqui cuando pongo el numero de ficha en el text2.text ejemp: 419719 y si existe tal ficha me manda todos los datos al datagrid, el problema es cuando no existe la ficha me manda este error:

Que se desconoce la columna Text2 en clause where... como puedo solucionarlo?

Lo que se me ocurrio fue poner un On error Resume Next para que se salte el error pero ese no es el caso.. me gustaria que al escribir una ficha no existente me mandara el mensaje de .. No existe tal ficha... espero me ayuden y gracias de antemano.