Modificar Cadena

[assdres]

Hola a todos!!

Tengo el siguiente código:

Código vb:

Function Comprime(Cadena As String) As String
  Dim Matriz1() As String
  Dim Matriz2() As String
  Dim Cadena1 As String
  Dim Cadena2 As String
  Dim F As Long
  
  Matriz1 = Split(Cadena, ";")
  ReDim Matriz2(0)
  Matriz2(0) = Matriz1(0)
  For F = 1 To UBound(Matriz1)
    Cadena1 = Left$(Matriz1(F), InStrRev(Matriz1(F), ":"))
    Cadena2 = Left$(Matriz2(UBound(Matriz2)), InStrRev(Matriz2(UBound(Matriz2)), ":"))
    If Cadena1 = Cadena2 Then
      Matriz2(UBound(Matriz2)) = Cadena1 & Val(Right$(Matriz2(UBound(Matriz2)), _
      Len(Matriz2(UBound(Matriz2))) - Len(Cadena1))) + Val(Right$(Matriz1(F), _
      Len(Matriz1(F)) - Len(Cadena1)))
    Else
      ReDim Preserve Matriz2(UBound(Matriz2) + 1)
      Matriz2(UBound(Matriz2)) = Matriz1(F)
    End If
  Next F
Comprime = Join(Matriz2, ";")
End Function
 

El cual me sirve para hacer este tipo de cosas:

MsgBox Comprime("1:11:26:1;1:22:60:1;1:8:18:1;1:8:18:1;1: 8:18:1")
Resultado: 1:11:26:1;1:22:60:1;1:8:18:3

Apliación de sumas:
MsgBox Comprime("1:11:26:1;1:22:60:1;1:8:18:1;1:8:18:2;1: 8:18:1")
Resultado: 1:11:26:1;1:22:60:1;1:8:18:4

Me suma el último dígito de las subcadenas REPETIDAS. Lo que quiero es me me sume no sólo el último número sino los tres últimos

La idea es esta:

Para: 1:11:26:1;1:22:60:1;1:8:18:1;1:8:18:1;1: 8:18:1

Salida: 1:11:26:1;1:22:60:1;1:24:54:3


Muchas gracias a todos!!!

[seba123neo]

Hola, a ver si entendi esa funcion, ¿ te suma el ultimo digito de las ultimas 3 subcadenas que estan separadas por ";" no ?

por ejemplo, ahora te esta sumando el ultimo numero de:

1: 8:18:1

y vos queres que ahora lo haga con los ultimos 3...

saludos.

[assdres]

Me suma el último dígito de las subcadenas REPETIDAS. Lo que quiero es me me sume no sólo el último número sino los tres últimos. Que me quede algo así:

Para: 1:11:26:1;1:22:60:1;1:8:18:1;1:8:18:1;1: 8:18:1

Salida: 1:11:26:1;1:22:60:1;1:24:54:3

Todas separadas primero con ";" y las cadenas pequeñas con ":"

Es bastante urgente el asunto.

Gracias!!

[pkj]

No es muy dificil.
Se puede hacer mejor, pero si la cadena no es muy larga puede servir esto:

Código vb:

Function Comprime2(byVal Cadena As String) As String
  Dim Matriz1() As String
  Dim Matriz2() As String
  Dim Matriz1Temp() As String
  Dim Matriz2Temp() As String
  Dim F As Long
  Matriz1 = Split(Cadena, ";")
  ReDim Matriz2(0)
  Matriz2(0) = Matriz1(0)
  For F = 1 To UBound(Matriz1)
    Matriz1Temp = Split(Matriz1(F), ":")
    Matriz2Temp = Split(Matriz2(UBound(Matriz2)), ":")
    If Matriz1Temp(0) = Matriz2Temp(0) _
    And Matriz1Temp(1) / Matriz1Temp(3) = Matriz2Temp(1) / Matriz2Temp(3) _
    And Matriz1Temp(2) / Matriz1Temp(3) = Matriz2Temp(2) / Matriz2Temp(3) Then
      Matriz2(UBound(Matriz2)) = Matriz2Temp(0) & ":" _
      & Val(Matriz1Temp(1)) + Val(Matriz2Temp(1)) & ":" _
      & Val(Matriz1Temp(2)) + Val(Matriz2Temp(2)) & ":" _
      & Val(Matriz1Temp(3)) + Val(Matriz2Temp(3))
    Else
      ReDim Preserve Matriz2(UBound(Matriz2) + 1)
      Matriz2(UBound(Matriz2)) = Matriz1(F)
    End If
  Next F
  Comprime2 = Join(Matriz2, ";")
End Function
 

Saludos

PD: La proxima vez lo llamo "Function PKJZip"
Ten en cuenta que siguen sumandose los valores ya sumados, como en la anterior función.
Esta línea:
1:11:26:1;1:22:60:1;1:24:54:3;1:8:18:1;1:8:18:1;1: 8:18:1
Devuelve:
1:11:26:1;1:22:60:1;1:48:108:6

[assdres]

¡¡¡ME QUITO EL SOMBRERO!!

ESPECTACULAR!

Me preocupa lo que dices de las cadenas largas, pues a veces las hay con 30 registros seguidos.

Sin embargo mi agradecimiento es infinito!

También me gustaría aprender acerca de su funcionamiento.

Andrés.

[pkj]

El funcionamiento es bastante sencillo, aunque explicarlo llevaría algún tiempo.
Básicamente troceo la cadena por los (;) y luego esos trozos los vuelvo a separar por los (:) para comparar unos con otros y sumarlos si todos coinciden.

Lo de la longitud no creo que te dé problemas. De todos modos experimenta por si se vuelve demasiado lento con muchos registros (a mí me preocupaba que fuesen 500 o mas).

A mí lo que realmente me preocupa es... que pronto vendrás a pedirme el descompresor

Saludos.