Crear Array con Strings y que devuelva uno de los valores en random

[sven_uri]

Buenos dias gente,

Estoy aprendiendo un poco de vb y aun me falta algun empujoncito más con algun temario, haber si vosotros podeis decirme como perfeccionar.

Resulta que estoy intentando crear un array con valores random. Concretamente quiero crear un array de 7 espacios con un string en cada una (en mi caso poner las horas) y que me devuelva una de las horas.

Código vb:

Dim lista(6) As String
    
        lista(0) = "8:00"
        lista(1) = "8:20"
        lista(2) = "8.40"
        lista(3) = "9:00"
        lista(4) = "9:20"
        lista(5) = "9:40"
        lista(6) = "10:00"
 

Como aún desconozco como funciona de momento solo he planteado esto...cómo seguiria el código?

Ex: Si saliera que lista=3 me tendria que imprimir por pantalla, ya sea con MsgBox o en la tabla del excel, la hora 9:00.

Grácias por vuestro tiempo :)

Saludos.

[erbuson]

Hola, revisa el siguiente enlace de Recursos Visual Basic que va a despejar todas tus dudas respecto a Numeros Aleatorios

Un saludo

[sven_uri]

Buenas erbuson!

Tenia la esperanza que encontrarias mi mensaje jejeje xD.

La cosa es que generar un número aleatorio ya lo se hacer (a mi manera, pero funciona jejeje). El problema que tengo es que no se como a partir del numero aleatorio que obtenga, que instrucción tengo que escribir para decirle: Si sale 3 dame 9:00.

No sé si me he explicado con claridad.

Saludos :)

[erbuson]

Si entiendo lo que preguntas, estás encallado en lo mas facil:

NumeroAleatorio = Random ..... Tal como lo calcules

despues

Msgbox Lista(NumeroAleatorio)

Si no te he entendido bien, corrígeme

[sven_uri]

Buenas erbuson,

He echo lo siguiente, haber que te parece:

Código vb:

Dim A(0 To 6) As String
Dim R As Long
A(0) = "8.00"
A(1) = "8.20"
A(2) = "8.40"
A(3) = "9.00"
A(4) = "9.20"
A(5) = "9.40"
A(6) = "10.00"
R = Randomize(A)
 
Range("K2").Value = R
 

No me funciona esta claro jejeje, que me falla? Simplemente quiero que me de uno de estos arrays aleatoriamente.

Se te ocurre alguna manera sencilla?

Grácias.

[erbuson]

Se me ocurre, que lo mejor es que te explique como va lo de los número aleatorios porque veo que no lo tienes nada claro.

La funcion Rnd(1) devuelve el siguiente numero en una secuencia aleatoria
La funcion Randomize lo que hace es inicializar esta secuencia por loq eu no devuelve ningun resultado.

Rnd(1) te devuelve un numero decimal siempre menor de 1.

Para consegur un numero aleatorio entre 0 y 6 debe multiplicarse el valor aleatorio por 7 y tomar el entero ya que la parte entera al ser el multiplicador menor de 1 siempre estará entre 0 y 6

Esta es la solución a tu problema:

Código vb:

Dim A(0 To 6) As String
  Dim R As Long
  A(0) = "8.00"
  A(1) = "8.20"
  A(2) = "8.40"
  A(3) = "9.00"
  A(4) = "9.20"
  A(5) = "9.40"
  A(6) = "10.00"
  Randomize  'Inicializa el generador de semillas aleatorias
  R = Int(Rnd(1) * 7)
 
  Range("K2").Value = A(R)    'R será el índice de la matriz
 

Saludos

[sven_uri]

Genial! Ya lo he entendido todo!!

Vaya fallo más tonto el mio pero bueno...jejeje, disculpa mi ignorancia de novato :S.

Voy a seguir practicando.

Muchas grácias otra vez erbuson!

Saludos

[erbuson]

De nada, encantado de ayudar en algo, mientras no sea en Bases de Datos que por razones personales ya lo doy por imposible, en lo demás aqui me tienes.

Saludos

[sven_uri]

Ahora que lo pienso, si quisiera hacer lo mismo pero leyendo los strings des de las casillas del excel, como se haria? O sea el mismo ejemplo pero de esta manera (para no sobrecargar tanto el programa)??

Saludos!

[erbuson]

Hola, hay muchas maneras de hacerlo, la mas simple para que lo entiendas facilmente sería por ejemplo esta:

Código vb:

Public Sub DameHora()
 
  Dim A(0 To 6) As String
  Dim R As Long
  A(0) = Range("A1").Value
  A(1) = Range("A2").Value
  A(2) = Range("A3").Value
  A(3) = Range("A4").Value
  A(4) = Range("A5").Value
  A(5) = Range("A6").Value
  A(6) = Range("A7").Value
  Randomize  'Inicializa el generador de semillas aleatorias
  R = Int(Rnd(1) * 7)
 
  Range("K2").Value = A(R)    'R será el índice de la matriz
 
End Sub
 

Para hacerlo de una manera mas elegante, sería en un bucle For Next

Código vb:

Public Sub DameHora()
 
  Dim A(0 To 6) As String
  Dim R As Long, I as Integer
  For I = 0 To 6
    A(I) = Range("A" & Cstr$(I+1)).Value
  Next
  Randomize  'Inicializa el generador de semillas aleatorias
  R = Int(Rnd(1) * 7)
 
  Range("K2").Value = A(R)    'R será el índice de la matriz
 
End Sub
 

Como puedes ver, el bucle va de 0 a 6 que son los indices de A pero I toma los valores de 1 a 7 (I+1) porque son uno mas en la hoja.

Saludos

[sven_uri]

Si si lo veo lo veo. Vaya, genial erbuson!

Que sepas que he aprendido más contigo con varios post que con 7 u 8 clases en la universidad.

Muchas grácias otra vez.

Hasta pronto! Un abrazo.

[sven_uri]

Por cierto, como podria crear un contador de tiempo de 1 minuto? Como seria una versión sencilla?

Saludos!

[sven_uri]

O sea, uno ultra sencillo que simplemente cuando apretara el boton se iniciara un contador y cuando llegara a 0 que parara lo que se esta haciendo actualmente. :S

[erbuson]

Hola, como pienso que te refieres a hacerlo desde Excel y en VBA, se me ocurre lo siguiente para hacerlo simplemente por código

Código vb:

Public Sub Cronometro()
  Dim HoraLimite As Date
  HoraLimite = DateAdd("s", 60, Now)    ' Ahora + 60 segundos
  Do
  Loop While HoraLimite > Now           'Mientras Ahora sea menor que HoraLimite
End Sub
 

Supongo que habrá otras maneras, ya se sabe que cada maestrillo tiene su librillo, pero así al vuelo se me ha ocurrido esta.

De todos modos, en realidad esto es una pausa de 60 segundos, ya que al estar en un bucle no efectua nada mas durante el proceso de éste.

Si el programa debe estar haciendo algo durante un minuto, debería buscarse otro modo de hacerlo, dependiendo de lo que haga el programa.

[erbuson]

Aqui te dejo una variante que podría utilizarse llámándolo de otro procedimiento para saber si debe terminarse el proceso.

Código vb:

Public Function Crono(Optional Segundos As Integer) As Boolean
  ' Funcion cronómetro que se utiliza de dos maneras.
  ' Crono 60  'Inicia el Cronometro para una duracion del 60 segundos
  ' Crono     'Devuelve Verdadero si ha llegado al limite de tiempo
  Static HoraLimite As Date
  If Segundos > 0 Then
    HoraLimite = DateAdd("s", Segundos, Now)    ' Ahora + Segundos
  Else
    If Now >= HoraLimite Then Crono = True
  End If
End Function
 
Public Sub PruebaCronometro()
  Crono 15   'Inicia el cronómetro durante 15 segundos
  Do
    ' En este bucle se efectuaría el proceso deseado
    ' comprobando si el crono ha llegado al limite para salir del bucle
    If Crono Then Exit Do
  Loop
End Sub
 

Saludos

[sven_uri]

Genial!

Y si quisiera hacer la gracia de que se viera como se va reduciendo el contador de 60 segundos a 0, cómo lo haria?

Es que he probado tus codigos y se me bloquea el excel hasta que pasan los 60segundos jajajaja, sera el bucle while?

Saludos! :D

[erbuson]

Hola, aunque no es perfecto, es la idea, así mas o menos funciona,

Código vb:

Public Function CronoCero(Optional Segundos As Integer) As String
  ' Si se le indica Segundos, activa el contador
  ' Siempre Devuelve los segundos que faltan
  Static HoraLimite As Date
  If Segundos > 0 Then HoraLimite = DateAdd("s", Segundos, Now)    ' Ahora + Segundos
  CronoCero = Format(HoraLimite - Now, "SS")
End Function
 
Public Sub PruebaCronometro()
  CronoCero 30   'Inicia el cronómetro durante 30 segundos
  Do
    ' En este bucle se efectuaría el proceso deseado
    ' comprobando si el crono ha llegado al limite para salir del bucle
    Range("A1") = CronoCero
    If Val(CronoCero) = 0 Then Exit Do
  Loop
  Range("A1") = ""
End Sub
 

Te comento que generalmente para esto se utilizaría un formulario con un Timer, pero he intentado solucionarlo así porque por lo que intuyo de momento estás utilizando sólo código.

En cuanto a lo del bloqueo, evidentemente es por el Bucle, por eso te había comentado que este 'crono' debe de ser llamado desde dentro del proceso que estás ejecutando.

Dependiendo de las necesidades, sería la manera de llamarlo. Ten presente que el Do/Loop bloque el sistema mientras no salgas del mismo con alguna instruccion adecuada.

Saludos

[sven_uri]

erbuson!

He creado un tema nuevo sobre visual basic, haber como lo ves jejeje.

El titulo es: Problemas cogiendo variables con un programa de un concurso.

Saludos y muchas gracias por todo!