Almacenamiento de varios registros.

[carlos79]

Buenas tardes estimados foristas :

Tengo una duda con relación al almacenamiento de varios registros. Tengo un list box en modo checked.... Cada vez que hago click en un check el valor que tiene asignado ese campo debe almacenarse en la base de datos.... Hasta aqui vamos bien...

Les anexo el código :

Dim cnn As ADODB.Connection
Dim rst As ADODB.Recordset
Dim sql$

Set cnn = New ADODB.Connection
cnn.ConnectionString = "DRIVER={mysql odbc 3.51 driver};" _
& "SERVER=999999;" _
& "Database=eeeeeeeee;" _
& "UID=segui;" _
& "password= vmsidmosdv;" _
& "port=3306;option3 "

cnn.Open

Set rst = New ADODB.Recordset

With rst
.CursorLocation = adUseClient
.CursorType = adOpenStatic
.LockType = adLockOptimistic
.Open "INSERT INTO tb_plan (cod_planif, cod_emp, cod_divi, id_audit, cod_audit, cod_prog, cod_tarea, cod_subta, tiempo) VALUES ('" & Val(Text6.Text) & "', '" & Val(Text7.Text) & "', '" & Val(Text15.Text) & "', '" & Val(Text16.Text) & "', '" & Val(Text18.Text) & "', '" & Val(Text9.Text) & "', '" & Val(Text10.Text) & "', '" & Val(Text11.Text) & "', '" & Val(Text12.Text) & "' )", cnn
End With


Hasta aqui vamos bien.... Pero imaginense lo lento que se pone el sistema cada vez que hago click en un checked del listbox... Se torna lento porque en cada click ejecuta la instrucción que les puse arriba....

Mi pregunta es la siguiente.... Como puedo hacer para que cuando el usuario elija 10 opciones estas se mantengan como en una variable y luego yo le de click a un botón que sea guardar y solo se haga una conexión al servidor y ahi se almacenen los 10 registros....

Estoy programando en visual basic 6 con base de datos en mysql.

Saludos.

Carlos.

[fradve]

Pues se me ocurre que crees una arreglo de estructuras con los campos que vas a almacenar y un contador como variable global, que cuando llegue a 10, lea todo lo almacenado en el arreglo de estrucutras y lo guarde en la base de datos.

[carlos79]

Exacto.... Algo así sería lo que quiero, pero te comento que no siempre puede ser un valor de 10.. pueden ser hasta 60 opciones....

Ese arreglo es lo que quiero hacer pero no se como... tendrás algún código por el cuál me pueda guiar ???

Gracias.

Carlos.

[fradve]

Claro puede ser la cantidad de registro que tú quieras, solo tienes que ir contando para irlos colocando en el arreglo para su posterior almacenamiento, así en un módulo define tu estructura:

Type Clientes
nombre as String
apellido as String
.
.
.
(los campos que sean)
End Type

y ahi mismo declaras el arreglo:

Dim aclientes(60) as Clientes

(el numero de registros pueder ponerlo tú)

la variable global bien la declaras en el módulo o en el formulario con el que trabajas:

Dim contador as Integer

para acceder a los miembros de la estructura, por ejemplo para colocar pedro en la posicion 0 del arreglo, y cada vez que agregues un registro incrementa el contador:

aclientes(contador).nombre="PEDRO"
contador = contador + 1

De ahi para leer basta con un for y los vas guardando en la basde de datos.

[carlos79]

hermano un millón de gracias por tu respuesta... Voy a intentar amoldarlo a mis requerimientos...

Lo que sucede es que mis conocimientos son extremadamente "BASICOS" en programación y es por ello la dificultad en comprender lo que me suministrastes....

Cualquier duda te pregunto de nuevo... de igual forma quisiera saber donde podré descargar un ejemplo ya que tengo como un mes con el desarrollo parado por esa problemática...

De nuevo un millón de gracias !!!

Carlos.

[carlos79]

Estimado amigo :

Desde ayer estuve probando lo que me enviastes pero no me sale... será que podrías darme una explicación extremadamente básica ???

Una explicación algo así como para "DUMMIES" jejejeje.....

Un millón de gracias y disculpa tanto fastidio !!!

Saludos.

Carlos.

[pkj]

No controlo de ADOC y tal, pero imagino que de algún modo cada elemento seleccionado del listbox conlleva guardar varios datos diferentes en la base.

Creo que lo que fradve te sugiere es que guardes cada valor en una matriz de tipo definido por tí.
Para que lo tengas fácil te voy a hacer la mitad del trabajo de lo que yo creo que dice.
Así me entretengo y quzá te aclare la cosa.

Código vb:

Option Explicit
 
Private Type Clientes
  nombre as String
  apellido as String
.
.
.
  (los campos que sean)
End Type
 
Dim Tabla () As Clientes
 
Private Sub Form_Load()
  ' creamos el primer elemento
  Redim Tabla(0)
End Sub
 
'en el click del listbox creas un elemento para la matriz y guardas ahí todos los datos que hay que mandar despues.
 
private sub list1_click()
 
'primero puedes mirar si ya lo has añadido, si quieres poder actualizarlo
  dim f as long
  for f=0 to ubound(tabla) - 1
    ' si existe
    if tabla(f).nombre=nombreainsertar then
     ' lo actualizamos
      goto guardar
    endif 
  next f
 
  'si no existe con anterioridad
  'se guardan los valores en el último elemento de la tabla
   f=ubound(tabla)
  ' y preparamos ya el siguiente elemento de la tabla
  redim preserve Tabla(f+1)
 
guardar:
  tabla(f).nombre=nombreainsertar
  tabla(f).apellido=
  tabla(f)...
 
 
End sub
 

Después en un botón guardas los elementos de la tabla desde 0 hasta ubound(tabla)-1
Recuerda también en el botón reiniciar la tabla: Redim Tabla(0)

Espero haber ayudado además de pasar un rato entretenido.

Suerte

[fradve]

Claro que si eres de gran ayuda pkj está muy bien explicado tú codigo, solo una cosita no soy muy amigo de los goto(:-p) y la función con una pequeña modificación y para que no tome en cuenta los repetidos:

Código vb:

Private Sub List1_Click()
    Dim nombreainsertar As String
    Dim bandera As Boolean
    
    nombreainsertar = List1.Text
    For f = 0 To UBound(tabla) - 1
        If tabla(f).nombre = nombreainsertar Then
            bandera = True
            Exit For
        End If
    Next f
    
    If Not bandera Then
        f = UBound(tabla)
        tabla(f).nombre = nombreainsertar
        ReDim Preserve tabla(f + 1)
    Else
        MsgBox "El valor ya ha sido agregado"
    End If
End Sub
 

Una vez que hayas seleccionado todo los datos que quieras almacenar lees el arreglo y dando clic en el botón guardar vas a enviar elemento por elemento a la base de datos, así:

Código vb:

Sub guardar()
    cnn.Open 
 
    Set rst = New ADODB.Recordset
 
    For i = 0 To UBound(tabla) - 1
        With rst
            .CursorLocation = adUseClient
            .CursorType = adOpenStatic
            .LockType = adLockOptimistic
            .Open "INSERT INTO Clientes VALUES ('" & tabla(i).nombre & "')", cnn
        End With
    Next
    cnn.Close
End Sub
 

Este es solo un ejemplo, de ahi puedes adecuarlo a tus necesidades. Cualquier duda postealea

[carlos79]

Estimados amigos :

Yo creo que mejor explicación no he podido recibir...

Me parece excelente la capacidad para responder este tipo de interrogantes... Nuevamente los felicito !!!!

Saludos.

Carlos.

[carlos79]

Estimados amigos miren lo siguiente :

Option Explicit

Dim Tabla() As Clientes

Private Type Clientes
cod_producto as integer
producto as string
End Type


Private Sub List1_Click()

Dim bandera As Boolean
Dim f As Long
Dim i As Integer

For i = 0 To List1.ListCount - 1

If List1.Selected(i) = True Then
Text11.Text = List1.ItemData(i)
End If

Next

For i = 0 To UBound(Tabla) - 1
If Tabla(i).cod_producto = Text11.Text Then
bandera = True
Exit For
End If
Next i
If Not bandera Then
i = UBound(Tabla)
Tabla(i).cod_producto = Text11.Text
ReDim Preserve Tabla(i + 1)
Else
MsgBox "El valor ya ha sido agregado"
End If

End Sub


Private Sub Command6_Click()

Dim cnn As ADODB.Connection
Dim rst As ADODB.Recordset
Dim i As Long

On Error Resume Next

Set cnn = New ADODB.Connection
cnn.ConnectionString = "DRIVER={mysql odbc 3.51 driver};" _
& "SERVER=11.11.11.11;" _
& "Database=seg;" _
& "UID=segi;" _
& "password=dsfSFsdfSVsd;" _
& "port=3306;option3 "

cnn.Open

Set rst = New ADODB.Recordset

For i = 0 To UBound(Tabla) - 1
With rst
.CursorLocation = adUseClient
.CursorType = adOpenStatic
.LockType = adLockOptimistic
.Open "INSERT INTO tb_plan VALUES ('" & Tabla(i).cod_producto & "')", cnn


End With
Next
' cnn.Close

End Sub



Les explico como opera el control :

Yo cargo el listbox con productos... y le pongo como indice el código de ese artículo.... Cuando yo le hago click por ejemplo al producto "JAMON", en un control de texto me coloca el código de ese cliente (22)... Pero si elijo varios productos, en ese text box me va colocando uno por uno los códigos.

Que pasa... Cuando yo le de al botón "GRABAR" el debe agarrar TODOS los códigos que fuéron almacenados en la matriz e irlos pasando uno a uno con su descripción para almacenarlos a la base de datos...


No me genera ningun error en tiempo de ejecución pero cuando consulto la base de datos no me almacena valores... me pueden ayudar ??

Gracias y disculpen mi torpeza !!!

Saludos.

Carlos.

[bionet_x86]

y porque mejor no usas VALUE y una vez que tengas todo ok un boton guardar y asi te ahorras todo lo de la matris

[carlos79]

bueno poruqe imaginate... son muchos productos y muchos códigos... y es mejor usar una matriz porque un mismo cliente puede tener productos de limpieza, productos de higiene personal, legumbres, etc.. me explico ???

por eso es que recurro a la matriz para que despues que tenga TODO cargado, le de guardar y listo... pero no se por que razón cuando le digo guardar la tabla me queda en cero... esto lo vi presionando la tecla f8 para ir viendo linea por línea el problema !!!!

saludos.

Carlos.

[fradve]

mira ya probé el código, porque en verdad que se me hace raro que no te funcione o mejor dicho que no guarde entonces aqui te pongo el codigo que usé:

Todo esto primero:

Código vb:

Private Type Productos
    codigo As Integer
    nombre As String
End Type
 
Dim tabla() As Productos
 
Dim cn As ADODB.Connection
Dim res As ADODB.Recordset
Dim conexion As String
 

Luego:

el botón guardar solo llama a la función guardar

Código vb:

Private Sub Command2_Click()
    guardar
End Sub
 

Código vb:

Sub guardar()
    Set res = New ADODB.Recordset
 
    For i = 0 To UBound(tabla) - 1
        With res
            .ActiveConnection = cn
            .CursorLocation = adUseClient
            .CursorType = adOpenStatic
            .LockType = adLockOptimistic
            .Open "INSERT INTO productos VALUES (" & tabla(i).codigo & ",'" & tabla(i).nombre & "')"
        End With
    Next
    
    res.Open "SELECT * FROM productos"
    Set DataGrid1.DataSource = res
End Sub
 

en el load del formulario coloco esto:

Código vb:

Private Sub Form_Load()
    
    Set cn = New ADODB.Connection
    conexion = "driver={MySQL ODBC 3.51 Driver};" _
                        & "SERVER=localhost;" _
                        & "DATABASE=prueba;" _
                        & "UID=root;PWD=utm123;OPTION=3"
                            
    cn.ConnectionString = conexion
    cn.Open
    ReDim tabla(0)
    List1.AddItem "Jamón"
    List1.AddItem "Carne"
    List1.AddItem "Leche"
    List1.AddItem "Queso"
End Sub
 

En el evento clic de la lista va esto:

Código vb:

Private Sub List1_Click()
    Dim bandera As Boolean
    
    Text1.Text = List1.ListIndex
    For f = 0 To UBound(tabla) - 1
        If tabla(f).codigo = Val(Text1.Text) Then
            bandera = True
            Exit For
        End If
    Next f
    
    If Not bandera Then
        f = UBound(tabla)
        tabla(f).codigo = Val(Text1.Text)
        tabla(f).nombre = List1.Text
        ReDim Preserve tabla(f + 1)
    Else
        MsgBox "El valor ya ha sido agregado"
    End If
End Sub
 

y en el unload del formulario cierro la conexión así: cn.close.

Si te fijas en la funcion guardar hace referencia a un data grid, simplemente lo coloqué para visualizar los datos que se han guardado.

Y eso es todo, prueba y comentas lo que suceda

[carlos79]

AMIGO EXCELENTE JEJEJEJEJE........ AL FINNNNNNNNNNNNNNNNNN............. wao pensé que nunca solventaría la problemática... jejejeje.... estoy acomodando MUCHOS códigos que tenía con este problema... estaba trabajando de lo mas rudimentario... click en una opción... a guardar... click otra opción... a guardar jejeje... imaginate lo lente que estaba esto... ahora los tiempos de respuesta de mi software han mejorado considerablemente gracias a su apoyo !!!!

DE VERDAD que no tengo como agradecer esta segundota que me han hecho !!!!

Feliz tarde !!!

Saludos.

Carlos.:aplaus o: