[SOLUCIONADO] NAudio en Visual Basic .NET

[vistaero]

Hola, estoy intentando hacer unas cosillas básicas con una librería llamada NAudio que espero que alguien controle un poco.

Esta es la página oficial: http://naudio.codeplex.com/

La razón por la que necesito ayuda, es que los ejemplos que encuentro están en C#, y aunque use un conversor online de C# a VB, el código no funciona, y como no soy programador, no tengo mucha idea de cómo arreglar los fallos que Visual Studio me detecta.

Lo que quiero hacer es simple, un botón comienza la reproducción en bucle de un sonido, y un segundo botón comienza la reproducción en bucle de un segundo sonido sin interrumpir el primero.

La razón por la que acudo a NAudio, es que tal vez su reproducción en bucle no tiene pausas de milisegundos cada vez que el sonido empieza de nuevo, y que otras formas de reproducir audio en bucle padecen.

Si alguien sabe hacer esto y quiere un sonido con el que comprobar que no hay cortes, este es uno de los que voy a usar: https://www.dropbox.com/s/6t5ks8jrh8656uu/2010%20Hum.wav

Gracias de antemano.

[alexg88]

Hola de nuevo,

He conseguido reproducir tal y como lo quieres y parece que no se producen cortes.

Lo primero es crear una clase para soportar la reproducción en bucle (sacado de la documentación de NAudio).

Código vb:

Imports NAudio.Wave
 
Public Class LoopStream
    Inherits WaveStream
    Private sourceStream As WaveStream
 
    ''' <summary>
    ''' Creates a new Loop stream
    ''' </summary>
    ''' <param name="sourceStream">The stream to read from. Note: the Read method of this stream should return 0 when it reaches the end
    ''' or else we will not loop to the start again.</param>
    Public Sub New(sourceStream As WaveStream)
        Me.sourceStream = sourceStream
        Me.EnableLooping = True
    End Sub
 
    ''' <summary>
    ''' Use this to turn looping on or off
    ''' </summary>
    Public Property EnableLooping() As Boolean
        Get
            Return m_EnableLooping
        End Get
        Set(value As Boolean)
            m_EnableLooping = value
        End Set
    End Property
    Private m_EnableLooping As Boolean
 
    ''' <summary>
    ''' Return source stream's wave format
    ''' </summary>
    Public Overrides ReadOnly Property WaveFormat() As WaveFormat
        Get
            Return sourceStream.WaveFormat
        End Get
    End Property
 
    ''' <summary>
    ''' LoopStream simply returns
    ''' </summary>
    Public Overrides ReadOnly Property Length() As Long
        Get
            Return sourceStream.Length
        End Get
    End Property
 
    ''' <summary>
    ''' LoopStream simply passes on positioning to source stream
    ''' </summary>
    Public Overrides Property Position() As Long
        Get
            Return sourceStream.Position
        End Get
        Set(value As Long)
            sourceStream.Position = value
        End Set
    End Property
 
    Public Overrides Function Read(buffer As Byte(), offset As Integer, count As Integer) As Integer
        Dim totalBytesRead As Integer = 0
 
        While totalBytesRead < count
            Dim bytesRead As Integer = sourceStream.Read(buffer, offset + totalBytesRead, count - totalBytesRead)
            If bytesRead = 0 Then
                If sourceStream.Position = 0 OrElse Not EnableLooping Then
                    ' something wrong with the source stream
                    Exit While
                End If
                ' loop
                sourceStream.Position = 0
            End If
            totalBytesRead += bytesRead
        End While
        Return totalBytesRead
    End Function
End Class
 

Lo segundo es usar el código que reproduce los dos archivos.

Código vb:

Imports NAudio.Wave
 
 
Public Class Form1
 
    Private sound1 As WaveOut
    Private sound2 As WaveOut
 
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button2.Click
        If sound1 Is Nothing Then
            Dim reader As New WaveFileReader("media/test.wav")
            Dim looping As New LoopStream(reader)
            sound1 = New WaveOut()
            sound1.Init(looping)
            sound1.Play()
    End Sub
 
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button3.Click
        If sound2 Is Nothing Then
            Dim reader As New WaveFileReader("media/test1.wav")
            Dim looping As New LoopStream(reader)
            sound2 = New WaveOut()
            sound2.Init(looping)
            sound2.Play()
    End Sub
End Class
 

Espero que te sirva.

Un saludo.

[vistaero]

Oh sí, ¡funciona! jaja, perfecto, maravilloso.

Dices que lo encontraste en la documentación, aunque yo no encontré nada, ahora me siento un inútil buscando :P

Definitivamente solucionado, un resultado perfecto. ¡Muchísimas gracias!

[alexg88]

Buenas,

Lo encontre en la parte de documentación: http://naudio.codeplex.com/documentation, en el apartado "How do I ...?", subapartado "Implement Looped Playback".

El ejemplo está en C#, lo único que he hecho ha sido pasarlo a VB.NET.

Un saludo.

[vistaero]

Añado una anotación para quien tenga también un problemilla que acabo de tener.

Para detener un sonido, y que luego pueda volver a reproducirse, usar esto:

Código vb:

If Drum Is Nothing Then
            Else
                Drum.Stop()
                Drum.Dispose()
                Drum = Nothing
            End If
 

Cambiar Drum por el nombre del sonido que sea.

Edito: Parece que este tema prefiere mantenerse lejos de estar solucionado, ahora pretendo que un sonido en concreto no se reproduzca en bucle.

Imagino que lo que debo cambiar es lo que pone entre los paréntesis de aquí: Sonido.Init(looping)
Dejarlo en blanco era demasiado fácil para funcionar.

Espero no estar haciendo mal en continuar un un tema marcado como solucionado, desde luego me precipité bastante al pulsar ese botón.

Edito 2: Ahora sí está solucionado, sólo hay que cambiar looping por reader.