Comprimir Cadena Ayuda Urgente!

[assdres]

Hola a todos. Necesito comprimir una cadena como esta:

1:11:26:1;1:22:60:1;1:8:18:1;1:8:18:1;1:8:18:1

a que quede así:

1:11:26:1;1:22:60:1;1:8:18:3

Cuando se repitan, cambie el último dígito.

Gracias!!

[pkj]

A ver que te parece...

Código vb:

Function Comprime(Cadena As String) As String
  Dim Matriz1() As String
  Dim Matriz2() As String
  Dim Cadena1 As String
  Dim Cadena2 As String
  Dim F As Long
  
  Matriz1 = Split(Cadena, ";")
  ReDim Matriz2(0)
  Matriz2(0) = Matriz1(0)
  For F = 1 To UBound(Matriz1)
    Cadena1 = Left$(Matriz1(F), InStrRev(Matriz1(F), ":"))
    Cadena2 = Left$(Matriz2(UBound(Matriz2)), InStrRev(Matriz2(UBound(Matriz2)), ":"))
    If Cadena1 = Cadena2 Then
      Matriz2(UBound(Matriz2)) = Cadena1 & Val(Right$(Matriz2(UBound(Matriz2)), Len(Matriz2(UBound(Matriz2))) - Len(Cadena1))) + Val(Right$(Matriz1(F), Len(Matriz1(F)) - Len(Cadena1)))
    Else
      ReDim Preserve Matriz2(UBound(Matriz2) + 1)
      Matriz2(UBound(Matriz2)) = Matriz1(F)
    End If
  Next F
  
  Comprime = Join(Matriz2, ";")
  
End Function
 

Permite sumar cuando ya se han sumado:

Tu ejemplo:
MsgBox Comprime("1:11:26:1;1:22:60:1;1:8:18:1;1:8:18:1;1: 8:18:1")
Resultado: 1:11:26:1;1:22:60:1;1:8:18:3

Apliación de sumas:
MsgBox Comprime("1:11:26:1;1:22:60:1;1:8:18:1;1:8:18:2;1:8:18:1")
Resultado: 1:11:26:1;1:22:60:1;1:8:18:4

Saludos

[assdres]

Muchas Gracias!!!! Es lo que necesitaba. No tengo palabras para agradecerte. En serio, estoy muy contento con esta página y con la comunidad de programadores.

Tengo otra duda, aunque me da hasta pena; cuando voy a importar archivos, lo hago de la siguiente forma:

'Cadena de conexión
CnOrigen.Open "DRIVER={Microsoft Text Driver (*.txt; *.csv)}; DBQ=" & ruta & ";Persist Security Info=False"
'Ejecutamos el recordset pasandole el archivo de texto en la cláusula From
RsOrigen.Open "select * from [" & arch & "]", CnOrigen, adOpenStatic, adLockReadOnly, adCmdText

Set DataGrid1.DataSource = RsOrigen

Pero en algunos computadores me importa con comas (,) y en otros con punto y coma (;). Esto a que se debe y como lo podré solucionar??

Muchas gracias!!!