insertar hojas en un libro excel

[Betina232022]

Hola otra vez

Ahora quiero insertar hojas en un archivo excel existente.
y al insertar una imagen que aparezca a partir de una celda específica

Espero me puedan ayudar, gracias

[Betina232022]

Hola ya resolvi el problema al crear el archivo le asigno 2 hojas al libro:
objExcel.SheetsInNewWorkbook = 2 ' el nuevo libro de trabajo va tener 2 hoja
objExcel.Workbooks.Add

y lo de la imagen la inserto en la hoja2 asi:
objExcel.Sheets(2).Pictures.Insert (sRuta & sNomArchivo & ".jpg")

Por si a alguien le interesa

saludos

[pana99]

Hola.
Aca te paso un codigo que saque de algun lado y que te va a permitir insertar una imagen y manipularla
Tendras que modificarla para que lo haga en la hoja que vos quieras
Espero te ayude

Código:

Sub TestInsertPicture()
    InsertPicture "C:\TuImagen.jpg", Range("D10"), True, True
End Sub

Sub InsertPicture(PictureFileName As String, TargetCell As Range, _
    CenterH As Boolean, CenterV As Boolean)
' inserts a picture at the top left position of TargetCell
' the picture can be centered horizontally and/or vertically
Dim p As Object, t As Double, l As Double, w As Double, h As Double
    If TypeName(ActiveSheet) <> "Worksheet" Then Exit Sub
    If Dir(PictureFileName) = "" Then Exit Sub
    ' import picture
    Set p = ActiveSheet.Pictures.Insert(PictureFileName)
    ' determine positions
    With TargetCell
        t = .Top
        l = .Left
        If CenterH Then
            w = .Offset(0, 1).Left - .Left
            l = l + w / 2 - p.Width / 2
            If l < 1 Then l = 1
        End If
        If CenterV Then
            h = .Offset(1, 0).Top - .Top
            t = t + h / 2 - p.Height / 2
            If t < 1 Then t = 1
        End If
    End With
    ' position picture
    With p
        .Top = t
        .Left = l
    End With
    Set p = Nothing
End Sub

[Betina232022]

Hola pana99, te agradezco mucho tu ayuda

Funciona muy bien