comparar el contenido de 2 image diferentes

[dulcefmq]

Gracias por su atención;
Tengo 2 form: Form1 y Form2. Cada uno de ellos tiene 3 control image, en el Form1 cada Image tiene una figura ejemlo: Image1 =carro, Image2 =pelota y Image3=mesa.
Estas mismas figuras estan en los 3 control image de Form2, pero desordenadas, es decir Image1=pelota, Image2=mesa, Image3=carro. Y las muevo a voluntad mediante dragdrop.
Lo que requiero es ¿cómo hacer para que cuando las ubicaciones de las 3 imagenes de los 3 control image de Form2, coincidan con la ubicacion de las 3 imagenes de los 3 control image de Form1, de un aviso "beep" o ejecute otra rutina?

[erbuson]

Hola, no se si lo que pides es posible, pero te diré lo que hice yo en una ocasión en que para aprender simulé un juego e parejas.

Al cargar la imagen en en Image.Picture, ponia el nombre del archivo en el Image.Tag.

La propiedad Tag puede utilizarse para cualquier propósito que nos sea de utilidad.

De este modo al intercambiar con tu drag/drop la imagen, debes tambien intercambiar el .Tag con lo que después al comparar esta propiedad sabes realmente que imagen tienes cargada y si es la misma.

Si no me he expresado bien, dilo y lo comentamos.

Saludos

[dulcefmq]

Gracias estimado Eburson por tu sugerencia. Lo que he realizado es cargar el nombre del archivo desplazado con el drag a la propiedad Image1.Toltiptext, que me funciona cuando comparo con el Image2.Toltiptext. Es decir cuando comparo 2 Image diferentes no indexados.Sin embargo, cuando se trata de Image indexados es decir Image1(0), Image1(1), etc. y realizo la operación de cargar la ruta del archivo cargado en la propiedad . Toltiptext de ambos Image1(x) indexados para compararlos, arroja que no son iguales porque el .Toltiptext del Image(x) indexado donde cargo el path del archivo agrega al path números adicionales, por lo que nunca coinciden, ambos .toltiptext donde se cargaron el path de los archivos.
Sin embargo probare cargando el path de ambos archivos ubicados en Image1 indexados, cargandolos en la propiedad .tag de cada uno de llos y comparando. Veremos que sucede ?

Con gratitud,

Felipe

[erbuson]

Hola, lo de añadir números adicionales me parece que no tiene mucho sentido ya que tu cargas el fichero y tu pones el tooltip, aunque se trate de imagenes indexadas, por lo que debe tratarse de algún lapsus en el código.

Piensa que realmente lo importante no es la imagen en si sino el contenido de la variable.

Ignoro si las imágenes las cargas en tiempo de diseño o en tiempo de ejecución pero realmente tiene que dar lo mismo.

Supongamos tus ejemplos.

Image1.Tag = "carro"
Image2.Tag = "pelota"
Image3.Tag = "mesa"

Image4(0).Tag = "carro"
Image4(1).Tag = "pelota"
Image4(2).Tag = "mesa"

Cuando intercambias el .Picture en el Drag/Drop, debes intercambiar su ,Tag y de este modo el Picture en si no es mas que un efecto óptico ya que tu comparación se basa en el .Tag

Pienso que debería funcionar por lo que algo esta fallando pero tiene que ser un simple error de lógica.

Si no termina de andar, pega el código donde cargas la imagen y el codigo cuando haces el Drag/Drop y le doy un vistazo.

Saludos

[dulcefmq]

En el Form1: se ubican 3 control Image1(index) medianos conteniendo 3 figuras desordenadas.
Las mismas figuras estan contenidas de manera ordenada en 3 Image2(index) más pequeños.
[B]La tarea consiste en ordenar las 3 figuras del Image1(index) mediante dragdrop, y al lograrlo y coincidir con las del Image2(index) se pueda dar una alarma o ejecutir otra rutina.[/B]

ADJUNTO CODIGO REALIZADO, GRACIAS POR SU ATENCIÓN Y APOYO.

Option Explicit
Dim imagen As Object
Dim nn As Integer

Private Sub Form_Load()
Dim x As Integer
Dim nomfig As String
Image1(0).Picture = LoadPicture("D:\VB\prac\e\fg3.jpg")
Image1(1).Picture = LoadPicture("D:\VB\prac\e\fg1.jpg")
Image1(2).Picture = LoadPicture("D:\VB\prac\e\fg2.jpg")

For x = 0 To 2
nomfig = App.Path & "\fg" & x & ".jpg"
Image2(x) = LoadPicture(nomfig)
Next x
End Sub

Private Sub Image1_DragDrop(Index As Integer, Source As Control, x As Single, Y As Single)

Set imagen = Image1(Index).Picture
If nn = 0 Then
Image1(Index) = Source.Picture
Source.Picture = imagen
ElseIf nn = 1 Then
Image1(Index) = Source.Picture
Source.Picture = imagen
ElseIf nn = 2 Then
Image1(Index) = Source.Picture
Source.Picture = imagen
End If

End Sub
Private Sub Image1_MouseDown(Index As Integer, Button As Integer, Shift As Integer, x As Single, Y As Single)
nn = Image1(Index).Index
If Button = 1 Then
Image1(Index).Drag
End If
End Sub


Felipe

[pkj]

No sé como lo haces, pero si arrastras los pictures como imagino, moviendo el contenido pero no cambiando de sitio el propio picture, podrías comparar las imágenes como cadenas de texto y contar las que coinciden:

Código vb:

Private Declare Function GetBitmapBits Lib "gdi32" _
    (ByVal hBitmap As Long, ByVal dwCount As Long, _
    lpBits As Any) As Long
 
Private Declare Function GetObject Lib "gdi32" Alias _
    "GetObjectA" (ByVal hObject As Long, ByVal nCount _
    As Long, lpObject As Any) As Long
 
Private Type BITMAP
      bmType As Long
      bmWidth As Long
      bmHeight As Long
      bmWidthBytes As Long
      bmPlanes As Integer
      bmBitsPixel As Integer
      bmBits As Long
End Type
 
Private Function PictureToString(pic As PictureBox) As String
 
      Dim tBitmap As BITMAP
      Dim bPicBytes() As Byte
      Dim lByteLen As Long
      GetObject Picture1.Image.Handle, Len(tBitmap), tBitmap
      lByteLen = tBitmap.bmWidthBytes * tBitmap.bmHeight
      ReDim bPicBytes(1 To lByteLen)
      GetBitmapBits pic.Picture.Handle, UBound(bPicBytes), bPicBytes(1)
       
      PictureToString = bPicBytes
End Function
 
Private Function ComparaPics(Pic1 As PictureBox, Pic2 As PictureBox) As Boolean
  Dim strPic1 As String
  Dim strPic2 As String
  
  strPic1 = PictureToString(Pic1)
  strPic2 = PictureToString(Pic2)
 
  ComparaPics = (strPic1 = strPic2)
 
End Function
 

Y cuando desplaces un picture comparas todos.

Dim Iguales As Integer
If ComparaPics(Form1.Picture1, Form2.Picture1) Then iguales = iguales + 1
If ComparaPics(Form1.Picture2, Form2.Picture2) Then iguales = iguales + 1
If ComparaPics(Form1.Picture3, Form2.Picture3) Then iguales = iguales + 1
If iguales=3 Then Msgbox "Completado"

Saludos

[erbuson]

Hola, siento insistir en los mismo, pero creo que lo mejor es utilizar la propiedad tag para controlar la imagen que tienes en el Image, después comparas la misma y si son iguales BINGO

Image1(0).Picture = LoadPicture("D:\VB\prac\e\fg3.jpg")
Image1(0).Tag = "fg3.jpg"

nomfig = App.Path & "\fg" & x & ".jpg"
Image2(x) = LoadPicture(nomfig)
Image2(x).Tag = "fg" & x & ".jpg"

Cuando hagas el Drag/Drop como te decia, intercambia ademas de la Imagen el TAG

Compara después la coincidencia de los TAG

Saludos

[pkj]

Hay un fallo en mi código, y como la política del foro ha cambiado y no puedo editar mis propios mensajes, lo pondré aquí:

La línea:
GetObject Picture1.Image.Handle, Len(tBitmap), tBitmap

Debería ser:
GetObject Pic.Image.Handle, Len(tBitmap), tBitmap

Saludos

PD: Aprovecho que aún puedo editar para rectificar.

Pues no... parece ser que si cambio esa línea no funciona y no veo el por qué.
Debe existir un Picture1 y la línea debe ser como antes:

GetObject Picture1.Image.Handle, Len(tBitmap), tBitmap

O cambiar por otro picture, pero claro, un picture que exista.

GetObject Picture4.Image.Handle, Len(tBitmap), tBitmap

[erbuson]

Hola pkj:

Fantástico el código para comparación de Imágenes, pero tal vez el problema esta en que según el mensaje de Felipe, o por lo que creo interpretar en su código las imágenes no son realmente las mismas ya que indica que unas son mas pequeñas e imgino que no se trata de que sea mas pequeño el Control/Contenedor sino la imagen propiamente.

De ser así realmente la comparación no creo que funcione ya que en realidad se trata de imágenes distintas.

Esperemos sus comentarios aclarando el tema o indicando algo al respecto.

Saludos

[pkj]

Como bien dices, erbuson, el método más barato es el de guardar una referencia en el tag, ya sea el nombre del fichero como un número o cualquier cosa que distinga una imagen de otra, y luego solo comparar los valores.
Yo solo intento darle otras opciones por si lo ve mas claro. Lo del tamaño de las imágenes no lo he visto, ya que no he leído todo con atención. Es posible que en ese caso no sirva el sistema.

Saludos

[dulcefmq]

Estimado Erbuson no se si estará bien el código en el queintentocomparar mediante "Tags". dado quehe probado su propuesta y no funciona, suena el "beep" en cuanto se traslada una imagen del Image1(0) al Image1(1), más no cuando ambas Imágenes coinciden.
Hay que considerar que el el Image2(index) que son más pequeñas, las mismas imágenes, estan ordenadas; en Image2(0)= "árbol", Image2(1) = "bicicleta", Image2(2)="casa" y permanecen asi constantemente.
Sin embargo es el Image1(index) el que traslada imágenes y por lotanto debe sonar el "Beep" cuando a Image1(0) se traslade el "árbol", a Image1(1) se traslade "Bicicleta", y a Image1(2) se traslade "casa". Lo que no sucede suena el Beep sin considerar esta situación ¿ ... ?

Private Sub Form_Load()
Dim x As Integer
Dim nomfig As String
Image1(0).Picture = LoadPicture("D:\VB\prac\e\fg3.jpg")
Image1(0).Tag = "fg3.jpg"
Image1(1).Picture = LoadPicture("D:\VB\prac\e\fg1.jpg")
Image1(1).Tag = "fg1.jpg"
Image1(2).Picture = LoadPicture("D:\VB\prac\e\fg2.jpg")
Image1(2).Tag = "fg2.jpg"

For x = 0 To 2
nomfig = App.Path & "\fg" & x & ".jpg"
Image2(x) = LoadPicture(nomfig)
Image2(x).Tag="fg" & x & ".jpg"
Next x
End Sub

Private Sub Image1_DragDrop(Index As Integer, Source As Control, x As Single, Y As Single)

Set imagen = Image1(Index).Picture
If nn = 0 Then
Image1(Index) = Source.Picture
Source.Picture = imagen
if Image1(index).Tag = Image2(nn).Tag="fg" & x & ".jpg" Then
beep
End if ElseIf nn = 1 Then
Image1(Index) = Source.Picture
Source.Picture = imagen
if Image1(index).Tag = Image2(nn).Tag="fg" & x & ".jpg" Then
beep
End if ElseIf nn = 2 Then
Image1(Index) = Source.Picture
Source.Picture = imagen
if Image1(index).Tag = Image2(nn).Tag="fg" & x & ".jpg" Then
beep
End if
End If

End Sub
Private Sub Image1_MouseDown(Index As Integer, Button As Integer, Shift As Integer, x As Single, Y As Single)
nn = Image1(Index).Index
If Button = 1 Then
Image1(Index).Drag
End If
End Sub


Seguiré intentando ...

Felipe

[pkj]

Intentando seguir tu código me ha quedado esto que parece funcionar, aunque seguramente se puede mejorar.

Código vb:

Option Explicit
 
Private Sub Form_Load()
  Dim x As Integer
  Dim nomfig As String
  Image1(0).Picture = LoadPicture("fg2.jpg")
  Image1(0).Tag = "fg2.jpg"
  Image1(1).Picture = LoadPicture("fg0.jpg")
  Image1(1).Tag = "fg0.jpg"
  Image1(2).Picture = LoadPicture("fg1.jpg")
  Image1(2).Tag = "fg1.jpg"
  
  For x = 0 To 2
    nomfig = App.Path & "\fg" & x & ".jpg"
    Image2(x) = LoadPicture(nomfig)
    Image2(x).Tag = "fg" & x & ".jpg"
  Next x
End Sub
 
Private Sub Image1_DragDrop(Index As Integer, Source As Control, x As Single, Y As Single)
  Dim eltag As String
  Dim imagen As Object
  eltag = Image1(Index).Tag
  Set imagen = Image1(Index).Picture
  Image1(Index).Picture = Source.Picture
  Image1(Index).Tag = Source.Tag
  Source.Picture = imagen
  Source.Tag = eltag
  Dim f As Integer
  For f = 0 To 2
    If Image1(f).Tag <> Image2(f).Tag Then Exit For
  Next f
  If f = 3 Then MsgBox "encontrado"
End Sub
Private Sub Image1_MouseDown(Index As Integer, Button As Integer, Shift As Integer, x As Single, Y As Single)
  If Button = 1 Then
    Image1(Index).Drag
  End If
End Sub
 

Saludos

[dulcefmq]

Hola estimado Erbuson

Tu recomendación funcionó muy bien,

Muchas Gracias, muy reconocido, estaremos en contacto.

Felipe

[dulcefmq]

Hola estimado Erbuson

La sugerencia de los Tags funcionó, excelente

Muy agradecido, estamos en contacto.

Mi especial reconocimiento, hasta pronto.

Felipe