Ejecutar en segundo plano Vb6

[JuJoGuAl]

Buenas tardes amigos del foro, pues veran tengo un programa hecho en vb6 que controla el mouse y necesito que el programa quede corriendo aun si minimizo el form, o si coloco el HIDE en el load que pueda seguir controlando el mouse...

Como le hago????

Aclaro que tengo 2 pcs donde lo programo una con Windows Vista y la otra con Windows 7...

Porfavor ayudenme es un proyecto que debo entregar...

[pkj]

Depende de a que llames "controlar el ratón" y que método uses.

Yo tengo un programa que mueve el ratón con un gamepad y no tengo ningún problema para minimizarlo o esconderlo y seguir moviendo el ratón, ya que el programa no se detiene por estar minimizado u oculto.

Si no precisas más no creo que te dén una solución.

Saludos.

[JuJoGuAl]

pues en el KEY DOWN del form tengo esto:

Dim Point As POINTAPI
GetCursorPos Point

Select Case KeyCode
Case "40"
'MsgBox ("Abajo")
Call SetCursorPos(Point.X, Point.Y + 10)

Case "38"
'MsgBox ("Arriba")
Call SetCursorPos(Point.X, Point.Y - 10)

Case "37"
'MsgBox ("Izquierda")
Call SetCursorPos(Point.X - 10, Point.Y)

Case "39"
'MsgBox ("Derecha")
Call SetCursorPos(Point.X + 10, Point.Y)
End Select

que me sirve para mover el puntero ahora quiero seguir moviendolo aun cuando el programa este oculto ya que debo de utilizar los accesos directos del escritorio con mi programa...

[pkj]

Si quieres leer el teclado desde cualquier sitio tienes que usar algo como GetAsyncKeyState.

Algo asi:

Con un timer...

Código vb:

Option Explicit
Private Const constKeyDown = -32767
 
Const MOUSEEVENTF_MOVE = &H1 '  movimiento del mouse
Const MOUSEEVENTF_LEFTDOWN = &H2 '  botón izquierdo presionado
Const MOUSEEVENTF_LEFTUP = &H4 '  botón izquierdo soltado
Const MOUSEEVENTF_RIGHTDOWN = &H8 '  botón derecho presionado
Const MOUSEEVENTF_RIGHTUP = &H10 '  botón derecho soltado
Const MOUSEEVENTF_MIDDLEDOWN = &H20 '  botón central presionado
Const MOUSEEVENTF_MIDDLEUP = &H40 ' botón central soltado
Const MOUSEEVENTF_ABSOLUTE = &H8000 '  movimiento absoluto
 
Private Type POINTAPI
    X As Long
    Y As Long
End Type
 
Private Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Function SetCursorPos Lib "user32" (ByVal X As Long, ByVal Y As Long) As Long
Private Declare Sub mouse_event Lib "user32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
 
Private Sub Form_Load()
  Timer1.Interval = 50
  Timer1.Enabled = True
End Sub
 
Private Sub Timer1_Timer()
  Dim Point As POINTAPI
  Static Levantar_L As Integer
  Static Levantar_R As Integer
  
  If GetAsyncKeyState(40) <= constKeyDown Then
    'MsgBox ("Abajo")
    GetCursorPos Point
    SetCursorPos Point.X, Point.Y + 10
  End If
 
  If GetAsyncKeyState(38) <= constKeyDown Then
    'MsgBox ("Arriba")
    GetCursorPos Point
    SetCursorPos Point.X, Point.Y - 10
  End If
  
  If GetAsyncKeyState(37) <= constKeyDown Then
    'MsgBox ("Izquierda")
    GetCursorPos Point
    SetCursorPos Point.X - 10, Point.Y
  End If
  
  If GetAsyncKeyState(39) <= constKeyDown Then
    'MsgBox ("Derecha")
    GetCursorPos Point
    SetCursorPos Point.X + 10, Point.Y
  End If
 
  If GetAsyncKeyState(vbKeyZ) <= constKeyDown Then
    If Levantar_L = 0 Then
      mouse_event MOUSEEVENTF_LEFTDOWN Or MOUSEEVENTF_ABSOLUTE, 0, 0, 0, 0
      Levantar_L = 1
    End If
  Else
    If Levantar_L = 1 Then
      mouse_event MOUSEEVENTF_LEFTUP Or MOUSEEVENTF_ABSOLUTE, 0, 0, 0, 0
      Levantar_L = 0
    End If
    'MsgBox ("Z")
  End If
 
  If GetAsyncKeyState(vbKeyX) = constKeyDown Then
    If Levantar_R = 0 Then
      mouse_event MOUSEEVENTF_RIGHTDOWN Or MOUSEEVENTF_ABSOLUTE, 0, 0, 0, 0
      Levantar_R = 1
    End If
  Else
    If Levantar_R = 1 Then
      mouse_event MOUSEEVENTF_RIGHTUP Or MOUSEEVENTF_ABSOLUTE, 0, 0, 0, 0
      Levantar_R = 0
    End If
    'MsgBox ("X")
  End If
 
End Sub
 

Saludos

PD: Lo he editado para mejorarlo. Ahora funciona tambien en diagonal.

[JuJoGuAl]

Amigo no entiendes no quiero controlar el teclado solo el mouse con el teclado codigo que ya tengo lo que necesito ahora es que me corra en 2do plano es decir que aun q yo minize el programa puda seguir usandolo...

[JuJoGuAl]

Disculpa amigo estaba algo Cerrado =) jajajaja el programa funciona apesar de que esta minimizado, ahora como hago que al pasar el cursor sobre un icono lo pueda "clikear" con el enter u otra tecla?


Gracias y Disculpame lo grosero :(

[pkj]

Todos cometemos errores.

He modificado el código para pulsar los botones con las teclas Z y X.

No funciona muy bien, ya que no mantiene pulsado el botón bien, pero es lo mejor que sé hacer.
Las teclas se pulsan además de mover el cursor, de modo que si pasas sobre el escritorio se seleccionan los iconos segun mueves el cursor, y si pasas sobre un texto se desplaza arriba o abajo, etc...

Tambien se bloquea si intentas pinchar en maximizar o minimizar el programa, aunque eso tambien me pasa a mi usando un gamepad en lugar de las teclas.
Tuve que añadir un boton "Minimizar" dentro del form.

Saludos.

[JuJoGuAl]

Bueno amigo partiendo de tucodigo y algo que encontre en google este seria el Programa final:

Código vb:

Option Explicit
Private Const constKeyDown = -32767
Private Type POINTAPI
X As Long
Y As Long
End Type
 
Private Declare Sub mouse_event Lib "user32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
Private Const MOUSEEVENTF_LEFTDOWN = &H2
Private Const MOUSEEVENTF_LEFTUP = &H4
Private Const MOUSEEVENTF_MIDDLEDOWN = &H20
Private Const MOUSEEVENTF_MIDDLEUP = &H40
Private Const MOUSEEVENTF_MOVE = &H1
Private Const MOUSEEVENTF_RIGHTDOWN = &H8
Private Const MOUSEEVENTF_RIGHTUP = &H10
 
Private Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Function SetCursorPos Lib "user32" (ByVal X As Long, ByVal Y As Long) As Long
      
Private Sub Form_Load()
Timer1.Interval = 50
Timer1.Enabled = True
'Me.Hide
End Sub
 
Private Sub Timer1_Timer()
Dim Point As POINTAPI
         
If GetAsyncKeyState(40) <= constKeyDown Then
'MsgBox ("Abajo")
GetCursorPos Point
SetCursorPos Point.X, Point.Y + 10
End If
       
If GetAsyncKeyState(38) <= constKeyDown Then
'MsgBox ("Arriba")
GetCursorPos Point
SetCursorPos Point.X, Point.Y - 10
End If
If GetAsyncKeyState(37) <= constKeyDown Then
'MsgBox ("Izquierda")
GetCursorPos Point
SetCursorPos Point.X - 10, Point.Y
End If
If GetAsyncKeyState(39) <= constKeyDown Then
'MsgBox ("Derecha")
GetCursorPos Point
SetCursorPos Point.X + 10, Point.Y
End If
If GetAsyncKeyState(13) <= constKeyDown Then
'MsgBox ("Enter")
mouse_event MOUSEEVENTF_LEFTDOWN, 0, 0, 0, 0
mouse_event MOUSEEVENTF_LEFTUP, 0, 0, 0, 0
End If
If GetAsyncKeyState(32) <= constKeyDown Then
'MsgBox ("Espacio")
mouse_event MOUSEEVENTF_RIGHTDOWN, 0, 0, 0, 0
mouse_event MOUSEEVENTF_RIGHTUP, 0, 0, 0, 0
End If
End Sub
 

Lo unico que faltaria es hacerle Hide al Form para que quedara oculto...

o no se si habra una forma de que se coloque en la barra de tareas (como la Hora o los iconos del Antivirus..)

pero ya basicamente hace lo que buscaba..

Ah yo use ENTER y ESPACIO como CLIC y RightClic

[pkj]

Espero que te sirva para lo que quieres.

El tema de colocar el icono en la barra de tareas está aquí:

http://www.forosdelweb.com/1044463-post55.html

Suerte.

[JuJoGuAl]

Me sale Error de Compilacion (varaiable no Definida)

Me.PopupMenu MNU

[pkj]

No lo he mirado bien, pero es diferente al que yo uso. Imagino que o quitas esa linea o deberas crear un menu llamado MNU (o como quieras si luego lo cambias en el código del ejemplo) con opciones, como p.ej. restaurar la ventana. Seguramente ese CASE se activa al pinchar el boton derecho sobre el icono.

Lo que pasa es que no te aclaran que significa cada valor del select case.

Usa mi mousemove como base

Código vb:

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Const WM_LBUTTONDBLCLK = &H203
  Const WM_LBUTTONDOWN = &H201
  Const WM_LBUTTONUP = &H202
  Const WM_RBUTTONDBLCLK = &H206
  Const WM_RBUTTONDOWN = &H204
  Const WM_RBUTTONUP = &H205
  
  Dim msg As Long
  
  
  msg = X / Screen.TwipsPerPixelX
  
  Select Case msg
      
    Case WM_LBUTTONDBLCLK:
    'Doble click izquierdo...
    
    Case WM_LBUTTONDOWN:
    'Si pulsas el boton izquierdo...
 
 
    Case WM_LBUTTONUP:
    ' Si sueltas el boton izquierdo...
 
    
    Case WM_RBUTTONDBLCLK:
    ' etc...
 
    
    Case WM_RBUTTONDOWN:
    'Si pulsas el boton derecho...
    ' Aqui puedes mostrar un menu desplegable con popupmenu.
    ' Aunque en realidad puedes mostrarlo en el Case que quieras.
    ' Incluso puedes elegir si lo muestras al pulsar o al soltar el boton que sea.
 
 
    Case WM_RBUTTONUP:
  
  End Select
End Sub