En Access como crear un mensaje de error

[AlexC]

Hola a todos,

Tengo una base de datos con una forma en la cual busco un No de record X.

Todo me funciona bien, excepto que al no existir el No de record, me da cualquiera.

Quisiera agregar al boton un mensaje de error que diga Ej record no existe y se devuelva al punto de buscar de nuevo.

Gracias de antemano por la ayuda y Adelante !!!

Alex

[Taribo007]

Como buscas exactamente el numero de record???

En principio, bastaria comprobar antes de buscar si el registro existe, lo puedes hacer con dcount, y mostrar un mensaje si no existe, o no hacer nada si existe

Un saludo

[AlexC]

Esto es lo que estoy usando:

Private Sub SearchAcct_Click()

On Error GoTo Err_SearchAcct_Click

Dim stDocName As String
Dim stLinkCriteria As String

stDocName = "PO"
stLinkCriteria = "[Purchase]=" & "'" & Me![Acc] & "'"
DoCmd.Close acForm, "By_PO", acSaveNo
DoCmd.OpenForm stDocName, , , stLinkCriteria

Exit_SearchAcct_Click:

Exit Sub

Err_SearchAcct_Click:

MsgBox Err.Description
Resume Exit_SearchAcct_Click

End Sub

El numero de record es "Purchase"

Gracias por tu ayuda...

[Taribo007]

Puedes, como te decia, comprobar con docunt, algo asi:

Private Sub SearchAcct_Click()

On Error GoTo Err_SearchAcct_Click

Dim stDocName As String
Dim stLinkCriteria As String

stDocName = "PO"
stLinkCriteria = "[Purchase]=" & "'" & Me![Acc] & "'"

If DCount("*", "NombreTabla", stLinkCriteria) = 0 Then
MsgBox "No existe el registro"
Else
DoCmd.Close acForm, "By_PO", acSaveNo
DoCmd.OpenForm stDocName, , , stLinkCriteria
End If

Exit_SearchAcct_Click:

Exit Sub

Err_SearchAcct_Click:

MsgBox Err.Description
Resume Exit_SearchAcct_Click

End Sub

Un saludo

[AlexC]

Taribu,

Te estoy muy agradecido, todo funciona bien.

Habia probado con esos codigos y no me funcionaba, pero vi que cuando el No. no existia, re-emplazaba uno exitente, y cometi el error de siempre probar con el mismo numero, y por supuesto siempre salia como "existente".

De nuevo, te agradezco mucho tu gentil ayuda.

Alex