Añadir funcionalidad a todos los textBox de un programa

[fantasma21]

Hola a todos,
Tengo un programa con varios Forms y unos cuantos textbox...
Me acabo de dar cuenta, de que tengo que cambiar el color del fondo de los textbox al recibir el FOCO.

Hay alguna manera de añadir esa funcionalidad a todos los textbox sin ir uno a uno??

Gracias
Saludos

[lokoman]

Hola!!
Pues se me ocurrió esto:
• Pones en la propiedad "TAG" de cada TextBox el valor "txt" (sin comillas)
• Agregas un Timer al Form, con su propiedad "INTERVAL" en 60 y agregas el codigo:

Código vb:

Private Sub Timer_Timer()
    For Each Control In Form1.Controls
        If Control.Tag = "txt" Then
            If Control.Text <> Empty Then
                Control.BackColor = &HC0FFC0
            Else
                Control.BackColor = &HFFFFFF
            End If
        End If
    Next
End Sub
 

Todos los TexBox que tengan la propiedad TAG=txt, obtendrán un color al momento que se DIGITE algo en ellos o si TIENEN algun valor, pero no ocurrirá con el GOTFOCUS

[fantasma21]

Hola, gracias por tomarte la molestia de contestarme (no es muy habitual en este foro por lo que veo..).

Te comento, el problema esque eso tendría que ponerlo en todos los forms que tengo... y el problema de los timers es que gastan mucho CPU.

Yo lo que busco realmente es algo que se aplique a todos los textbox de un programa( con varios forms ) una sola vez al ejecutar el programa...

se podria hacer con un modulo o algo parecido?

Gracias

[JonathanB]

Saludos, estoy algo oxidado en VB6 pero puedes utilizar algo como esto (aún le falta que lo pulas)

Partimos de un proyecto Nuevo

Crea una nueva clase llamada clsAdvancedTextBox y añade el siguiente código:

Código vb:

Option Explicit
 
Public WithEvents txtBox As TextBox
 
Private Sub Class_Terminate()
    Set txtBox = Nothing
End Sub
 
Private Sub txtBox_GotFocus()
    txtBox.BackColor = vbRed
End Sub
 
Private Sub txtBox_LostFocus()
    txtBox.BackColor = vbWindowBackground
End Sub
 

Añade otra clase llamada clsAdvancedTextBoxCollection y añade el siguiente código:

Código vb:

Option Explicit
 
Private c As Collection
 
Public Sub AddTextBox(ByRef frmValue As Form)
    Dim txtBox As clsAdvancedTextBox
    Dim xControl As Control
    
    For Each xControl In frmValue.Controls
        If TypeOf xControl Is TextBox Then
            Set txtBox = New clsAdvancedTextBox
            Set txtBox.txtBox = xControl
            c.Add txtBox, xControl.Name
        End If
    Next
End Sub
 
Private Sub Class_Initialize()
    Set c = New Collection
End Sub
 
Private Sub Class_Terminate()
    Set c = Nothing
End Sub
 

Teniendo ya las clases, procedemos a agregar varios textbox al formulario, luego añade el siguiente código al Form1

Código vb:

Option Explicit
 
Dim clsTextBoxCollection As clsAdvancedTextBoxCollection
 
Private Sub Form_Load()
    Set clsTextBoxCollection  = New clsAdvancedTextBoxCollection
    clsTextBoxCollection.AddTextBox Form1
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    Set clsTextBoxCollection  = Nothing
End Sub
 

Cuando ejecutes el programa, te podrás dar cuenta que al recibir el foco en alguno de los textbox, su color de fondo será de color rojo :).

Espero que te haya sido de utilidad, y como te mencione a la clase le hace falta mas trabajo, simplemente tiene lo necesario para funcionar.

[fantasma21]

Eres un crack, ha funcionado.

bueno ahora me toca entender el codigo... :p

Muchas gracias.