[SOLUCIONADO] Leer archivo .ini

yamiblancoc · #1 (**permalink**) 30/11/2011, 10:09

HOLA BUEN DIA, TENGO UNA GRAN DUDA Y NO SE COMO RESOLVERLA HE LEIDO VARIOS ARTICULO PERO NO SE COMO HACERLO Y ME DA ERRORES...

ESTE ES MI ARCHIVO SIPRE.INI

[REFERENCIAS_SIPRE]

server=8247

bdatos2=SIPRE
bdatos3=INTRA

COMO HAGO PARA QUE MI SISTEMA EN VB ME LO LEA Y SE META EN MI SERVIDOR Y BUSQUE EN ESAS BASE DE DATOS

AQUI ES LO QUE HICE PERO NO SE SI ESTA BIEN

Código VB:

Ver originalGlobal servidor1 As String
Global servidor2 As String
Public BD_servidor As String
Public BD_usuario As String
Public BD_nombre As String
Public BD_clave As String
 
'**ABRIR EL ARCHIVO PLANO**
 
 Public Function Def_Var()
   Dim variable, StrVar As String
   Open App.Path & "\SIPRE.ini" For Input As #1
 
    Do While Not EOF(1)
      Line Input #1, variable
      StrVar = Trim(Mid(variable, 1, 10))
      If UCase(StrVar) = "server=" Then
         servidor1 = Trim(Mid(variable, 11, 18))
      End If
      
       StrVar = Trim(Mid(variable, 1, 8))
      If UCase(StrVar) = "bdatos2=" Then
         bdatos2 = Trim(Mid(variable, 9, 16))
      End If
  
      StrVar = Trim(Mid(variable, 1, 8))
      If UCase(StrVar) = "bdatos3=" Then
         bdatos3 = Trim(Mid(variable, 9, 16))
      End If
      
      Loop
 
 
  Close #1
   
End Function
 
Public Sub Toma_registro()
 
 
 Dim Aux_clave As String
 Dim Aux_usuario As String
 
 'BD_servidor = GetSetting("SIPRE", "Base de Datos", "Servidor")
 'BD_nombre = GetSetting("SIPRE", "Base de Datos", "NOMBD")
 'BD_usuario = GetSetting("SIPRE", "Base de Datos", "User")
 
 'Obj_Enc.Decrypt BD_usuario
 'BD_usuario = Trim(Obj_Enc.Content)
 
 'BD_clave = GetSetting("SIPREFII", "Base de Datos", "Clave")
 'Obj_Enc.Decrypt BD_clave
 'BD_clave = Trim(Obj_Enc.Content)
 
 'bdatos2 = "driver={Sql Server};server=" & Trim(BD_servidor) & ";Uid=" & Trim(BD_usuario) & ";Pwd=" & Trim(BD_clave) & ";Database=" & Trim(BD_nombre)
  bdatos2 = "driver={Sql Server};server=8247;Uid=sa;Pwd=123;Database=SIPRE"
 'bdatos2 = "driver=(Sql Server);server=" & "localhost" & ";Uid=" & "sa" & ";Pwd=" & "123" & ";Database=" & "SIPRE"
 
tipo_datos1 (bdatos2)
 
 
 'bdatos3 = "driver={Sql Server};server=" & Trim(BD_servidor) & ";Uid=" & Trim(BD_usuario) & ";Pwd=" & Trim(BD_clave) & ";Database=" & Trim(BD_nombre)
  bdatos3 = "driver={Sql Server};server=8247;Uid=sa;Pwd=123;Database=INTRA"
 'bdatos3 = "driver=(Sql Server);server=" & "localhost" & ";Uid=" & "sa" & ";Pwd=" & "123" & ";Database=" & "SIPRE"
 
tipo_datos1 (bdatos3)
 
 
End Sub

LO QUE QUIERO ES ELIMINAR LO QUE TENGO QUEMADO EN bdatos 2 y bdatos3 Y QUE EL SISTEMA ME LEA LO QUE ESTA EN EL ARCHIVO .INI

GRACIAS A LOS QUE ME PUEDAN AYUDAR

JonathanB · #2 (**permalink**) 02/12/2011, 10:24

Saludos, puedes probar una clase que usaba hace bastante tiempo para leer archivos INI.

A tu proyeco agregale la referencia a Microsoft Scripting Runtime (Menú Proyecto>Referencias>Selecciona Microsoft Scripting Runtime).

Crea un modulo "Declaraciones"y añade el siguente código

Código vb:

Ver originalOption Explicit
 
' API que recupera información de un archivo INI
' ==============================================
Public Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" ( _
    ByVal lpApplicationName As String, _
    ByVal lpKeyName As String, _
    ByVal lpDefault As String, _
    ByVal lpReturnedString As String, _
    ByVal nSize As Long, _
    ByVal lpFileName As String) As Long
  
' API que guarda información a un archivo INI
' ===========================================
Public Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" ( _
    ByVal lpApplicationName As String, _
    ByVal lpKeyName As Any, _
    ByVal lpString As Any, _
    ByVal lpFileName As String) As Long

Crea una nueva clase "ArchivoIni" y añade el siguiente código.

Código vb:

Ver original' =========================================================
' Jonathan Búcaro
' =========================================================
' Clase para el manejo de configuraciones por medio de
' archivos INI.
' =========================================================
' 25/09/2009 - Creación
' =========================================================
 
Option Explicit
 
Private m_Ruta As String
Private m_Nombre As String
Private m_Seccion As String
Private m_Llave As String
Private m_Valor As String
 
' Clase ArchivoINI
' =================
Private Sub Class_Initialize()
    m_Ruta = App.Path
    m_Nombre = ""
    m_Seccion = ""
    m_Llave = ""
    m_Valor = ""
End Sub
 
' Ruta donde se encuentra el Archivo INI
' ======================================
Public Property Get Ruta() As String
    Ruta = m_Ruta
End Property
 
Public Property Let Ruta(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Ruta = strValue
    End If
End Property
 
' Nombre del archivo INI
' ======================
Public Property Get Nombre() As String
    Nombre = m_Nombre
End Property
 
Public Property Let Nombre(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Nombre = strValue
    End If
End Property
 
' Sección del Archivo INI donde se encuentra la información
' =========================================================
Public Property Get Seccion() As String
    Seccion = m_Seccion
End Property
 
Public Property Let Seccion(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Seccion = strValue
    End If
End Property
 
' Sección del Archivo INI donde se encuentra la información
' =========================================================
Public Property Get Llave() As String
    Llave = m_Llave
End Property
 
Public Property Let Llave(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Llave = strValue
    End If
End Property
 
' Valor de la Llave que se encuentra dentro de una Sección en un Archivo INI
' ==========================================================================
Public Property Get Valor() As String
    Valor = m_Valor
End Property
 
Public Property Let Valor(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Valor = strValue
    End If
End Property
 
' Guarda la información al Archivo INI
' ====================================
Public Function GrabarLlave() As Boolean
    Dim lRet As Long
    Dim strPath As String
    Dim fso As FileSystemObject
    
    Set fso = New FileSystemObject
    
    ' Verificar que exista el Directorio
    If Not fso.FolderExists(m_Ruta) Then GoTo ErrHandler
    
    ' Armar la ruta completa, incluyendo el nombre del Archivo
    If Right(m_Ruta, 1) = "\" Then
        strPath = m_Ruta & m_Nombre
    Else
        strPath = m_Ruta & "\" & m_Nombre
    End If
 
    ' Grabar la información al Archivo INI
    lRet = WritePrivateProfileString(m_Seccion, m_Llave, m_Valor, strPath)
    If lRet = 0 Then GoTo ErrHandler
    
    If Not fso Is Nothing Then Set fso = Nothing
    GrabarLlave = True
    
    Exit Function
    
ErrHandler:
    If Not fso Is Nothing Then Set fso = Nothing
    GrabarLlave = False
End Function
 
' Borra una Llave dentro de una Sección del Archivo INI
' =====================================================
Public Function BorrarLlave() As Boolean
    Dim lRet As Long
    Dim strPath As String
    Dim fso As FileSystemObject
    
    Set fso = New FileSystemObject
    
    ' Verificar que se hayan establecido los valores Sección y Llave
    If Len(Trim(m_Seccion)) = 0 Then GoTo ErrHandler
    If Len(Trim(m_Llave)) = 0 Then GoTo ErrHandler
    
    ' Verificar que exista el Directorio
    If Not fso.FolderExists(m_Ruta) Then GoTo ErrHandler
    
    ' Armar la ruta completa, incluyendo el nombre del Archivo
    If Right(m_Ruta, 1) = "\" Then
        strPath = m_Ruta & m_Nombre
    Else
        strPath = m_Ruta & "\" & m_Nombre
    End If
    
    ' Borra una llave dentro de una Sección del Archivo INI
    lRet = WritePrivateProfileString(m_Seccion, m_Llave, vbNullString, strPath)
    If lRet = 0 Then GoTo ErrHandler
    
    If Not fso Is Nothing Then Set fso = Nothing
    BorrarLlave = True
    
    Exit Function
    
ErrHandler:
    If Not fso Is Nothing Then Set fso = Nothing
    BorrarLlave = False
End Function
 
' Borra una Sección del Archivo INI
' =================================
Public Function BorrarSeccion() As Boolean
    Dim lRet As Long
    Dim strPath As String
    Dim fso As FileSystemObject
    
    Set fso = New FileSystemObject
    
    If Len(Trim(m_Seccion)) = 0 Then GoTo ErrHandler
    
    ' Verificar que exista el Directorio
    If Not fso.FolderExists(m_Ruta) Then GoTo ErrHandler
    
    ' Armar la ruta completa, incluyendo el nombre del Archivo
    If Right(m_Ruta, 1) = "\" Then
        strPath = m_Ruta & m_Nombre
    Else
        strPath = m_Ruta & "\" & m_Nombre
    End If
    
    ' Borra una seccion del Archivo INI
    lRet = WritePrivateProfileString(m_Seccion, vbNullString, vbNullString, strPath)
    If lRet = 0 Then GoTo ErrHandler
    
    If Not fso Is Nothing Then Set fso = Nothing
    BorrarSeccion = True
    
    Exit Function
    
ErrHandler:
    If Not fso Is Nothing Then Set fso = Nothing
    BorrarSeccion = False
End Function
 
' Lee la información de una Llave dentro de una Sección del Archivo INI
' =====================================================================
Public Function LeerLlave() As Boolean
    Dim lRet As Long
    Dim sDefault As String
    Dim sRetValue As String * 256
    Dim strPath As String
    Dim fso As FileSystemObject
    
    Set fso = New FileSystemObject
    
    ' Verificar que se hayan establecido los valores Sección y Llave
    If Len(Trim(m_Seccion)) = 0 Then GoTo ErrHandler
    If Len(Trim(m_Llave)) = 0 Then GoTo ErrHandler
    
    ' Verificar que exista el Directorio
    If Not fso.FolderExists(m_Ruta) Then GoTo ErrHandler
    
    ' Armar la ruta completa, incluyendo el nombre del Archivo
    If Right(m_Ruta, 1) = "\" Then
        strPath = m_Ruta & m_Nombre
    Else
        strPath = m_Ruta & "\" & m_Nombre
    End If
    
    sDefault = ""
    lRet = GetPrivateProfileString(m_Seccion, m_Llave, sDefault, sRetValue, Len(sRetValue), strPath)
    
    If lRet = 0 Then GoTo ErrHandler
 
    Valor = Left(sRetValue, lRet)
    LeerLlave = True
    If Not fso Is Nothing Then Set fso = Nothing
    
    Exit Function
    
ErrHandler:
    If Not fso Is Nothing Then Set fso = Nothing
    Valor = sDefault
    LeerLlave = False
End Function

Para utilizarlo:

Código vb:

Ver originalDim Contenido as String
 
' Crear el objeto
Private Configuracion As ArchivoINI
Set Configuracion = New ArchivoINI
 
With Configuracion
    ' Nombre del archivo. Si no se especifica ruta, tomara default el app.path
    .Nombre = "miArchivo.ini"
 
    .Seccion = "miSeccion"
    .Llave = "miLlave"
 
    ' Si no existe la llave dentro de la sección, generar error 380
    If Not .LeerLlave Then Err.Raise 380, "miLlave"
    Contenido = .Valor
 
End With
 
' Limpiar el objeto
If Not Configuracion Is Nothing Then Set Configuracion = Nothing

Recuerda que un archivo INI esta compuesto por secciones y llaves

Ejemplo de sección:
[Seccion1]
[ConfigBD]

Ejemplo de Sección y Llave:
[ConfigBD]
Servidor=125.2.204.52
Usuario=sa

Espero que te sea de utilidad.

yamiblancoc · #3 (**permalink**) 05/12/2011, 07:47

hola, bueno gracias pero ya habia resuelto utilice

Código Visual Basic:

Ver originalPublic Sub Toma_registro()
 
 
 Dim Aux_clave As String
 Dim Aux_usuario As String
    
    Dim variable, StrVar As String
    Open App.Path & "\SIPRE.ini" For Input As #1
 
    Do While Not EOF(1)
      Line Input #1, variable
      StrVar = Trim(Mid(variable, 1, 7))
      If StrVar = "server=" Then
         Server = Trim(Mid(variable, 8, 15))
      End If
      
        
      StrVar = Trim(Mid(variable, 1, 7))
      If StrVar = "datos2=" Then
         datos2 = Trim(Mid(variable, 8, 15))
      End If
  
      StrVar = Trim(Mid(variable, 1, 7))
      If StrVar = "datos3=" Then
         datos3 = Trim(Mid(variable, 8, 15))
      End If
      
 
      Loop
 
 
 
 'bdatos2 = "driver={Sql Server};server=" & Trim(BD_servidor) & ";Uid=" & Trim(BD_usuario) & ";Pwd=" & Trim(BD_clave) & ";Database=" & Trim(BD_nombre)
  bdatos2 = "driver={Sql Server};server=" & Server & ";Uid=" & "sa" & ";Pwd=" & "pwd" & ";Database=" & datos2
 'bdatos2 = "driver=(Sql Server);server=" & "localhost" & ";Uid=" & "sa" & ";Pwd=" & "pwd" & ";Database=" & "SIPRE"
 
tipo_datos1 (bdatos2)
 
 
 'bdatos3 = "driver={Sql Server};server=" & Trim(BD_servidor) & ";Uid=" & Trim(BD_usuario) & ";Pwd=" & Trim(BD_clave) & ";Database=" & Trim(BD_nombre)
  bdatos3 = "driver={Sql Server};server=" & Server & ";Uid=" & "sa" & ";Pwd=" & "pwd" & ";Database=" & datos3
 'bdatos3 = "driver=(Sql Server);server=" & "localhost" & ";Uid=" & "sa" & ";Pwd=" & "pwd" & ";Database=" & "SIPR"
 
tipo_datos1 (bdatos3)
 
 
End Sub

y funciona perfectamente

JonathanB · #4 (**permalink**) 05/12/2011, 12:46

Saludos, me alegra que hayas encontrado una solución a tu problema. Sin embargo no es la solución definitiva para leer archivos INI: http://en.wikipedia.org/wiki/INI_file

Un Archivo INI puede estar compuesto de propiedades, valores, secciones, comentarios, lineas en blanco, valores en comillas.

La solución que mencionas es especifica de tu proyecto.

lokoman · #5 (**permalink**) 07/12/2011, 15:03

Hola!
Este es mi aporte:

En un modulo:

Código vb:

Ver original'INI
Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
 
Public Function LeerINI(strClave As String, strNombre As String, Optional ByVal strDefecto As String) As String
    Dim intTamano As Integer
    Dim strTexto As String
    Dim strArchivoINI As String
    
    strArchivoINI = App.Path & "\Config.INI"
    strTexto = Space(200)
    intTamano = GetPrivateProfileString(strClave, strNombre, "", strTexto, Len(strTexto), strArchivoINI)
    
    If intTamano > 0 Then
        strTexto = Left$(strTexto, intTamano)
    Else
        strTexto = ""
    End If
    
    If Len(strTexto) Then
        LeerINI = strTexto
    Else
        LeerINI = strDefecto
    End If
End Function
 
Public Function EscribirINI(strClave As String, strNombre As String, strTexto As String) As String
    Dim intTamano As Integer
    Dim strArchivoINI As String
    
    strArchivoINI = App.Path & "\Config.ini"
    
    intTamano = WritePrivateProfileString(strClave, strNombre, strTexto, strArchivoINI)
End Function

• Uso para escribir:
strRuntime = EscribirINI("CLAVE", "NOMBRE", TEXTO)

• Uso para Leer:
strRuntime = LeerLicencia("CLAVE", "NOMBRE", "VALOR DEFAULT")

El "VALOR DEFAULT" es el valor por defecto si no se encuentra el valor de la llave "NOMBRE"

Esta es la composicion archivo .ini:
[CLAVE]
NOMBRE=lokoman

!!