una subcadena dentro de una cadena

[minette1988]

Hola, he de realizar un script en Visual Basic que cuente el número de veces que aparece una subcadena en una cadena. El mensaje debe mostrar lo siguiente:
La subcadena aparece: x veces
He de introducir la cadena de teclado.
Ej: casa La letra a aparece 2 veces.
No tengo ni idea de como hacerlo. Si me podéis echar una mano. Gracias.

[erbuson]

Hola, creo que algo así podría servirte

Private Function CuantasVeces(Palabra As String, Frase As String) As Integer
Dim c As Integer
For c = 1 To Len(Frase)
If UCase$(Palabra) = UCase$(Mid$(Frase, c, Len(Palabra))) Then CuantasVeces = CuantasVeces + 1
Next
End Function

aunque probablemente no sea la única solución.

[minette1988]

Puedes decirme otra manera más sencilla es que el Private Function no lo he dado, si puede ser usando option explicit y el inputbox para introducir la cadena de teclado. Gracias

[erbuson]

No tienes porque usar una Function, ya que puedes copiar el código necesario dentro de un Command que me imagino que vas a utilizar para iniciar la búsqueda.

Si no es así, es mejor que pongas tu código para que pueda corregirte lo que haces mal ya que de esta manera aprenderás algo y si yo te pongo el código tu lo copiarás y no aprenderás, por tanto los dos estaremos perdiendo el tiempo.

[pkj]

Todo depende de los comandos que si que hayas estudiado.

Esto sería el script, suponiendo que hayas estudiado InputBox, MsgBox, For Next, If Then, Mid y Len.

Código vb:

' Forzamos la declaracion de variables
Option Explicit
 
' Declaramos las variables que vamos a necesitar
Dim F
Dim Texto
Dim Buscar
Dim CuantasVeces
 
' Pedimos los textos para trabajar:
Buscar=InputBox("Texto a buscar")
Texto=InputBox ("Texto donde buscar")
 
' Y si el texto a buscar es menor o igual que el texto principal se buscan las coincidencias
If Len(Texto)>=Len(Buscar) Then
 
  ' creamos un bucle desde 1 hasta la longitud del texto menos la longitud del texto a buscar menos 1.
  'De este modo no se intenta buscar el texto a partir de la posicion en que ya no se puede extraer 
  'un trozo del tamaño necesario.
  For F = 1 To Len(Texto) - (Len(Buscar) - 1)
 
    ' y vamos comparando bloques de texto de la misma longitud del texto a buscar 
    If Mid(Texto, F, Len(Buscar)) = Buscar Then CuantasVeces = CuantasVeces + 1
 
  Next
 
  ' Y después mostramos el resultado
  MsgBox "El texto está " & CuantasVeces & " veces"
 
End If
 

Saludos