Reinicar xp y vista con vb6

[jrrm]

Hola, como reinicio ó apago un ordenador con vista y xp con visual basic 6

[A.H.H]

Hola
con el siguiente codigo depende de los valores que pongas puedes:

cerrar sesion ---> ret = ExitWindowsEx(0, 0&)
apagar equipo-->ret = ExitWindowsEx(1, 0&)
reiniciar equipo-->ret = ExitWindowsEx(2, 0&)

tambien para forzar apagado y que los programas no pregunten aunque si hay archivos abiertos se perdera el contenido se usa:

ret = ExitWindowsEx(4, 0&)

ejemplo:

en un form pon un boton(command1), primero en la seccion General escribe el siguiente codigo:

Código:

'CONSTANTES Y DECLARACIONES PARA SALIR DE WINDOWS
' Cerrar todos los programas'
'ejemplos:'
' cerrar sesion'
Private Const EWX_LOGOFF = 0
' Apagar el equipo
Private Const EWX_SHUTDOWN As Long = 1
' Reiniciar el equipo
Private Const EWX_REBOOT = 2
' Forzar el apagado. Los ficheros abiertos se pueden perder. Las
' aplicaciones no preguntarán si se quieren guardar las modificaciones
Private Const EWX_FORCE As Long = 4
'
Private Declare Function ExitWindowsEx Lib "user32" (ByVal _
        dwOptions As Long, ByVal dwReserved As Long) As Long

'DECLARACIONES PARA OBTENER EL PERMISO NECESARIO EN NT
Private Type LUID
    UsedPart As Long
    IgnoredForNowHigh32BitPart As Long
End Type
Private Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    TheLuid As LUID
    Attributes As Long
End Type
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal _
        ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" _
        Alias "LookupPrivilegeValueA" _
        (ByVal lpSystemName As String, ByVal lpName As String, lpLuid _
        As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" _
        (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, _
        NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, _
        PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long

DESPUES ESCRIBE EL SIGUIENTE PRIVATE SUB PARA OBTENER PRIVILEGIOS:

Código:

Private Sub AdjustToken()
Const TOKEN_ADJUST_PRIVILEGES = &H20
Const TOKEN_QUERY = &H8
Const SE_PRIVILEGE_ENABLED = &H2
Dim hdlProcessHandle As Long
Dim hdlTokenHandle As Long
Dim tmpLuid As LUID
Dim tkp As TOKEN_PRIVILEGES
Dim tkpNewButIgnored As TOKEN_PRIVILEGES
Dim lBufferNeeded As Long

hdlProcessHandle = GetCurrentProcess()
OpenProcessToken hdlProcessHandle, (TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY), hdlTokenHandle
' Get the LUID for shutdown privilege
LookupPrivilegeValue "", "SeShutdownPrivilege", tmpLuid
tkp.PrivilegeCount = 1 ' One privilege to set
tkp.TheLuid = tmpLuid
tkp.Attributes = SE_PRIVILEGE_ENABLED ' Enable the shutdown privilege in the access token of this process
AdjustTokenPrivileges hdlTokenHandle, False, tkp, Len(tkpNewButIgnored), tkpNewButIgnored, lBufferNeeded
End Sub

DESPUES DENTRO DEL BOTON(COMMAND1)EL SIGUIENTE CODIGO PARA CERRAR SESION;

Código:

Private Sub Command1_Click()
AdjustToken 'Llamamos al sub adjustoken y obtenemos permisos'
ret = ExitWindowsEx(0, 0&) 'cierra sesion'
End Sub

SI CAMBIAS LOS DIFERENTES VALORES EN LA LINEA
ret = ExitWindowsEx(0, 0&) DENTRO DEL PARENTESIS EL PRIMER CARACTER
POR LOS DIFERENTES VALORES QUE TE PUSE ARRIBA APAGAR, FORZAR,REINICIAR.....
cerrar sesion ---> ret = ExitWindowsEx(0, 0&)
apagar equipo-->ret = ExitWindowsEx(1, 0&)
reiniciar equipo-->ret = ExitWindowsEx(2, 0&)
FORZAR----------->ret = ExitWindowsEx(4, 0&)


SALU2

[jrrm]

Muchas gracias, justamente lo que necesitaba.