[SOLUCIONADO] Juego pintar con flash

[SirDante]

verán, estoy buscando como realizar un juego parecido a este

[URL="http://www.kiddia.org/juego-flash-0-5-anos-colorear"]http://www.kiddia.org/juego-flash-0-5-anos-colorear[/URL]

no necesito que funcionen las opciones de cambiar dibujo, imprimir o borrar, pero quisiera saber como puedo hacer que al clickear el color de la paleta, la "brocha" tome la propiedad del color y la transfiera al objeto que quiero pintar.

Además (y esto es digamos que menos importante) quisiera saber si hay alguna forma de limitar las acciones, es decir, que si tengo un circulo, pueda elegir que el juego se acaba cuando el circulo se coloree de un color en concreto.l

Gracias por el tiempo.

[Mahalo]

Mírate la clase ColorTransform. Se aplica sobre objetos de tipo Shape pero cualquier mc puede ser interpretado como tal.

Código ActionScript:

mc.addEventListener(MouseEvent.CLICK, function() {
    var colorTransform = new ColorTransform();
    colorTransform.color = 0xFF0000;
    mc.transform.colorTransform = colorTransform;
});
 

Ojo, lo convertirá todo al color que le dés, incluidos los bordes.
Saludos!

[SirDante]

Hola Mahalo, gracias por contestar, pero la verdad es que esa interacción que plantea el color transform no es la que estoy buscando, ya que con esta el objeto cambia de color al presionar un cierto objeto, lo que en realidad estoy buscando es que yo pueda seleccionar el color con el pincel y posteriormente colorear un objeto especifico dandole click encima (tal como el juego que deje de ejemplo).

Agradezco si alguien mas tiene una solución.

[Mahalo]

Bueno, yo te he puesto el ejemplo con un color fijo pero es fácil implementar una paleta de colores. Basta que tengas una variable global color_activo que cambie cuando hagas click en los distintos colores. En fin, no creo que esperes que te lo hagan todo, ¿no? Ve probando y deja aquí tus dudas.
Saludos!

[SirDante]

verás Mahalo, que mi problema es justamente ese, he estado intentando lograr que al clickear un color la "brocha" asuma el color (es decir, dar un set_color a la "brocha" que en este caso es el puntero del mouse) para posteriormente trasladar dicho color a otro objeto.

Tu ejemplo me da una solución al problema sin cambiando el color de forma inmediata al clickear un objeto (en este caso un color de la paleta). pero en realidad no puedo hacer pruebas sobre algo que no tengo ni idea como hacer :lol: es por eso que he posteado en el foro.

No soy una persona muy experimentada en As3, apenas lo estoy aprendiendo, si alguien puede solucionarme mi duda, que no he encontrado en ninguna parte le agradecería mucho.

¿Como consigo que la brocha asuma un color especifico (con que variable)? ¿como transfiero dicho color a un objeto especifico (con que variable)? mucha gracias.

PD: como dijo Mahalo, no tienen que darme un ejercicio completamente hecho, con que me den el dato de las variables que debo usar, o de las etiqueta que necesito es suficiente.

[Bandit]

Hola SirDante:
Visita mi página, allí tienes un tutor que se llama Efecto_pintar, está en AS2.

Espero que te sea de alguna utilidad.

[dvpareja]

Buenas

este juego lo hice hace 2 o 3 años. Te puede servir de pista.

Lo primero que hacía era crear un tablero con recuadros en blanco, usando la siguiente clase:

Código AS3:

package  {
    
    import flash.display.MovieClip;
    import flash.events.MouseEvent;
    import flash.display.Sprite;
    import flash.geom.ColorTransform;
    
    public class creaTablero extends MovieClip {
        
            private var marco:Sprite;
            private var mc:MovieClip;
            public var color:int;
            
        
        public function creaTablero():void {
            // constructor code
                
            for (var i:int = 0; i<4; i++) {
                for (var j:int = 0; j<9; j++) {
                    
                    mc = new MovieClip();
                    marco = new Sprite();
                                
                    marco.graphics.lineStyle(1,0x000000);
                    marco.graphics.beginFill(0xFFFFFF,1);
                    marco.graphics.drawRoundRect(0, 0, 60, 60, 0);
                    mc.addChild(marco);
                    marco.addEventListener(MouseEvent.MOUSE_UP,Colorear)
                    
                    mc.x = (62*j);
                    mc.y = (62*i);
                    if (i<3 || j<8) {
                        addChild(mc);
                    }
                }
            }
        }
        
        private function Colorear(evt:MouseEvent) {
            
            var miColor:ColorTransform=evt.target.transform.colorTransform;
            miColor.color=color;
            evt.target.transform.colorTransform=miColor;
        }
        public function SetColor(c:int) {
            color = c;
        }
 
 
    } // end class
    
} // end pack
 

Como podrás ver, contiene un setter para decir el color que lleva el pincel, que capturaba desde la main class:

Código AS3:

// AS3 code
import flash.geom.ColorTransform;
 
var tablero:creaTablero = new creaTablero();
cont.addChild(tablero);
 
rojo.addEventListener(MouseEvent.MOUSE_UP,SetRojo)
verde.addEventListener(MouseEvent.MOUSE_UP,SetVerde)
azul.addEventListener(MouseEvent.MOUSE_UP,SetAzul)
//addEventListener(MouseEvent.MOUSE_OVER,Puntero) 
//function Puntero(evt:MouseEvent) {
    puntero.startDrag();
    Mouse.hide();
//}
 
    
    puntero.x = mouseX+1;
    puntero.y = mouseY+1;
 
 
 
function SetRojo(evt:MouseEvent) {
    tablero.SetColor(0xFF0000);
    var miColor:ColorTransform=puntero.transform.colorTransform;
    miColor.color=0xFF0000;
    puntero.transform.colorTransform=miColor;
 
}
function SetVerde(evt:MouseEvent) {
    tablero.SetColor(0x00FF00)
    var miColor:ColorTransform=puntero.transform.colorTransform;
    miColor.color=0x00FF00;
    puntero.transform.colorTransform=miColor;
}
function SetAzul(evt:MouseEvent) {
    tablero.SetColor(0x0000FF)
    var miColor:ColorTransform=puntero.transform.colorTransform;
    miColor.color=0x0000FF;
    puntero.transform.colorTransform=miColor;
}
 

Con esto tienes todo lo que necesitas para entender como colorear en AS3.

Saludos

[SirDante]

Mucha gracias Bandit y dvpareja, ya me hago una mejor idea de como funciona, ahora voy a hacer la aplicación y si sale algun inconveniente publico de nuevo, aunque espero que no.

Muchas gracia de nuevo a los que respondieron ^^.