[SOLUCIONADO] Activar checkbox en Datagridview cuando selecciono Combobox

[aid_val]

Hola buen día..

Tengo una aplicacion en vb.net en el cual cargo en un Datagridview "códigos y centros" y lo que quiero es que al seleccionar en un combobox un código en el datagridview se seleccionen los Checkbox que contengan el código igual al seleccionado.

Porfis que alguien me ayude.

[javidotnet]

Hola aid_val, no pusiste código, y así es difícil ayudarte; no obstante inventé uno, fijate si te sirve:

Código vb.net:

Public Class Form1
 
    Private WithEvents cbo As New ComboBox    'Creamos un ComboBox en tiempo de ejecución y habilitamos la captura de eventos para el mismo
    Private dgv As New DataGridView    'Creamos un DataGridView en tiempo de ejecución
 
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
 
        Me.Controls.Add(dgv)    'Agregamos el dgv a la colección de controles del formulario actual
        Me.Controls.Add(cbo)    'Agregamos el cbo a la colección de controles del formulario actual
 
        cbo.Dock = DockStyle.Top     'Posicionamos el cbo para que ocupe toda la parte superior del form
        dgv.Dock = DockStyle.Fill     'Posicionamos el dgv para que ocupe toda el resto de espacio que quede libre en el form
 
        'Mostramos el dgv y el cbo
        dgv.Show()
        cbo.Show()
 
        'Dijiste que tenés CheckBoxes en tu DGV, por eso tenemos que crear una columna de este tipo
        Dim dgv_chkcol As New DataGridViewCheckBoxColumn
        dgv.Columns.Add(dgv_chkcol)    'Agregamos la columna de CheckBoxes a la colección de columnas del DGV
 
        'Asignamos unos códigos inventados a cada CheckBox
        For i As Integer = 1 To 5
            Dim dgv_chkcell As New DataGridViewCheckBoxCell With {.ValueType = Type.GetType("Integer"), .TrueValue = i, .FalseValue = 0}
            Dim dgv_row As New DataGridViewRow
 
            dgv_row.Cells.Add(dgv_chkcell)
            dgv.Rows.Add(dgv_row)
 
            cbo.Items.Add(i)
        Next
 
    End Sub
 
    'Al seleccionar en el cbo un código, en el dgv se seleccionarán los CheckBoxes que contengan el código igual al seleccionado en el cbo
    Private Sub cbo_SelectedIndexChanged(sender As Object, e As EventArgs) Handles cbo.SelectedIndexChanged
 
        Dim v As Integer = CInt(cbo.SelectedItem)
        For i As Integer = 0 To 4    'Recorremos las filas del dgv
            If DirectCast(dgv(0, i), DataGridViewCheckBoxCell).TrueValue = v Then
                dgv(0, i).Value = v
            End If
        Next
 
    End Sub
End Class
 

Espero que te sea útil. . ¡Saludos desde Argentina!