definir variables globales

[TCL_ZIP]

Estoy utilizando el "adobe flash CS3 professional"
y estoy intentando definir 2 variables globales, pero no se como.

de momento lo hago de la siguiente manera:

Código:

_global.off = new int(2);
_global.ini = new int(1);
stop();

en el primer fotograma,
el problema es que al ejecutar me sale el siguiente error:

Escena 1, Capa "actionscript", Fotograma 1, Linea 1
1120: Acceso a una propiedad _global no definida.
_global.off = new int(2);

el problema supongo que esta en que no inicializo bien la variable, como puedo hacerlo?

lo unico k me interesa hacer escrear 2 variables numericas que sena visibles para toda la pelicula


Gracias por adelantado

[TCL_ZIP]

up, me urge mucho

[Lynxcraft]

Código PHP:

  _global.off = Math.floor(2);
_global.ini= Math.floor(1);
stop(); 
   

aver si esto t sirve

[TCL_ZIP]

me sigue dando el mismo error :$ alguna otra forma de definir una variable que pueda ser vista por todos los clips de la pelicula?

[jahepi]

Hola TCL_ZIP !

Tu proyecto lo estas compilando en As3.0 y la palabra reservada global fue eliminada, ahora en As3.0 puedes enfrentar este problema con una clase que implemente el patrón de diseño llamado 'Singleton', con esta solución puedes tener una instancia global en tu proyecto.

No sé si lo que te mencionó te suene a chino pero no te quiero confundir más, te propongo que compiles tu proyecto en As2.0 para que puedas volver a utilizar la palabra reservada _global, y si no quieres compilarlo en as2.0 pues con gusto te explico como sería la solución en as3.0.

Un saludote !

[TCL_ZIP]

pues la verdad me interesa tambien la solucion en AS3.0 para poder seguir aprendiendo ^^

gracias por tu interes

[jahepi]

Iniciado por TCL_ZIP

pues la verdad me interesa tambien la solucion en AS3.0 para poder seguir aprendiendo ^^

gracias por tu interes

Hola TCL_ZIP ! !

Para solucionar esto en as3.0 tienes que crear un archivo aparte con extensión .as, este se debe encontrar en donde tienes el .fla de tu proyecto, lo llamaremos en este caso Global (Global.as), ahora el código que va dentro de este archivo es el siguiente:

Código:

package {

    public class Global {
    
            private var _data:Object;
            private static var _self:Global;

            public function Global() {
                _data = new Object();
            }

            public static function getInstance():Global {
                if(_self == null) {
                    _self = new Global();
                }
                return _self;
            }

            public function setValue(key:String, value:*):void {
                _data[key] = value;
            }

            public function getValue(key:String):* {
                return _data[key];
            }
    }
}

Esta clase tiene como finalidad guardar valores globales en un objeto, así en toda tu aplicación podrás consultarlo sin problemas, el modo de usarlo sería de la siguiente forma en tu .fla:

Código:

//En esta parte obtenemos nuestra instancia global
var global:Global = Global.getInstance();

//Para declararlas desde cualquier punto.
global.setValue("off", 2);
global.setValue("ini", 1);

//Para recuperarlas desde cualquier punto
trace(global.getValue("off"));
trace(global.getValue("ini"));

Sale, cualquier duda no dudes en preguntar.

Un saludote !