Aportación: Mostrar un mensaje con temporizador

[erbuson]

Hola, hoy me ha surgido esta necesidad y se me ha ocurrido la siguiente idea, aquí la dejo por si sirve de ayuda a alguien:

La idea es mostrar un mensaje de error, aviso, etc evitando el MsgBox y tener que pulsar Aceptar, agilizando el proceso.

Para el ejemplo se necesita crear un Formulario con dos Command, un Timer con el nombre msgTimer y un Label con el nombre msgLabel, por supuesto la posición, colores y tamaño del label a gusto del usuario.

Código vb:

Option Explicit
 
Private Sub Command1_Click()
  msgLabel = "Mensaje de prueba en el Command Uno"
End Sub
 
Private Sub Command2_Click()
  msgLabel = "Mensaje de prueba en el Command Dos"
End Sub
 
Private Sub Form_Load()
  ' En la carga del formulario, ajustamos los valores y deshabilitamos el Timer
  msgTimer.Enabled = False    ' Timer detenido
  msgTimer.Interval = 5000    ' Pausa 5 segundos
  msgLabel.Caption = ""       ' Mensaje Borrado
  msgLabel.Visible = False    ' Mensaje Oculto
End Sub
 
Private Sub msgLabel_Change()
  If msgLabel.Caption = "" Then
    ' Mensaje en blanco, detener temporizador, ocultar mensaje
    msgTimer.Enabled = False
    msgLabel.Visible = False
  Else
    ' Mensaje con datos, activar temporizador, mostrar mensaje
    msgTimer.Enabled = False  'Primero desactivamos para detenerlo
    msgTimer.Enabled = True
    msgLabel.Visible = True
  End If
End Sub
 
Private Sub msgTimer_Timer()
  ' Llegado al tiempo, borramos mensaje
  msgLabel.Caption = ""
End Sub
 

Espero que a alguien le sea de utilidad.

Saludos

[pkj]

Viendo tu código y al darme cuenta de que el mensaje aparece dentro del form, se me ha ocurrido una idea para mostrar un mensaje en una ventana externa sin crear un nuevo formulario. Quizá le interese a alguien experimentar con ello.

He tenido que añadir una llamada a una api, pero el resultado puede valer la pena.

Con un poco más de código se puede hacer siempre visible o que se pueda arrastrar con el ratón, pero de momento esto es lo que he hecho.

Crear un formulario con un timer llamado msgTimer. Añadir un frame (Frame1), y dentro de ese frame 2 labels y un commandbutton (Label1, Label2 y Command1)
Añadir otro CommandButton fuera del frame (Command2)

Y este código:

Código vb:

Option Explicit
Dim DuracionMensajes As Integer
Dim ContadorDuracion As Integer
Private Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hwndNewParent As Long) As Long
 
Private Sub Command1_Click()
' este command esta dentro del frame
' y sirve para cerrar la ventana
  ContadorDuracion = DuracionMensajes - 1
  msgTimer_Timer
End Sub
 
Private Sub Command2_Click()
  ' este timer esta en el form para probar el mensaje
  SetParent Frame1.hWnd, 0
  Frame1.Visible = True
  Frame1.Top = (Screen.Height - Frame1.Height) / 2
  Frame1.Left = (Screen.Width - Frame1.Width) / 2
  msgTimer.Enabled = True
End Sub
 
Private Sub Form_Load()
  msgTimer.Enabled = False
  msgTimer.Interval = 1000
  DuracionMensajes = 5 ' mostraremos el mensaje 5 segundos
  Frame1.Visible = False
  Frame1.Caption = "Aviso"
  Label1.Caption = "Aqui tu mensaje"
  Label2.Caption = CStr(DuracionMensajes) ' Este label muestra la cuenta atras
  Command2.Caption = "Mostrar mensaje"
  Command1.Caption = "Aceptar"
End Sub
 
Private Sub msgTimer_Timer()
  ContadorDuracion = ContadorDuracion + 1
  Label2.Caption = DuracionMensajes - ContadorDuracion
  If ContadorDuracion >= DuracionMensajes Then
    Frame1.Visible = False
    SetParent Frame1.hWnd, Me.hWnd
    msgTimer.Enabled = False
    ContadorDuracion = 0
    Label2.Caption = CStr(DuracionMensajes) ' Este label muestra la cuenta atras
  End If
End Sub
 

Saludos

PD: Lo bueno de este método es que puedes tener minimizado el formulario y mostrar el mensaje sin restaurar el formulario.

[-rommel_]

claro el ejemplo de erbuson es parecido a los mensajes a USuarios que hace el SAP... buen aporte amigo...

[pkj]

Por mi parte solo quería ampliar un poco las posibilidades.
Por supuesto en ningún caso menospreciar el esfuerzo del compañero Erbuson que se merece un aplauso por su dedicación y paciencia demostradas.

Saludos

[erbuson]

Muchas gracias amigo pkj, ante todo, que te quede claro que en ningún momento he pensado que menospreciabas mi trabajo, es más, con tu inestimable ayuda la función puede tener una gran mejora y con tu permiso la dejo de esta manera:

Para que funcione el código se necesitará un Frame llamado msgFrame, un Label dentro de msgFrame llamado msgLabel y un Timer llamado msgTimer

Código vb:

Option Explicit
 
Private Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hwndNewParent As Long) As Long
 
Private Sub msgMensaje(Optional Mensaje As String, _
                       Optional Segundos As Integer = 5, _
                       Optional Objeto As Variant, _
                       Optional Centrado As Boolean = False)
  ' Rutina para mostrar u ocultar el mensaje, todos los parámetros son Opcionales
  ' la simple llamada de msgMensaje sin parámetros, lo inicializará
  
  ' Detenemos Temporizador, Ajustamos intervalo, Ocultamos mensaje
  msgTimer.Enabled = False
  msgTimer.Interval = Segundos * 1000
  msgFrame.Visible = False
  
  ' Ajustamos el tamaño del Frame exactamente con el Label (Esto no es necesario)
  msgFrame.Width = msgLabel.Width
  msgFrame.Height = msgLabel.Height
  msgLabel.Move 0, 0
  
  ' Anclamos el frame al Objeto que opcionalmente le indiquemos
  If IsObject(Objeto) Then
    SetParent msgFrame.hWnd, Objeto.hWnd
    ' Si deseamos el objeto centrado lo centramos
    If Centrado Then
      msgFrame.Move (Objeto.Width - msgFrame.Width) / 2, (Objeto.Height - msgFrame.Height) / 2
    Else
      msgFrame.Move 0, 0
    End If
  End If
  
  ' Si hay mensaje lo ponemos, hacemos Visible el Frame y activamos Temporizador
  If Mensaje <> "" Then
    msgLabel.Caption = Mensaje
    msgFrame.Visible = True
    msgTimer.Enabled = True
  End If
End Sub
 
Private Sub Form_Load()
  ' Inicializamos Temporizador y mensaje
  msgMensaje
End Sub
 
Private Sub msgTimer_Timer()
  ' Llegado al tiempo, borramos mensaje
  msgMensaje
End Sub
 

La siguiente es opcional, simplemente el Click en el label procederá a ocultar el mensaje, sin necesidad de un Command.

Código vb:

Private Sub msgLabel_Click()
  ' Click sobre el Label lo ocultará (Esta Sub es opcional)
  msgMensaje
End Sub
 

La llamada al mismo es bastante intuitiva por los nombres definidos en la Sub, pero unos ejemplos serían:

msgMensaje "Este es el mensaje a visualizar", , MSFlexGrid1, True
msgMensaje "Este es el mensaje a visualizar", , Form1, True
msgMensaje "Este es el mensaje a visualizar", 3, Picture1


IMPORTANTE Recordad que el Objeto al que se puede 'Anclar' el Frame debe tener la propiedad hWnd o de lo contrario se producirá un error.

Saludos

[carnero]

Que son secos, una pregunta ustedes trabajan en visual basic ???? O es solo por amor al arte.

Yo soy estudiante, lo aprendi "por obligacion" pero me gusta la programacion es un arte.
¿ustedes a que se dedican?

[pkj]

Amigo Carnero, yo soy camionero. Y es que odio pensar por obligación.
Programar es mi hobby por culpa de las mujeres y gracias a las mujeres mi vida es ahora muy tranquila acompañado de mi fiel PC.

Al amigo Erbuson solo decirle que confiaba en que te parecería interesante el sistema, y que la adaptación del código a tu gusto era lo esperado.

Solo añadir (para dar ideas) que esa api la uso yo en un programa que absorve ventanas que están estorbando en el escritorio pero que están procesando algo y no quieres cerrar, como un compresor de video. Una especie de escritorio virtual donde puedes guardar y manejar los programas.
Así luego escondo mi programa y se esconde todo con él. Cuando me parece los libero y vuelven al escritorio.

Por mi parte aportaría alguna sub, como una que auto-ajusta el tamaño de los controles al formulario, pero me temo que no tenga paciencia para solucionar después todas las dudas.
Además no es mágico y la gente parece esperar magia muchas veces.
También mi experiencia al regalar mi PKJ-Player (la niña de mis ojos, literalmente porque me he dejado media vista en el) y ver el poco interés de la gente, me hace pensar que solo pierdo mi tiempo en esos casos.

Saludos