EventListener para eventos de Mouse

[Weahl]

¿Es correcto usar esto?

Código ActionScript 3.0:

boton.addEventListener(MouseEvent.CLICK, sendSoldier);
boton.addEventListener(MouseEvent.ROLL_OVER, infoSoldier);
boton.addEventListener(MouseEvent.ROLL_OUT, infoSoldierOut);
 

Un eventlistener cuando se haga click en el botón, otro para cuando el ratón esté encima y otro para cuando salga del botón.

Soy nuevo en esto y he leído por ahí algo de "on(release)" y demás, pero no se como hacerlo funcionar.


Muchas gracias.

[TMeister]

Como dices, los Listeners son para AS3 y si, tu ejemplo esta bien aplicado.

on(release) es para AS1 y AS2

Saludos!!

[Weahl]

Pero el caso es que quiero poner como unos 10 botones con sus respectivos eventListener, ¿no ralentizará eso el funcionamiento del juego?

Otra pregunta:

¿Es posible hacer algo para que, con solo 3 eventListener (click, roll over y roll out), pueda usarlo para todos los botones, en plan que cuando pulse en uno me devuelva un valor y si pulso en otro me devuelva otro valor diferente, así no lleno el código de eventListener y de funciones para cada botón.



Muchísimas gracias.

[polo_W12]

Iniciado por Weahl

Pero el caso es que quiero poner como unos 10 botones con sus respectivos eventListener, ¿no ralentizará eso el funcionamiento del juego?

Otra pregunta:

¿Es posible hacer algo para que, con solo 3 eventListener (click, roll over y roll out), pueda usarlo para todos los botones, en plan que cuando pulse en uno me devuelva un valor y si pulso en otro me devuelva otro valor diferente, así no lleno el código de eventListener y de funciones para cada botón.



Muchísimas gracias.

Amigo sabes se soluciona de la siguiente manera aunque yo no estoy acostumbrado a trabajar con botones solo con clips, por que son más versátiles.

Código ACTIONSCRIPT:

var valores:Array   = new Array("primer valor","segundo valor", "tercer valor",
                                "cuarto valor", "quinto valor", "sexto valor")
var i:uint          = 0;
//Cantidad de clips en el escenario.
var t:uint          = valores.length;
//nombre común entre los clips ejemplo:
//boton0, boton1, y así sucesivamente...
var nombre:String   = "boton";
 
 
for(i=0; i<t; i++){
    //obtienes el clip que está en el escenario
    var clip:MovieClip      = getChildByName(nombre+i) as MovieClip;
    //preguntas si existe 
    if(clip){
        //asignas un valor a una propiedad llamada "imprimir"
        //que en este caso es el valor de un arreglo
        clip.imprimir       = valores[i];
        //asignas un valor a una propiedad llamada "myindex"
        //que en este caso contiene el índice de la iteración
        clip.myindex        = [i];
        //si existe agregas los eventos
        addlistenerevent(clip);
    }
}
 
function addlistenerevent(a:MovieClip):void{
    //haces que al pasar el mouse sobre el clip
    //aparezca la mano como si fuese un botón
    a.buttonMode        = true;
    //asignas evento CLICK
    a.addEventListener(MouseEvent.CLICK, sendSoldier);
    //asignas evento ROLL_OVER
    a.addEventListener(MouseEvent.ROLL_OVER, infoSoldier);
    //asignas evento ROLL_OUT
    a.addEventListener(MouseEvent.ROLL_OUT, infoSoldierOut);
}
 
function sendSoldier(a:MouseEvent):void{
    //obtienes que clip fue presionado
    var clip:MovieClip = a.currentTarget as MovieClip;
    trace("Obtienes \""+clip.imprimir+"\"");
    trace("Mi índice "+clip.myindex);
}
 
function infoSoldier(a:MouseEvent):void{
    //obtienes que clip por el cual has pasado
    var clip:MovieClip = a.currentTarget as MovieClip;
    trace("ROLL_OVER "+clip.name);
}
 
function infoSoldierOut(a:MouseEvent):void{
    //obtienes que clip por el cual has salido
    var clip:MovieClip = a.currentTarget as MovieClip;
    trace("ROLL_OUT "+clip.name);
}
 

Espero te sea de ayuda.

Saluda Atte.
Claudio Barrera Asencio.

[Weahl]

Algo falla y creo que es en el FOR.

Leyendo el código y teniendo en cuenta mi inexperiencia, creo que la variable clip debería ser un array y almacenar cada uno de los valores en la misma, porque con la función FOR tal cual lo que hace es almacenar los valores en la variable clip, por lo que en teoría quedaría almacenado solo el último valor.

Puede ser que el problema sea donde hay que poner la función FOR.

Yo lo tengo tal que así ahora mismo:

Código ActionScript:

package  
{
    import flash.display.MovieClip;
    import flash.events.MouseEvent;
    import flash.events.Event;
    
    public class UpMenu extends MovieClip
    {
        
        var valores:Array   = new Array("Soldado","ninja")
        var i:uint          = 0;
        //Cantidad de clips en el escenario.
        var t:uint          = valores.length;
        //nombre común entre los clips ejemplo:
        //boton0, boton1, y así sucesivamente...
        var nombre:String   = "boton";
 
        
        public function UpMenu() 
        {
            info.visible = false;
            for(i=0; i<t; i++)
            {
                //obtienes el clip que está en el escenario
                var clip:MovieClip      = getChildByName(nombre+i) as MovieClip;
                
                //preguntas si existe 
                if(clip)
                {
                    //asignas un valor a una propiedad llamada "imprimir"
                    //que en este caso es el valor de un arreglo
                    clip.imprimir       = valores[i];
                    //asignas un valor a una propiedad llamada "myindex"
                    //que en este caso contiene el índice de la iteración
                    clip.myindex        = [i];
                    //si existe agregas los eventos
                    addlistenerevent(clip);
                }
            }
            oro.sumar(50);  //Cantidad de oro con el que se empieza
        }
        
        
        function addlistenerevent(a:MovieClip):void
        {
            //haces que al pasar el mouse sobre el clip
            //aparezca la mano como si fuese un botón
            a.buttonMode        = true;
            //asignas evento CLICK
            a.addEventListener(MouseEvent.CLICK, sendSoldier);
            //asignas evento ROLL_OVER
            a.addEventListener(MouseEvent.ROLL_OVER, infoSoldier);
            //asignas evento ROLL_OUT
            a.addEventListener(MouseEvent.ROLL_OUT, infoSoldierOut);
        }
        
        
        function sendSoldier(a:MouseEvent):void
        {
            //obtienes que clip fue presionado
            var clip:MovieClip = a.currentTarget as MovieClip;
            trace("Obtienes \""+clip.imprimir+"\"");
            trace("Mi índice "+clip.myindex);
            
            if(oro.currentValue >= 10)
            {
                var type = clip.imprimir;
                var unit:MovieClip = new type();
                stage.addChild(unit);
                
                oro.sumar(-10);
            }
        }
         
        function infoSoldier(a:MouseEvent):void
        {
            //obtienes que clip por el cual has pasado
            var clip:MovieClip = a.currentTarget as MovieClip;
            trace("ROLL_OVER "+clip.name);
            
            info.visible = true;
        }
         
        function infoSoldierOut(a:MouseEvent):void
        {
            //obtienes que clip por el cual has salido
            var clip:MovieClip = a.currentTarget as MovieClip;
            trace("ROLL_OUT "+clip.name);
        }
        
 
    }
    
}
 

Por lo que la función FOR solo se ejecuta una vez, es ahí donde me extraña porque el clip no es un Array.

Poniendo el código tal cual (y añadiendo lo básico obviamente) no obtengo ninguno de los TRACE del código.


¿Está bien situado?


Muchas gracias por el código Sr. Barrera.


EDIT: Vale, acabo de comprobar que no funciona con los botones, pero si con MovieClip, ahora entiendo su primera frase del post jeje.

¿Hay alguna forma de aplicarlo a botones? De todos modos intentaré fabricar un botón con MovieClip aunque tenga cero de experiencia.


Muchísimas gracias.

[polo_W12]

Iniciado por Weahl

EDIT: Vale, acabo de comprobar que no funciona con los botones, pero si con MovieClip, ahora entiendo su primera frase del post jeje.

¿Hay alguna forma de aplicarlo a botones? De todos modos intentaré fabricar un botón con MovieClip aunque tenga cero de experiencia.


Muchísimas gracias.

Amigo:

Sabes que trabajo desde hace dos años con Flash y con ActionScript3 y debo decir que insisto en la versatilidad que puede ofrecer el MovieClip por sobre el Boton, por lo que te recomiendo utilizar MovieClip por sobre Button, pero en cosa de gustos no hay nada escrito.

Saluda Atte.
Claudio Barrera Asencio.

[Weahl]

Iniciado por polo_W12

Amigo:

Sabes que trabajo desde hace dos años con Flash y con ActionScript3 y debo decir que insisto en la versatilidad que puede ofrecer el MovieClip por sobre el Boton, por lo que te recomiendo utilizar MovieClip por sobre Button, pero en cosa de gustos no hay nada escrito.

Saluda Atte.
Claudio Barrera Asencio.

Te haré caso, muchas gracias por el consejo ^^.


Un cordial saludo.