Me da un error el ON UPDATE CASCADE y el ON DELETE CASCADE

[pumi]

Hola a todo el mundo de nuevo:

Quiero crear tablas en access mediante código usando DDL y necesito establecer una FOREIGN KEY en un campo de dicha tabla y establecer ON UPDATE CASCADE ON DELETE CASCADE en la clausa CONSTRAINT de dicho campo.

Si únicamente establezco el FOREIGN KEY, la tabla se me crea correctamente, pero si pongo el ON UPDATE CASCADE ON DELETE CASCADE, al ejecutar la sentencia DDL me da error en la parte CONSTRAINT.

He visto que esto pasa si en las opciones de ACCESS no marcamos la opción "Sintaxis compatible con SQL Server (ANSI 92)", asi que la he marcado y el error de la parte CONSTRAINT me desaparece y la tabla se me crea correctamente, con actualización en cascada y eliminación en cascada.

Todo este rollo ha sido para poneros en situación. Ahora paso a exponer lo que realmente quiero conseguir, que no se si es posible o no.

Realmente, las tablas las quiero crear en una base de datos distinta de aquella en la que ejecuto el código, pero cuando se va a ejecutar la instrucción DDL para la creación de la tabla, me da el error en la parte CONSTRAINT, aunque la opción de access "Sintaxis compatible con SQL Server (ANSI 92)" esté marcada para esa base de datos destino.

¿Alguien sabe en qué me puedo estar equivocando?

Como siempre muchas gracias.

[Ribon]

Yo recomiendo crear las llaves foráneas aparte del create table, esto es:
creando el índice correspondiente y asignándole la restricción de FK.
y hacer esto luego de creadas todas las tablas.

dicho gráficamente sería crear todas las tablas independientes y después unirlas con los FK.

espero se entienda, ando un poco mareado hoy xD!

[pumi]

Hola Ribon, gracias por tu resouesta.

Creo que te he entendido, pero me sigue sin funcionar. Este es el código que estoy usando:

---------------------------------------------------------------------------------------

Private Sub Comando7_Click()

Dim dbsMiBaseDatos As DAO.Database
Dim miselect As String

Set dbsMiBaseDatos = DBEngine.OpenDatabase("C:\A.accdb")

'----------------------------------------------
'----------------------------------------------


'Creamos la tabla Equipos
miselect = "CREATE TABLE Equipos (CodEquipos Autoincrement PRIMARY KEY, NombreEquipo Text(255));"
dbsMiBaseDatos.Execute miselect

'----------------------------------------------
'----------------------------------------------

'Creamos la tabla Equipos_Integrantes
miselect = "CREATE TABLE Equipos_Integrantes (CodEquiposIntegrantes Autoincrement PRIMARY KEY, CodEquipos Long, CodResponsable Long);" dbsMiBaseDatos.Execute miselect

miselect = "ALTER TABLE Equipos_Integrantes ADD CONSTRAINT FKCodEquipos FOREIGN KEY (CodEquipos) REFERENCES Equipos (CodEquipos) ON UPDATE CASCADE ON DELETE CASCADE;"
dbsMiBaseDatos.Execute miselect


dbsMiBaseDatos.Close
Set dbsMiBaseDatos = Nothing

End Sub

--------------------------------------------------------------------------------------



Cuando ejecuto es te código me da el siguiente mendaje de error:

Se ha producido el error 3289 en tiempo de ejecución.
Error de sintaxis en la cláusula CONSTRAINT.

Pero si no pongo el "ON UPDATE CASCADE ON DELETE CASCADE", este error no se produce y si me genera la relación entre las dos tablas.

¿Sabes qué puede estar pasando?.

Gracias y un saludo.

[pumi]

¡¡¡YA LO HE SOLUCIONADO!!!

El código es el que sigue:

--------------------------------------------------------------------------------

Private Sub Comando7_Click()

Dim dbsMiBaseDatos As DAO.Database
Dim RelNew As Relation
Dim miselect As String

Set dbsMiBaseDatos = DBEngine.OpenDatabase("C:\A.accdb")

'----------------------------------------------
'----------------------------------------------


'Creamos la tabla Equipos
miselect = "CREATE TABLE Equipos (CodEquipos Autoincrement PRIMARY KEY, NombreEquipo Text(255));"
dbsMiBaseDatos.Execute miselect

'----------------------------------------------
'----------------------------------------------

'Creamos la tabla Equipos_Integrantes
miselect = "CREATE TABLE Equipos_Integrantes (CodEquiposIntegrantes Autoincrement PRIMARY KEY, CodEquipos Long, CodResponsable Long);" dbsMiBaseDatos.Execute miselect

With dbsMiBaseDatos
Set RelNew = .CreateRelation("FKCodEquipos", "Equipos", "Equipos_Integrantes", dbRelationUpdateCascade + dbRelationDeleteCascade)
RelNew.Fields.Append RelNew.CreateField("CodEquipos")
RelNew.Fields!CodEquipos.ForeignName = "CodEquipos"
.Relations.Append RelNew
End With


dbsMiBaseDatos.Close
Set dbsMiBaseDatos = Nothing


End Sub

---------------------------------------------------------------------------------

Espero que sirva a más gente, ya que he visto en Internet que este problema que yo tenía se le presentaba a mucha gente.

Saludos a todos y gracias