Duda con navigateToURL

[maxpower78]

Hola, estoy desarrollando una aplicación en la que los usuarios puedan hacer un dibujo en flash y luego este dibujo se guarda en un servidor. Todo funciona bien, excepto que en el script para guardar la imagen al sevidor hay un navigateToURL que cuando guarda la imagen me abre una ventana con la url de la imagen y si comento esa linea no salta la ventana pero no guarda la imagen en servidor

¿Como podría evitar que saltase esa ventana, pero que la imagen se guarde en el servidor?

Este es el script que utilizo:

Código:

private function saveHandler(e:MouseEvent):void 
      { 
         canvas.overlay = null; 
         //creamos un Bitmap del lienzo 
         var canvasBmp:BitmapData = new BitmapData(521,213); 
         canvasBmp.draw(canvas); 
 
         var myEncoder:JPGEncoder = new JPGEncoder(100); 
         var byteArray:ByteArray = myEncoder.encode(canvasBmp); 
 
         canvasBmp.dispose(); 
 
         _fileRef = new FileReference(); 
         _fileRef.save(byteArray, "dibujo.jpg"); 
         var header:URLRequestHeader = new URLRequestHeader("Content-type","application/octet-stream"); 
         var myDate:Date = new Date(); 
         var timeNow:Number = myDate.getTime(); 
         timeNow.toString(); 
         var saveJPG:URLRequest = new URLRequest("savejpg.php?nombre=images/dibujo_"+myDate+".jpg"); 
         saveJPG.requestHeaders.push(header); 
         saveJPG.method = URLRequestMethod.POST; 
         saveJPG.data = byteArray; 
         //**************************************** 
         navigateToURL(saveJPG, "_blank"); 
         //**************************************** 
      }

y este es el php:

Código PHP:

  <?php 
if (isset($GLOBALS["HTTP_RAW_POST_DATA"])) 
{ 
   // get bytearray 
   $jpg = $GLOBALS["HTTP_RAW_POST_DATA"]; 
 
   // add headers for download dialog-box 
   header('Content-Type: image/jpeg'); 
   $nombreArchivo = $_GET['nombre']; 
   $manejadorArchivo = fopen($nombreArchivo, 'w') or die("No se pudo escribir archivo"); 
   fwrite($manejadorArchivo,$jpg); 
   fclose($manejadorArchivo); 
} 
?>   

gracias!!

[TMeister]

Hola.

Efectivamente, el comportamiento es correcto, navigateToURL es para abrir una nueva pagina en el navegador.

Si quieres solo enviar data de forma transparente al usuario debes usar un loader algo así:

Código actionscript:

//..dentro de la funcion
var loader:URLLoader = new URLLoader();
loader.addEventListener(Event.COMPLETE, handleComplete);
loader.addEventListener(IOErrorEvent.IO_ERROR, onIOError);
loader.load(saveJPG);
 
//final funcion
 
private function handleComplete(e:Event)
{
     trace("Envio completado " + e)
}
 
private function onIOError(e:IOErrorEvent)
{
    trace("Algo salio mal " + e)
}
 

Con esto envías tu data al script y esperas a que se ejecute algún evento dependiendo del resultado de la petición.

Saludos