Transformación libre de Movie Clips

[longoe]

Estimados,
estuve buscando en foros anteriores y no encontré nada.
Necesito poder dibujar poligonos y colorearlos al presionar Control+Enter (no en el escenario de Flash, sino en el swf publicado)
Alguien me da una idea por donde arrancar?
gracias!

[evo_it]

Hola, los movie clips tienen algunos métodos que sirven para dibujar, desconozco cómo funcionan en AS3 pero aquí te paso algunos códigos de ejemplo de AS2:



Ejemplo
El ejemplo siguiente crea un cuadrado con relleno rojo en el escenario (puede ser el polígono que tu quieras, incluso círculos):

Código actionscript:

//esta línea crea un movieClip vacío que luego servirá como contenedor del dibujo
this.createEmptyMovieClip("square_mc", this.getNextHighestDepth());
//aquí especificamos el color del polígono
square_mc.beginFill(0xFF0000);
//aquí le decimos desde qué punto comenzará el dibujo (X:10 e Y:10)
square_mc.moveTo(10, 10);
//comenzamos a dibujar las líneas
//en este caso desde la ubicación establecida antes hasta X: 100 e Y: 10
square_mc.lineTo(100, 10);
square_mc.lineTo(100, 100);
square_mc.lineTo(10, 100);
square_mc.lineTo(10, 10);
//terminamos de dibujar
square_mc.endFill();
 

Puedes ir comentando partes del código para entender bien cómo lo hace.


Aquí otro código pero con curvas (es un poquito más complejo).

Código actionscript:

this.createEmptyMovieClip("circle_mc", 1);
with (circle_mc) {
    lineStyle(0, 0x0000FF, 100);
    beginFill(0xFF0000);
    moveTo(0, 100);
    curveTo(0,200,100,200);
    curveTo(200,200,200,100);
    curveTo(200,0,100,0);
    curveTo(0,0,0,100);
    endFill();
}
 

Espero que te haya servido, luego me cuentas.

Saludos

[longoe]

Hola evo_it

Gracias por el código que posteaste

este metodo ya lo tengo visto, el tema es que lo que yo quiero hacer es que el usuario haga click en determiandos puntos de la pantalla y esos puntos sean los vertices del poligono.
No que aparezca automáticamente, me explico?

Alguna idea por donde empezar?

[evo_it]

Bueno vamos por parte:

Tu código debería (según mi parecer) tener los siguientes eventos:

PASO 1 - Iniciar dibujo (el usuario dice "bueno voy a hacer clic acá para comenzar a dibujar mi polígono"). Esto sería dibujar dentro de un clip que oficiaría de lienzo de dibujo.

PASO 2 - Marcar los puntos

PASO 3 - Marcar último punto (esto sería al hacer clic sobre el icono nuevamente.)


Bien pasamos al código, definiremos algunas funciones que luego usarás, llamándolas desde botones, en el escenario tendremos un clip que usaremos como incono (icono_mc) y otro que usaremos como lienzo (miLienzo_mc):

Código actionscript:

///PASO 1: a esta función la llamaremos cuando comencemos a dibujar
function comenzarDibujo(lienzo_mc:MovieClip)
{
        this.createEmptyMovieClip("clipVacio_mc", this.getNextHighestDepth());
        clipVacio_mc._x=lienzo_mc._x;
        clipVacio_mc._y=lienzo_mc._y;
        clipVacio_mc.beginFill(0xFF0000);
        _global.numeroPunto=1;
}
 
//PASO 2: aquí dibujamos los puntos
function dibujarPunto(lienzo_mc:MovieClip,posX:Number, posY:Number)
{
       if(_global.numeroPunto==1)
       {
         clipVacio_mc.moveTo(posX, posY);
       }
       else
       {
           clipVacio_mc.lineTo(posX, posY);
       }
       _global.numeroPunto++;
}
//PASO 3: terminar dibujo
function terminarDibujo(lienzo_mc:MovieClip)
{
        lienzo_mc.enabled=false;
        clipVacio_mc.endFill();
}
 
_global.numeroPunto=0;
miLienzo_mc.enabled=false;
//eventos de botones
icono_mc.onRelease=function()
{
    if(!_global.numeroPunto)
    {
        miLienzo_mc.enabled=true;
        comenzarDibujo(this._parent.miLienzo_mc)
    }
    else
    {
        miLienzo_mc.enabled=false;
        terminarDibujo(this._parent.miLienzo_mc)  
    }    
}
 
miLienzo_mc.onRelease=function()
{
    dibujarPunto(this, this._xmouse, this._ymouse)
}
 

Con eso tienes para empezar, luego le deberás agregar tú solo detalles...


Saludos