Repetir un sonido indefinidamente

[icuevas]

Hola a tod@s,

Es la primera vez que necesito de ayuda pues comienzo a introducirme en el tema de Flash.

Tengo un script que arranca un sonido o lo para, pero cuando suena solo lo hace una sola vez y me gustaría que una vez arrancado sonara indefinidamente, y poderlo para con el botón de paro. (Arrancar y parar funcionan perfectamente)

Gracias y un saludo

Script AS2.0
/* Primero declaramos dos variables, pausa y estado; pausa nos servirá
para almacenar la posición donde esta la canción, y estado para saber en que
estado se encuentra la canción, 1 si el sonido se está reproduciendo y 0 para el
estado en que el sonido esté en pause*/
var pausa:Number = 0;
var estado:Number = 0;

/* Como no le pusimos ninguna acción al Movie Clip, para que no se reprodujera
como loco, lo frenamos al comienzo*/
Sonido.stop();
/*Atachamos inmediatamente el sonido linkeado desde la biblioteca a una variable
llamada: "misonido"*/
_root.onLoad = function(){
misonido = new Sound();

misonido.attachSound("Musica");
}
//En el evento onPress ó cuando presione el botón
Sonido.onPress = function (){


if (estado == 0){

/* se verifica en que estado se encuentra el sonido, si está en 0, ósea el sonido no se esta reproduciendo,
ponemos play al sonido; usamos la variable de pausa que contiene
lo que lleva la canción reproducida hasta el momento en milisegundos, por eso lo dividimos entre 1000;
para que nos de exactamente la posición donde se encuentra*/
misonido.start(pausa/1000);
//Una vez el sonido en play, cambiamos el estado a 1, ósea reproduciéndose
estado = 1;
//y finalmente cambiamos la apariencia del botón
Sonido.gotoAndStop("pause");
} else {

/*En caso de que no sea 0, significa que se esta reproduciendo la canción y
queremos detenerla, primero calculamos la posición donde se va a quedar en pause
almacenándolo en la variable pausa*/
pausa = misonido.position;
//detenemos totalmente el sonido
misonido.stop();
//cambiamos el estado a 0, ósea sin sonido
estado = 0;
//y finalmente cambiamos la apariencia del botón
Sonido.gotoAndStop("play");
}
}

[Bandit]

Hola icuevas:
Bienvenido al Foro.
Tu código escríbelo así:

Código actionscript:

var pausa:Number = 0;
var estado:Number = 0;
Sonido.stop();
_root.onLoad = function() {
    misonido = new Sound();
    misonido.attachSound("musica");
    misonido.onSoundComplete = function() {
        misonido.start();
    };
};
Sonido.onPress = function() {
    if (estado == 0) {
        misonido.start(pausa/1000);
        estado = 1;
        Sonido.gotoAndStop("pause");
    } else {
        pausa = misonido.position;
        misonido.stop();
        estado = 0;
        Sonido.gotoAndStop("play");
    }
};
 

Espero haberte sido de ayuda.