Comunicacion entre Variables de Peliculas externas *AS 3

[buhomorado]

Hola, he estado buskando por todos lados y no he encontrado la solución concreta.

Estoy haciendo unas pruebas simples para entender como se comunican las peliculas cargadas entre si.

Esta unica linea de codigo esta en el frame 1 de la pelicula la cual exportaré bajo el nombre de uno.swf:


/// Creo la variable mama y le doy un valor de 5
var mama:Number = 5;



Ahora bien, una vez exportada la anterior pelicula bajo el nombre de: uno.swf, la cargo en otra pelicula. Estas lineas de codigo estan ubicadas en el primer frame de lapelicula "cargadora":

/// Creamos el Contenedor para cargar la pelicula externa
var cargador:Loader = new Loader();
/// Hacemos la petición de carga de la pelicula uno.swf
var cual:URLRequest = new URLRequest("uno.swf");


/// Doy la orden de carga de la pelicula
cargador.load(cual);

/// Pongo la instancia en el escenario
addChild(cargador);

/// Ahora trato de comunicarme con la pelicula uno.swf, pero sin exito
if (stage.child.mama == 5) {
trace ("Dizke es igual a Cinco");
} else { trace ("Si no es igual a Cinco, no conozco otros numeros");
}


Obviamente me da error, ya que no se como comunicarme con la pelicula externa (uno.swf). Alguien podria ayudarme? a cambiar las lineas stage.child.mama por la forma correcta?

Cual es la ruta? Algun tutorial que expliqué la comunicación entre externas?

[buhomorado]

Este codigo me funcionó:

if (MovieClip(cargador.parent).mama == 5) {
trace ("Dizke es igual a Cinco");
} else { trace ("No es igual a Cinco, no conozco otros numeros");
}

[buhomorado]

Sospecho que algo es incorrecto... El "condicional" no esta funcionando...

[buhomorado]

Prueba No Superada :( No hay comunicación entre las variables.

[buhomorado]

Por lo que veo nadie ha sido capaz de resolver el ENIGMA de las "rutas".

Es decir. Tengo una pelicula Madre.
Y una pelicula externa swf, que es la hija, la cual sera cargada.

La Madre tiene un cargador (Como se explica arriba en los anteriores, un Loader), el cual carga una pelicula hija.

La pelicula hija tiene una variable de valor numerico.

Como puedo comunicarme desde la pelicula madre para evaluar el valor de la variable que esta en la pelicula hija.

root.child
root.parent
child.child
content.child
parent.child, etc etc... No ha funcionado nada.. Algo debo estar pasando por alto.

Si alguien pudiese explicarme que es lo que esta mal, me ayudaría a terminar con este "cuello de botella", ya que ya tengo toda la iNterfase del Interactivo, y todo depende de este punto. LA COMUNICACION ENTRE LAS PELICULAS.

Ayuda, por favor.

[buhomorado]

Nuevamente mando este POST arriba, a ver si Zeus me oye....

Repaso de la película:

1. David es un Diseñador Web Frustrado aprendiendo Actionscript 3.
2. David elabora un código para un CD interactivo y se da cuenta de que le es necesario evaluar cierta cantidad de variables entre una pelicula madre y una pelicula "anidada", por medio de un Loader, y addChild.
3. David intenta mil y un maneras de comunicarse entre las variables de la pelicula hijo a la pelicula madre. Pero solo obtiene Errores.
4. David Viene a forosdelweb ahacer su pregunta y esperar respuesta..
5. David lleva 4 días sin dormir...
6. David regresa a la escena del crimen, esta vacio.
7. El asesino esta escondido detras del armario, saca una navaja.
8. Por casualidad David nota la sombra y detiene el golpe, comienza el forcejeo.
9. David alcanza a tomar de un estante una figura de porcelana, la cual estampa en la cabeza del asesino.
10. Finalmente, inconsciente el asesino le quita la máscara...
11. El asesino es Andrea Bocelli, quién frustrado por las bajas ventas de su ultimo Disco "Christmas with Mr. Bocelli", decide robar la Navidad.
13. Bocelli tras las rejas jura que un día le hará pagar a David.


Me salte el 12.

...
12. David regresa a forosdelweb y los Diseñadores armaron un complot debido a la baja incidencia de respuestas a preguntas estupidas, TMeister tiene jaqueca y no esta capacitado para tomar decisiones. David toma el mando e instruye como primer mandato: Que se conteste la pregunta de las variables. pero Bandit hace una revuelca junto con los adoradores de AS 2 y comienza la lucha entre el bien y el Mal.

[Lynxcraft]

a ver este es un script que funciona como globals para la carga y recogida de variables dentro de swf externo

Código PHP:

  package com.cfx.utils{
    [Bindable]
    public class Global {
        public var _var:Object={};
        public var _class:Object={};
        public var _function:Object={};
        public static var TypeVar:String='_var';
        public static var TypeClass:String='_class';
        public static var TypeFunction:String='_function';
        public var value:*;
        private static var instance:Global;
 
        public function Global() {
        }
        public static function setGlobal(value:Object,type:String):Global {
            ini();
            for (var prop in value) {
                instance[type][prop]=value[prop];
            }
            return instance;
        }
        public static function getGlobal(name:String,type:String):Global {
            ini();
            if (instance[type][name]) {
                instance.value=instance[type][name];
            }
            return instance;
        }
        public static function getType(type:String):Global {
            ini();
            instance.value=instance[type];
            return instance;
        }
        private static function ini():void {
            if (instance==null) {
                instance=new Global  ;
            }
        }
        public static function get VAR():* {
            ini();
            return instance[TypeVar];
        }
        public static function get CLASS():* {
            ini();
            return instance[TypeClass];
        }
        public static function get FUNCTION():* {
            ini();
            return instance[TypeFunction];
        }
        public static function listName(type:String):Array {
            ini();
            var Names:Array=new Array
            for (var prop in instance[type]) {
                Names.push(prop);
            }
            return Names
        }
        public static function liberate():void {
            ini();
            instance[TypeFunction]=null
            instance[TypeClass]=null
            instance[TypeVar]=null
            instance=new Global 
        }
    }
} 
   

por ejemplo en el swf principal creas una funcion como por ejemplo

Código PHP:

  import com.cfx.utils.Global;
 
//funcion que quremos que sea global
 
function functionGlobalXXX (value:String):void{
    trace(value)
}
//registramos la funcion 
 
Global.setGlobal({funGxxx:functionGlobalXXX},Global.TypeFunction);
 
// ahora ya podemos ejecutar dicha funcion de esta manera
 
Global.FUNCTION.funGxxx('hola Mundo') 
   

en el swf externo podemos ejecutar la misma fucnion de esta manera

Código PHP:

  import com.cfx.utils.Global;
Global.FUNCTION.funGxxx('hola Mundo')//hola Mundo 
   

para las variables es lo mismo

en el swf principal

Código PHP:

  import com.cfx.utils.Global;
var miVariableGlobal:String='Hola Mundo'
Global.setGlobal({variable:miVariableGlobal},Global.TypeVar); 
   

en el swf externo

Código PHP:

  import com.cfx.utils.Global;
trace(Global.VAR.variable) //Hola Mundo 
   

de esta manera puedes controlar variables globales y leerlas tanto de swf externo como de la pelicula principal

[mortiprogramador]

Hola
Bueno, no soy el único con n dias sin dormir, y por lo que veo el efecto
delirio si es propagable, a diferencia de la comunicación entre las variables

pregunto, ambas peliculas (madre e hija) son as3??
dame pistas para resolver el caso
saludos

[buhomorado]

Gracias Lynxcraft y mortiprogramador.

Lynx, estoy por probar el código a ver como me va. Ahorita posteo lo que ocurrio.

Y en cuando a morti, te platico un poco más de las "peliculas".

Este Código esta en la Pelicula "MADRE", la que cargara a la película uno.swf.

Código:

import gs. *;
import gs.easing. *;

var cargador:Loader = new Loader();
var cual:URLRequest = new URLRequest("uno.swf");

cargador.load(cual);

addChild(cargador);



if (MovieClip(cargador.child).mama == 5) 
//// Es decir que si la variable mama de la pelicula cargada es igual a 5, la pelicula cargador se mueve a la posicion 1400 //
{
	TweenMax.to ( cargador, 4.5,
			 {x:-1400, ease: Elastic.easeOut}
			 )
	trace ("Como es igual a 5 Se movio a -1400");
	} else { 
	TweenMax.to ( cargador, 4.5,
			 {x:0, ease: Elastic.easeOut}
	trace ("Como no es igual a 5 se quedo en 0");
	}  /// Obviamente todo esto, da un error... Por que MovieClip(cargador.child).  es una de las tantas tonteras de "RUTA" que intente para comunicarme...

Este es el código de la pelicula uno.swf. Lo unico que hace es declarar la variable mama, con la que me quiero comunicar.

Código:

var mama:Number = 5;
trace (mama);

[buhomorado]

En la pelicula Madre:

Código:

import gs. *;
import gs.easing. *;
import com.cfx.utils.Global; 


var cargador:Loader = new Loader();
var cual:URLRequest = new URLRequest("uno.swf");
cargador.load(cual);
addChild(cargador);


if (Global.VAR.mama == "Sabelotodo") 
//// Es decir que si la variable mama de la pelicula cargada es igual a "Sabelotodo", la pelicula cargador se mueve a la posicion -1400 //
{
	TweenMax.to ( cargador, 4.5,{x:-1400, ease: Elastic.easeOut} )
} else { 
	TweenMax.to ( cargador, 4.5,{x:0, ease: Elastic.easeOut })
}

trace (Global.VAR.mama);

En la Pelicula Hija:

import com.cfx.utils.Global;

Código:

var mama:String="Sabelotodo"; 
Global.setGlobal({variable:mama},Global.TypeVar);  

trace (mama);

Y pruebo entonces la pelicula madre.. Obtengo en la salida:

undefined
Sabelotodo

Obviamente el undefined es

if (Global.VAR.mama == "Sabelotodo")

y el Sabelotodo es el trace que hago en la pelicula Hija.


Lynx, ves algun error? Gracias por tu código sigo intentandole.

[mortiprogramador]

Hola
Bueno, vamos a hacer esto con clase...
de hecho, con clases!

Pasos a seguir:

0. En el fla que va a ser de hija (uno.fla por ej) ir al escenario
y en el panel de propiedades asignarle una clase,
en nuestro caso uno (y esto va a hacer referencia a un archivo uno.as)

1. En el fla que va a ser de madre (madre.fla por ej) hacemos lo mismo
pero la clase sera madre (archivo madre.as)

2. Crearemos los archivos .as al mismo nivel (carpeta) que los fla

Y empieza lo chevere

En uno.as ira lo siguiente:

Código actionscript:

package 
{
    import flash.display.MovieClip;
    public class uno extends MovieClip
    {
        private var hija:Number = 5;
        public function uno():void {
            init();
        }
        
        public function init():void {
            //trace("HOLA EN UNO ");
        }
        
        public function probando():Number {
            return hija;
        }
    }
}
 

y en madre.as lo siguiente

Código actionscript:

package
{
    import flash.display.MovieClip;
    public class madre extends MovieClip 
    {
        public var hija:uno = new uno();
        private var mama:Number;
        public function as3():void {
            init();
        }
        
        function init():void {
            mama = hija.probando();
            trace("HOLA EN AS3 " + mama);
        }
        
    }
 
}
 

Obviamente esto puede mejorarse aún más con los dispatchevent
y los addlistener, y eventos personalizados y muchas mas cosas
que tiene as

prueba y comentas
saludos

[Lynxcraft]

esta mal tienes que ver el nombre con que la registras

Código PHP:

  import gs. *;
import gs.easing. *;
import com.cfx.utils.Global; 
 
 
 
 
var cargador:Loader = new Loader();
var cual:URLRequest = new URLRequest("uno.swf");
cargador.load(cual);
addChild(cargador);
 
 
if (Global.VAR.variable== "Sabelotodo") 
//// Es decir que si la variable mama de la pelicula cargada es igual a "Sabelotodo", la pelicula cargador se mueve a la posicion -1400 //
{
    TweenMax.to ( cargador, 4.5,{x:-1400, ease: Elastic.easeOut} )
} else { 
    TweenMax.to ( cargador, 4.5,{x:0, ease: Elastic.easeOut })
}
 
trace (Global.VAR.variable); 
   

[Kottore]

Es mi imaginación o se están pirando demasiado con las clases? ^_~

Lo único que se necesita para tomar el valor de una variable en un movieClip externo es hacer referencia al movieClip en el padre en su propiedad contenido así:

Código ActionScript:

trace(MovieClip(cpCargador.content).varMama);
 

Donde cpCargador es tu Loader y varMama es tu variable.

Saludos ^_^


PD. 14-de entre las sombras obscuras del internet emerge un personaje de identidad incierta que resulve el enigma que tenía tan desesperado a un búho que hasta morado se puso... y ara Kottore se queda en espera de un cuantioso cheque que usará para fines de investigación ^.^

[mortiprogramador]

Hola

Kottore, ese trace lo has probado en as3?

Pues si lo pongo da este mensaje

Código HTML:

TypeError: Error #1009: No se puede acceder a una propiedad o a un método de una referencia a un objeto nulo.
    at as3_fla::MainTimeline/frame1()

saludos

[Lynxcraft]

o asi

Código PHP:

  var mc:MovieClip=cpCargador.content as MovieClip

trace(mc.varMama) 
   

la utilización de clases es para un mejor control y registro de datos XDXD

[Kottore]

Iniciado por mortiprogramador

Hola

Kottore, ese trace lo has probado en as3?

Pues si lo pongo da este mensaje

Código HTML:

TypeError: Error #1009: No se puede acceder a una propiedad o a un método de una referencia a un objeto nulo.
    at as3_fla::MainTimeline/frame1()

saludos

Es porque tiene contenido numérico. Agregar ""+ para que vaya o una palabra extra. Yo puse:

Código ActionScript:

trace("variableExterna: "+MovieClip(cpCargador.content).varMama);
 

Cualquier cosa aqui dejo los *.fla

Saludos

[mortiprogramador]

Hola

He copiado tu nuevo aporte

Iniciado por Kottore

Es porque tiene contenido numérico. Agregar ""+ para que vaya o una palabra extra. Yo puse:

Código ActionScript:

trace("variableExterna: "+MovieClip(cpCargador.content).varMama);
 

quedandome así

Código actionscript:

trace("variableExterna: "+MovieClip(cargador.content).mama);
 

pero muestra el mismo mensaje

Lynxcraft, mismo mensaje, basado en tu post

Código actionscript:

var mc:MovieClip=cargador.content as MovieClip
trace(mc.mama)
 

saludos

[buhomorado]

Que diablos.... Yo ya abandone el proyecto por esa simple "ligereza" de las rutas, nunca imaginé que la discusión aún seguiría en pie... probaré el código de Kotore a ver si funciona.

[mortiprogramador]

Hola
jajjaja aqui nos matamos la cabeza!
probaste el código que te postee?
funciona como necesitas?

comentas
saludos

[TMeister]

:)

Bueno primero no se puede acceder a las propiedades de nada que no se haya cargado completamente.

Estan tratando de acceder a algo que aun no se carga.

child.swf

Código actionscript:

var somevalue:Number = 1000;
 

SWF que carga

Código actionscript:

import flash.display.Loader;
import flash.events.Event;
import flash.net.URLRequest;
import flash.display.MovieClip;
import flash.display.LoaderInfo;
 
var loader:Loader = new Loader();
var swf:URLRequest = new URLRequest("child.swf");
 
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loaderComplete);
loader.load( swf );
 
function loaderComplete(e:Event)
{
    trace("El Archivo ha sido cargado. Ahora podemos acceder a sus propiedades");
    var child:LoaderInfo = e.target as LoaderInfo;
    var mc:MovieClip = child.content as MovieClip;
    addChild( mc )
    trace ( mc.somevalue )
}
 
trace("No podemos acceder a las propiedades de algo que aun no se carga")
 

y listo!! ;)

[buhomorado]

morti, siento mucho no tener clase...

Veras es mi primer error, el hecho de que no he aprendido a usar las clases, todo lo programo (como en AS2), en el frame 1 de la linea principal.

:0( Así que no entiendo como ajustar ese código a mi Array.

El codigo de Kotore parece funcionar muy bien.

TMeister, luego pruebo ese código, grax y disculpa por la mención anterior en la historia hipérlucida.


Espero que alguién más les sirva este post... Ahora sigo averiguando de los malditos Arrays.

Saludos a todos desde el desierto del Mal. Reynosa Tamaulipas, Mex.

[mortiprogramador]

Hola
Bueno, pues mira este post a ver si tal vez
se te hace más amigable las clases

En cuanto a los arrays, no son tan enredados
como parecen, revisa esto

doc
ej

saludos