Comprimir los archivos de una carpeta por SEPARADO.

[davidalonsso05]

Buenos días!
Mi duda es como comprimir una carpeta con vb.net 2005, pero los archivos que esten dentro comprimirlos por separado.
Por ejemplo si la carpeta tiene 5 documentos, sin importar si son imagenes, .txt, .doc, etc. que me cree 5 archivos .zip en la misma carpeta, 1 por cada documento.
Hasta el momento tengo el siguiente codigo:

Código vb:

Imports System.IO
Imports System.IO.Directory
Imports System.IO.DirectoryInfo
Imports ionic.Zip
Imports Ionic.BZip2
Imports System.IO.Compression
 
Public Class Form1
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Try
 
            With FolderBrowserDialog1
                .Reset()
                .Description = " Seleccionar una carpeta "
                .SelectedPath = Environment.GetFolderPath(Environment.SpecialFolder.MyDocuments)
                .ShowNewFolderButton = False
                Dim ret As DialogResult = .ShowDialog
                If ret = Windows.Forms.DialogResult.OK Then
                    Dim nFiles As ObjectModel.ReadOnlyCollection(Of String)
                    nFiles = My.Computer.FileSystem.GetFiles(.SelectedPath)
                    TextBox1.Text = FolderBrowserDialog1.SelectedPath.ToString()
                    MsgBox("Total de archivos: " & CStr(nFiles.Count), _
                                            MsgBoxStyle.Information)
                End If
                .Dispose()
            End With
            Archivos()
        Catch oe As Exception
            MsgBox(oe.Message, MsgBoxStyle.Critical)
        End Try
    End Sub
 
    Public Sub Archivos()
        Dim folder As New DirectoryInfo(Me.TextBox1.Text)
 
        For Each file As FileInfo In folder.GetFiles()
            ListBox1.Items.Add(file.Name)
            
        Next
    End Sub
   
 
 
    Public Sub Comprimir()
        Dim txtFiles = Directory.GetFiles(Me.TextBox1.Text, "*", SearchOption.AllDirectories)
        Dim FileN As String = ListBox1.Items.ToString
        Using zip As ZipFile = New ZipFile()
            For Each currentFile As String In txtFiles
                zip.AddFile(currentFile, "")
                zip.Save(System.IO.Path.Combine(System.IO.Path.GetDirectoryName(Me.TextBox1.Text), System.IO.Path.GetFileNameWithoutExtension(currentFile) + ".zip"))
            Next
        End Using
    End Sub
 
    Private Sub Comprimir_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        If TextBox1.Text = "" Then
            MessageBox.Show("Ingrese una carpeta")
        Else
            Comprimir()
            MessageBox.Show("Carpeta comprimida")
        End If
 
 
    End Sub
End Class
 

Como podran ver, el usuario selecciona la carpeta, esta ruta se pasa al Textbox1

PERO se queda trabado el programa al momento de comprimir la carpeta y solo me comprime 2 archivos, en el primer .zip viene un documento y en el segundo viene, el primer documento y el que le sigue y se queda paralizado el programa...

Me habia comentado mi jefe que en este pedazo podia ir comprimiendo uno por uno:

Código vb:

Public Sub Archivos()
        Dim folder As New DirectoryInfo(Me.TextBox1.Text)
 
        For Each file As FileInfo In folder.GetFiles()
            'ListBox1.Items.Add(file.Name)
            'AQUI COMPRIMIR LOS ARCHIVOS
        Next
    End Sub
 

Pero no se como seria cualquier ayuda gracias!

[davidalonsso05]

Y no me guarda los archivos dentro de la carpeta seleccionada si no en la misma ruta que esta la carpeta por ejemplo:
C:\Mis Documentos\Prueba <--- la ruta de la carpeta y me los guarda los archivos
C:\Mis Documentos\Documentos.zip <--- en lugar de que venga dentro de la carpeta Prueba

[Malenko]

Yo uso esta librería y la he adaptado un poco a mis necesidades:

http://dotnetzip.codeplex.com/

[alexg88]

Tienes varios fallos:

1º Creas el fichero zip fuera del bucle, por eso se te crea los siguientes zip con los ficheros anteriores.
2º Estás usando mal esto: System.IO.Path.GetDirectoryName(Me.TextBox1.Text. Esto devuelve el directorio de la ruta que le pases. Por tanto, si has seleccionado el directorio C:\Directorio\Prueba, te va a devolver C:\Directorio.

Te recomiendo además que uses el método EnumerateFiles, que es más eficiente. (Puedes leer porque buscando en Google).

Además, no indicas si quieres comprimir los ficheros en subdirectorios o sólo los que se encuentren en el directorio directamente. Si quieres en los subdirectorios sólo tienes que cambiar Directory.EnumerateFiles(Me.TextBox1.Text) por Directory.EnumerateFiles(Me.TextBox1.Text, "*", SearchOption.AllDirectories)

Código vb:

Public Sub Comprimir()
        Dim txtFiles = Directory.EnumerateFiles(Me.TextBox1.Text)
 
        For Each currentFile As String In txtFiles
            Using zip As ZipFile = New ZipFile()
                zip.AddFile(currentFile, "")
                zip.Save(System.IO.Path.Combine(System.IO.Path.GetDirectoryName(currentFile), System.IO.Path.GetFileNameWithoutExtension(currentFile) + ".zip"))
            End Using
        Next
    End Sub
 

[davidalonsso05]

No me aparece la opcion de EnumarateFiles.

Logre hacerlo de la siguiente forma:

Código vb:

Public Sub Comprimir()
 
        For Each archivo As String In My.Computer.FileSystem.GetFiles(Me.TextBox1.Text, "*", FileIO.SearchOption.SearchAllSubDirectories)
            Using zip As ZipFile = New ZipFile()
                zip.AddFile(archivo, "")
                zip.Save(Path.Combine(Me.TextBox1.Text, Path.GetFileNameWithoutExtension(archivo) + ".zip"))
            End Using
        Next
 
    End Sub
 

Y me comprime de manera exitosa los archivos por separado.

Sin embargo, si la carpeta cuenta con subcarpetas quisiera preguntarle si desea comprimir las subcarpetas pero aun no encuentro la solucion...
Confirmo utilizo Vb 2005

[davidalonsso05]

Iniciado por alexg88

Tienes varios fallos:

1º Creas el fichero zip fuera del bucle, por eso se te crea los siguientes zip con los ficheros anteriores.
2º Estás usando mal esto: System.IO.Path.GetDirectoryName(Me.TextBox1.Text. Esto devuelve el directorio de la ruta que le pases. Por tanto, si has seleccionado el directorio C:\Directorio\Prueba, te va a devolver C:\Directorio.

Te recomiendo además que uses el método EnumerateFiles, que es más eficiente. (Puedes leer porque buscando en Google).

Además, no indicas si quieres comprimir los ficheros en subdirectorios o sólo los que se encuentren en el directorio directamente. Si quieres en los subdirectorios sólo tienes que cambiar Directory.EnumerateFiles(Me.TextBox1.Text) por Directory.EnumerateFiles(Me.TextBox1.Text, "*", SearchOption.AllDirectories)

Código vb:

Public Sub Comprimir()
        Dim txtFiles = Directory.EnumerateFiles(Me.TextBox1.Text)
 
        For Each currentFile As String In txtFiles
            Using zip As ZipFile = New ZipFile()
                zip.AddFile(currentFile, "")
                zip.Save(System.IO.Path.Combine(System.IO.Path.GetDirectoryName(currentFile), System.IO.Path.GetFileNameWithoutExtension(currentFile) + ".zip"))
            End Using
        Next
    End Sub
 

Disculpa muchas muchas gracias, me a servido mucho el codigo y probablemente sea la version del Visual ya que el mio es 2005, solo le modifique el EnumarateFiles por GetFiles ya que me marcaba error para comprimir los archivos de subcarpetas :D, gracias y buen fin de semana!! \♦/