Problea labelField y dataProvider

[gorkamu89]

Realmente no tengo muy claro si me pregunta va aqui...asi que si no es el mejor lugar movedmelo.
Bueno la cosa es que desde hace poco estoy trabajando con Flex Builder 3 y programando mediante MXML y ActionScript 3 y estoy en un proyeco atascadisimo.

Tengo dos listas en las que quiero que se muestre una serie de informacion sacada de un XML externo mediante el objeto HTTPService. Es un sistema de muestra de informacion de unos LPs. En la primera lista se carga el nombre de los artistas y al seleccionar en uno de ellos he hecho mediante el evento change() que complete unos text en los cuales se muestren artista-disco-genero y discografica y me gustaria que en la segunda lista cargase un array de canciones correspondiente a cada disco. Basicamente utilizo la propiedad list.labelField para cargar cada informacion en los text pero no se porque no me termina de cargar el array de canciones.
La estructura del XML es asi como

<disco>
<artista></artista>
<canciones>
<t>track1</t>
<t>track2</t>
</canciones>
</disco>

Me han dicho que deberia utilizar un identificador, pero realmente no se si para cada disco o para el nodo de canciones y a demas tampoco se como lo podria vincular a la segunda lista, tambien mediante un labelField?

Espero ayuda y muchas gracias

[Bandit]

Movido al Foro de Flex desde ActionScript.

[jahepi]

Hola gorkamu89 !

Ahorita no me voy a meter en la dudas del labelField, quiero ver la parte de como obtienes y generas los datos.

Te propongo esta solución que es más intuitiva, la idea es que a partir de los archivos XML generar colecciones de objetos del tipo Disco, teniendo estos datos te será más sencillo generar la parte gráfica.

Por ejemplo, tenemos la siguiente estructura en el XML:

Código XML:

<discos>
 
    <disco>
    <artista>Artista 1</artista>
    <canciones>
        <t>track1</t>
        <t>track2</t>
    </canciones>
    </disco>
    
    <disco>
    <artista>Artista 2</artista>
    <canciones>
        <t>track1</t>
        <t>track2</t>
    </canciones>
    </disco>
 
    <disco>
    <artista>Artista 3</artista>
    <canciones>
        <t>track1</t>
        <t>track2</t>
    </canciones>
    </disco>
 
</discos>
 

Ahora si generamos nuestra clase Disco que encapsulará toda la información genérica:

Código actionscript:

package {
 
    public class Disco
    {
        private var artista:String
        private var canciones:Array;
    
        public function Disco(artista:String)
        {
            this.artista = artista;
            canciones = new Array();
        }
        
        public function agregarCancion(cancion:String):void
        {
            canciones.push(cancion);
        }
        
        public function obtenerCancion(index:int):String
        {
            return canciones[index];
        }
    
        public function numeroCanciones():int
        {
            return canciones.length;
        }
        
        public function obtenerArtista():String
        {
            return artista;
        }
    }
}
 

La clase contiene como atributos el nombre del artista y la lista de canciones, puedes preguntarle a la clase por el número de canciones, por determinada canción, etc.

Ahora la idea es generar instancias de esta clase con la ayuda del XML:

Código actionscript:

package {
    
    import flash.events.Event;
    import flash.net.URLRequest;
    import flash.net.URLLoader;
    
    public class Main
    {
        public static function main():void
        {
            var loader:URLLoader = new URLLoader();
            loader.load(new URLRequest("discos.xml"));
            loader.addEventListener(Event.COMPLETE, Main.materializar);
        }
        
        private static function materializar(evt:Event):void
        {
            var discosCol:Array = new Array();          
            var xml:XML = new XML(evt.target.data);
            var discos:XMLList = xml.disco; 
            for each (var disco:XML in discos) {
                var discoObj:Disco = new Disco(disco.artista);
                var canciones:XMLList = disco.canciones;
                for each (var cancion:XML in canciones.children()) { 
                    discoObj.agregarCancion(cancion);
                }
                discosCol.push(discoObj);
            }
        }
    }
}
 

La variable discosCol contiene todos los objetos Disco, estos los tendrás disponibles dentro de la aplicación, con esta información puedes generar tus lista de artistas así como mostrar las canciones de ese artista, solo falta meterle talacha a la parte de presentación (MXML).

Un saludote !

[gorkamu89]

Muchas gracias jahepi la verdad es que no entiendo mucho el codigo porque llevo 2 semanas con actionscript y mxml pero prometo que lo estudiaré ;) un saludo