Crear un EXEL desde un DATAGRID

[segma]

Hola, sabéis como se puede crear un exel, apartir de un Datagrid?

Saludos!!

[Sergestux]

Yo use una libreria que pusieron en cristalabs y me funciona muy bien

[segma]

Hola,

La he probado y me he bajado este SWC de este link

http://code.google.com/p/as3xls/

Pero no se como inscrustarlo en el FLEX

Aparte me peta en el

import com.as3xls.xls.ExcelFile;

Que puede ser que por no poner el SWC.

Yo he copiado el código tal cual y luego he añadido la clase pero lo del pakage

import com.kcc.tempos.utils.exporter.ExcelExporterUtil;

lo he puesto así import exporter.ExcelExporterUtil;

sin com.kcc.tempos.utils. que no se como lo ponen ellos.
¿Me puedes explicar alguna cosa que hago mal? Por no decir todo..

Muchas gracias y un saludo!

[Sergestux]

No tienes que crear tantas carpetas como lo hacen ellos, basta con que crees una que se llama com, dentro de ella otra que se llame utils, o como desees y dentro de esa carpeta puedes pegar el codigo de la clase que te mencione (ExcelExporterUtil.as).

En tu codigo principal, donde vayas a exportar a excel importas la clase y en una funcion la usas:

Código Javascript:

import com.utils.ExcelExporterUtil;
 
//Importa a excel el grid
        private function ExportarExcel(Archivo:String="Archivo"):void
        {           
            var NomFile:String=this.title;
            ExcelExporterUtil.dataGridExporter(GridId, NomFile + ".xls");
        }
 

GridId es el id del grid que quieres exportar a excel



Clase que debe ir en la carpeta com -> utils -> ExcelExporterUtil.as

Código Javascript:

package com.utils 
{ 
   import com.as3xls.xls.ExcelFile; 
   import com.as3xls.xls.Sheet; 
    
   import flash.errors.IllegalOperationError; 
   import flash.net.FileReference; 
   import flash.utils.ByteArray; 
    
   import mx.collections.ArrayCollection; 
   import mx.collections.ICollectionView; 
   import mx.collections.IViewCursor; 
   import mx.collections.XMLListCollection; 
   import mx.controls.DataGrid; 
    
   /** 
    * 
    * Author: Andrés Lozada Mosto 
    * Version: 0.1 
    * Fecha release: 10/03/2009 
    * Contacto: [email protected] 
    *   
    * Clase que maneja la exportacion de elementos 
    * a Excel. 
    *  
    * Se utiliza el proyecto http://code.google.com/p/as3xls/  
    * para la generacion de Excel. 
    *  
    * Se necesita la version 10 de Flash player para realizar el correcto 
    * guardado del archivo sin pasar por backend. 
    *  
    * @example 
    * <code> 
    * private var flat:ArrayCollection = new ArrayCollection([ 
    *                              {nombre:"Andrés", apellido:"Sanchez"}, 
    *                              {nombre:"Mónica", apellido:"Sanchez"}, 
    *                              {nombre:"Agustina", apellido:"Sanchez"}, 
    *                              {nombre:"Pablo", apellido:"Sanchez"}, 
    *                              {nombre:"Magalí", apellido:"Sanchez"} 
    *                              ]); 
    * ExcelExporterUtil.dataGridExporter(this.dg, "prueba_excel.xls"); 
    * </code> 
    *  
    * Lista de funciones 
    * <list> 
    *  dataGridExporter:       Exporta un datagrid a un excel de forma automatica 
    *  export:             Exporta un listado de objetos 
    * </list> 
         * 
    */ 
 
   public class ExcelExporterUtil 
   { 
      public function ExcelExporterUtil() 
      { 
         throw new IllegalOperationError("Class \"ExcelExporterUtil\" is static. You can't instance this"); 
      } 
       
      //----------------------------- 
      // Public function 
      //----------------------------- 
      /** 
       *  
       * Exporta los datos de un datagrid hacia un Excel. 
       * Toma el dataProvider del mismo y las columnas para su exportacion 
       *  
       * @param dg          Referencia al datagrid 
       * @defaultName         Nombre default con el que se va a generar el archivo excel 
       *  
       */ 
      static public function dataGridExporter(dg:DataGrid, defaultName:String):void 
      { 
         if (dg == null || dg.dataProvider == null || defaultName == null || defaultName == "") 
            return; 
          
         var cols:Number = 0; 
         var colsValues:Array = []; 
         var cantCols:Number = dg.columnCount; 
         var fieldT:String; 
         var headerT:String; 
          
         // armo el listado de headers y variables para cada columna 
         for ( ; cols < cantCols; cols++) 
         { 
            headerT = (dg.columns[cols] as Object).headerText 
            fieldT = (dg.columns[cols] as Object).dataField; 
            if ( fieldT == null || fieldT == "" || headerT == null || headerT == "") 
               continue;  
            colsValues.push({ 
                        header:headerT, 
                        value:fieldT 
            }); 
         } 
          
         if ( colsValues.length == 0 ) 
            return; 
             
         ExcelExporterUtil.export(dg.dataProvider, colsValues, defaultName); 
      } 
       
      /** 
       *  
       * Export to Excell 
       *  
       * @param obj          Objeto simple, XML, XMLList, Array, ArrayCollection o XMLListCollection 
       *                   que se quiere exportar a excel 
       * @colsValues         Listado de objetos que indican cual es el nombre de la columna 
       *                   y que propiedad del objeto se utiliza para sacar los datos de la columna 
       *                   {header:"nombre del header", value:"propiedad del objeto que contiene el valor"} 
       * @param defaultName   Nombre default con el que se genera el excel 
       *  
       */ 
      static public function export(obj:Object, colsValues:Array, defautlName:String):void 
      { 
         var _dp:ICollectionView = ExcelExporterUtil.getDataProviderCollection(obj); 
         if ( _dp == null ) 
            return; 
          
         var rows:Number = 0; 
         var cols:Number = 0; 
         var cantCols:Number = colsValues.length; 
         var sheet:Sheet = new Sheet(); 
         sheet.resize(_dp.length+1, colsValues.length); //El +1 es Para incluir el ultimo renglon
          
         for ( ; cols < cantCols; cols++) 
         { 
            sheet.setCell(rows, cols, colsValues[cols].header); 
         } 
          
         cols = 0; 
         rows++; 
         var cursor:IViewCursor = _dp.createCursor(); 
         while ( !cursor.afterLast ) 
         { 
            for (cols = 0 ; cols < cantCols; cols++) 
            { 
               if ( (cursor.current as Object).hasOwnProperty(colsValues[cols].value) ) 
                     sheet.setCell(rows, cols, (cursor.current as Object)[colsValues[cols].value]); 
            } 
             
            rows++; 
            cursor.moveNext(); 
         }
  
          
         var xls:ExcelFile = new ExcelFile(); 
         xls.sheets.addItem(sheet); 
         var bytes:ByteArray = xls.saveToByteArray(); 
          
         var fr:FileReference = new FileReference(); 
         fr.save(bytes, defautlName); 
      } 
       
      //----------------------------- 
      // Private function 
      //----------------------------- 
      /** 
       *  
       * A partir de un elemento pasado se genera un ICollectionView 
       * para su correcto recorrido 
       *  
       * @param obj         Objeto a convertir a ICollectionView 
       *  
       *  
       * @return referencia a un ICollectionView.  
       *  
       */ 
      static private function getDataProviderCollection(obj:Object):ICollectionView 
      { 
         if ( (obj is Number && isNaN(obj as Number)) || (!(obj is Number) && obj == null)) 
         { 
            return null; 
         } 
         else if ( obj is ICollectionView ) 
         { 
            return obj as ICollectionView; 
         } 
         else if ( obj is Array ) 
         { 
            return new ArrayCollection(obj as Array); 
         } 
         else if ( obj is XMLList ) 
         { 
            return new XMLListCollection(obj as XMLList); 
         } 
         else if ( obj is XML ) 
         { 
            var col:XMLListCollection = new XMLListCollection(); 
            col.addItem(obj); 
            return col; 
         } 
         else if ( obj is Object ) 
         { 
            return new ArrayCollection([obj]); 
         } 
         else 
         { 
            return null; 
         } 
      } 
   } 
}
 

[segma]

Hola Sergestux, muchas gracias. Ya lo he hecho pero ahora me peta lo que te contaba anterior mente

import com.as3xls.xls.ExcelFile;
import com.as3xls.xls.Sheet;

Me dice que no están definidas.

¿He de hacer algo con esta librería? o ¿me he de bajar algo?
Saludos y gracias de nuevo.

[Sergestux]

Si tienes mucha razon, te hace falta agregar la libreria.

En el menu Project -> Properties -> Flex Build Path ... Escoges la pestaña Library Path y de las opciones del lado derecho escoges Add SWC y y con esto buscas la libreria que bajaste .swc y ya no te deberia marcar algn error

[segma]

Pues muchas gracias, perfecto ahora ya no me peta esta librería, era eso que no sabía como instalar un swc.
Ahora hay una función llamada fr.save(bytes, defautlName); que me da un error de:

1061: Llamada a un método save posiblemente no definido mediante una referencia con tipo estático flash.net:FileReference. Graphics/src/com/utils
ExcelExporterUtil.as line 151 1266853191551 4615

es referente a la librería import flash.net.FileReference;

No se deja dominar este script. ¿Sabes si he de intalar o modificar el as?
De nuevo muchisimas gracias, y un saludo!!

[Sergestux]

Segun tengo entendido file reference solo funciona bien para flash 10 en adelante, asi que lo que tienes que hacer es actualizar tu propio flash y pedir a los cleintes que se instale la version 10 x en adelante
Project -> Properties - > Felx compiler -> Require flash player version

[segma]

Si, ya tengo bajado el flash player 10, pero he buscado y ponía que tenía que tener el SDK 3.4, lo he instalado, ahora no me da este error pero me da un error de ColumnChart

1046: No se encontró el tipo o no es una constante en tiempo de compilación: ColumnChart

Como si no estuviese implementado, o algo así, en teoría la versión es estable, al menos lo pone.