Guardar configuracion de app...

[McBlink]

Buenas tardes, estoy comenzando con VB y ahora me surgio la necesidad de tener que guardar algunos datos, como un tamaño de ventana y una variable (un simple numero) y alguos datos mas seguramente.. estuve leyendo que se pueden guardar en:

- base de datos (preferentemente no quiero)
- archivos de texto
- archivos INI
- archivos CONFIG


quisiera que me recomenden algunos de esos archivos ( el mas simple por ahora ) y que me den una ayuda con el código..

Muchas Gracias!

[seba123neo]

Hola, yo lo haria con un .INI, fijate que la mayoria de los programas lo tienen, en el registro tambien lo podes hacer si son pocos datos, pero por las dudas es mejor dejar el registro como esta.para escribir en un ini debes conocer que son las secciones y las claves, por ejemplo la seccion VENTANA esta conformado por alto y ancho y quedaria algo asi:

[VENTANA]
ancho=1000
alto=2000

y asi mismo podes tener varias secciones, se usan las api's GetPrivateProfileString y WritePrivateProfileString , creo que ya te dije todo, ahora te toca buscar en internet que esta repleta de ejemplos.

saludos.

[pkj]

Para facilitar las cosas os paso el código que uso yo para guardar y leer de ficheros ini.
Hay en las faqs algo sobre esto pero no queda demasiado claro.

Código vb:

#If Win32 Then
    'Declaraciones para 32 bits
    Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" _
        (ByVal lpApplicationName As String, ByVal lpKeyName As Any, _
         ByVal lpDefault As String, ByVal lpReturnedString As String, _
         ByVal nSize As Long, ByVal lpFileName As String) As Long
    Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" _
        (ByVal lpApplicationName As String, ByVal lpKeyName As Any, _
         ByVal lpString As Any, ByVal lpFileName As String) As Long
#Else
    'Declaraciones para 16 bits
    Private Declare Function GetPrivateProfileString Lib "Kernel" _
        (ByVal lpApplicationName As String, ByVal lpKeyName As Any, _
         ByVal lpDefault As String, ByVal lpReturnedString As String, _
         ByVal nSize As Integer, ByVal lpFileName As String) As Integer
    Private Declare Function WritePrivateProfileString Lib "Kernel" _
        (ByVal lpApplicationName As String, ByVal lpKeyName As Any, _
         ByVal lpString As Any, ByVal lplFileName As String) As Integer
#End If
 
Sub GuardarIni(ByVal FicheroINI As String, ByVal Seccion As String, _
ByVal Clave As String, ByVal Valor As String)
  On Local Error GoTo ErrorGuardarIni
  WritePrivateProfileString Seccion, Clave, Valor, FicheroINI
  Exit Sub
ErrorGuardarIni:
  MsgBox Err.Number & ". " & Err.Description, vbCritical
  Err.Clear
End Sub
 
'------------------------------------
 
Function LeerIni(ByVal FicheroINI As String, ByVal Seccion As String, _
ByVal Clave As String, Optional ByVal ValorDefault As String) As String
  Dim lpString As String
  Dim LTmp As Long
  Dim sRetVal As String
  On Local Error GoTo ErrorLeerIni
  If IsMissing(ValorDefault) Then
    lpString = ""
  Else
    lpString = ValorDefault
  End If
  sRetVal = String$(255, 0)
  LTmp = GetPrivateProfileString(Seccion, Clave, _
  lpString, sRetVal, Len(sRetVal), FicheroINI)
  If LTmp = 0 Then
    LeerIni = lpString
  Else
    LeerIni = Left(sRetVal, LTmp)
  End If
  Exit Function
ErrorLeerIni:
  MsgBox Err.Number & ". " & Err.Description, vbCritical
  Err.Clear
End Function
 

Ejemplo para guardar y leer el alto y ancho del form1:

Código vb:

'               fichero       seccion    clave   valor a guardar
  GuardarIni "C:\Config.ini", "Ventanas", "F1Alto", Form1.Height
  GuardarIni "C:\Config.ini", "Ventanas", "F1Ancho", Form1.Width
 

En el fichero ini se guardaría:

Código :

[Ventanas]
F1Alto=3500
F1Ancho=4200
 

El fichero ini se crea automáticamente al guardar un dato en el.

Para devolver su tamaño a la ventana pondríamos:

Código vb:

'                                fichero     seccion    clave   valor por defecto
  Form1.Height = LeerIni ("C:\Config.ini", "Ventanas", "F1Alto", Form1.Height)
  Form1.Width = LeerIni ("C:\Config.ini", "Ventanas", "F1Ancho", Form1.Width)
 

Como veis, pongo como valores por defecto el actual ancho y alto de la ventana, de modo que si no existen valores guardados en el fichero .INI, dejamos la ventana con su tamaño original.

Como muchos sabrán, todos los valores se pueden poner como variables o textuamente como he hecho yo, además de que se pueden guardar textos, no solo valores numéricos:
Ejm:

Código vb:

Fichero = App.Path & "\Config.ini"
  Seccion = "Ventanas"
  Clave = "F1Titulo"
  Valor = Form1.Caption
  GuardarIni Fichero, Seccion, Clave, Valor
 

Espero que esto anime a muchos a usar este tipo de ficheros tan cómodos. Una vez que tienes las 2 funciones, guardar y leer datos es muy simple, y al ser un fichero de texto se puede editar fácilmente con el bloc de notas de windows.

Saludos

[McBlink]

Muchisimas gracias a ambos.. tengo un par de dudas que me surgieron de éste codigo..

la prima es todo el codigo grande del principio donde lo coloco? (es una duda que tuve estos dias) osea tiene que ir dentro del Form1_Load() o puede ir fuera de eso? o donde es lo correcto..?

la otra es, una ves creado el archivo INI con 2 datos por ejemplo, al agregarle mas datos se borran los anteriores o como es?

Saludos y muchas gracias!

[pkj]

El código puedes ponerlo al comienzo del todo del código del formulario, si solo usas un formulario, pero lo mejor es ponerlo en un modulo y podrás usarlo desde cualquier formulario de la aplicación.

Por otro lado, los datos del ini nunca se borran.
Si guardas la misma clave 2 veces, la segunda vez sobreescribes el valor que había.
Si metes nuevos datos se añaden en la sección correspondiente sin afectar a los datos anteriores.

Feliz Navidad

[McBlink]

ah buenisimo! mil gracias! me voy a poner a leer sobre los modulos..

Saludos y FELIZ AÑO 2010!

[pkj]

Lo de los módulos no es muy complicado, al menos los módulos normales.

En caso de poner en código p.ej. en el Form1 y querer usarlo desde el Form2, solo hay que declararlo como Public o, como he hecho yo, no añadir Private al comienzo de la declaración.
La cuestión es que para usarlo desde el Form2 tienes que incluir delante de la llamada el nombre del formulario que contiene la sub o función que quieres ejecutar.
Ej:
Form1.GuardarIni blablabla...

Si en lugar de eso, copias el código en un módulo normal (Proyecto/Agregar Modulo), las constantes, variables, subs y funciones que declares como públicas (o no pongas Private) se podrán usar desde cualquier sitio sin tener que incluir el nombre del módulo:
GuardarIni blablabla...

Que se dé bien.

[smoke001]

como te lo agradezco esto de cargar INI y salvar INI tenia dudas pero he probado tu codigo y me ha hido de maravilla en hora buena te agradezco

[zxs23]

Aqui dejo otro codigo haber si les sirve.

En un modulo bas

Código:

Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long

Public Sub GrabaINI(Archivo As String, Seccion As String, Clave As String, Text As String)
 WritePrivateProfileString Seccion, Clave, Text, Archivo
End Sub

Public Function LeeINI(Archivo As String, Seccion As String, Clave As String)
 Dim iRetLen As Integer
 Dim sRet As String
 sRet = Space(255)
 iRetLen = GetPrivateProfileString(Seccion, Clave, "", sRet, Len(sRet), Archivo)
 sRet = Left(sRet, iRetLen)
 LeeINI = sRet
End Function

Para utilizarlo en cualquier form

Código:

Dim xRuta As String

Private Sub Form_Load()
xRuta = App.Path & "\archivo.ini"
End Sub

Private Sub Command1_Click()

Text1 = LeeINI(xRuta, "datos", "nombre")
Text2 = LeeINI(xRuta, "datos", "apellido")

End Sub

Private Sub Command2_Click()
Call GrabaINI(xRuta, "datos", "nombre", "tu nombre")
Call GrabaINI(xRuta, "datos", "apellido", "tu apellido")
End Sub

[pkj]

He retocado las declaraciones del código que puse en mi primer mensaje de este post, ya que la función GuardarIni estaba declarada para recibir cadenas de texto y generaba errores cuando intentabas guardar una variable numérica. Un desliz de última hora.
Y dado que en los ejemplos se simula guardar el tamaño de un form directamente, seguramente esas mismas líneas ya generarían errores (no he llegado a probarlo).

Creo que esta vez ha quedado "a prueba de torpes". Osea, apta para mi propio uso.

Un saludo.