class en Flash (donde va?)

[Raziel]

Meencontre una programacion para crear tooltips en Action Script 2.0, sin embargo, la parte que empieza con:

class ToolTip { .... etc

no se donde ubicarla, la guarde en una archivo .as pero Flash me dice que "The classo or interface 'Tooltip' cannot be loaded o que tiene que ser un archivo externo de Actions Script 2.0 class Script.. cual es ese???.... como lo hago? plis! help!

Bandit: oie, te juro que intentetodo pero no puedo hacer que tu tooltip jale en mi archivo, por eso busque otras opciones.... mis movie clips que quiero que tengan esa accion estan dentro de varios moviclips mas y por eso no jala...!

[jahepi]

Hola Raziel !

La clase va en un archivo aparte .as, si la clase esta declarada así:

Código PHP:

  class ToolTip {
} 
   

Debes de colocar el archivo en la misma carpeta donde se encuentra el .fla.

Un saludote !

[Raziel]

esque eso es lo mas extraño, asi lo hice y me marca ese error!.... :S
como lo declaro en mi pelicula flash para que lo jale o como? ...
en mi pelicula el codigo esta asi: comole digoque mande llamar el archivo?... le dije #include "tooltip2.as" al inicio pero me dice que no jala...

var myTip:ToolTip = new ToolTip();

//start the tip
myMC.onRollOver = function () { myTip.addTip("Hello, whazzaaa!");}

//remove tip in all possibilities
myMC.onRollOut = function () { myTip.removeTip(); }
myMC.onRelease = function () { myTip.removeTip(); }
myMC.onDragOut = function () { myTip.removeTip(); }
myMC.onReleaseOutside = function () { myTip.removeTip(); }


que me falta?...

[jahepi]

Hola Raziel ! !

Esta muy raro, no debes usar include, en lugar se utiliza la palabra reservada import pero en tu caso no es necesario porque el classpath esta definido para que el programa busque primero en la carpeta donde se encuentra el .fla.

Mejor pega aqui la clase para ver si no esta en AS3.0 o a lo mejor esta usando paquetes.

Un saludote !

[Raziel]

va el class completo:

class ToolTip {
public var tip:MovieClip;
public var tipMask:MovieClip;
private var tip_txt:TextField;
private var removeInterval:Number;
private var pauseInterval:Number;

public var lineColor:Number = 0x666666;
public var bgColor:Number = 0xFFFFE9;
public var shadowColor:Number = 0x777777;
public var sD:Number = 3; //shadow distance
public var PAUSE_INT:Number = 800; //time until tip shows up
public var REMOVE_INT:Number = 4000; //time that tip stays on

function ToolTip() {
}

public function addTip(words:String):Void {

tip = _root.createEmptyMovieClip("tip", _root.getNextHighestDepth());
tip._x = _root._xmouse;
tip._y = _root._ymouse;

tip.onEnterFrame = function() {
this._x += ((_root._xmouse-this._x-2)*0.2);
this._y += ((_root._ymouse-this._y-5)*0.2);
};

pauseInterval = setInterval(this, "setText", PAUSE_INT, words);

}


private function setText(words:String):Void {
clearInterval(pauseInterval);

//create empty text holder
tip.createTextField("txt", 0, -8, -21, 0, 20);
tip.txt.autoSize = true;
tip.txt.border = false;
tip.txt.selectable = false;
tip.txt.type = "dynamic";
tip.txt.text = words;
//set font style
var myformat:TextFormat = new TextFormat();
myformat.font = "Verdana,Arial";
myformat.size = 10;
tip.txt.setTextFormat(myformat);
var textWidth = tip.txt._width;

drawBubble(textWidth); //now draw bubble

//time to remove tip
removeInterval = setInterval(this, "removeTip", REMOVE_INT);
}


//draw the bg bubble for the text field
private function drawBubble(textWidth:Number):Void {

//get text width from text field
tip.createEmptyMovieClip("outline_mc", -1);
tip.outline_mc.enabled = false;
tip.outline_mc.lineStyle(0, lineColor, 100);
tip.outline_mc.beginFill(bgColor, 100);
tip.outline_mc.moveTo(0, 0);
tip.outline_mc.lineTo(-3, -3);
tip.outline_mc.lineTo(-10, -3);
tip.outline_mc.lineTo(-10, -20);
tip.outline_mc.lineTo(textWidth-6, -20);
tip.outline_mc.lineTo(textWidth-6, -3);
tip.outline_mc.lineTo(3, -3);
tip.outline_mc.lineTo(0, 0);
tip.outline_mc.endFill();

drawShadow(textWidth); //now draw shadow

}


private function drawShadow(textWidth:Number):Void {

tip.createEmptyMovieClip("shadow_mc", -2);
tip.shadow_mc.beginFill(shadowColor, 40);
tip.shadow_mc.moveTo(0+sD, 0+sD);
tip.shadow_mc.lineTo(-3+sD, -3+sD);
tip.shadow_mc.lineTo(-10+sD, -3+sD);
tip.shadow_mc.lineTo(-10+sD, -20+sD);
tip.shadow_mc.lineTo(textWidth-6+sD, -20+sD);
tip.shadow_mc.lineTo(textWidth-6+sD, -3+sD);
tip.shadow_mc.lineTo(3+sD, -3+sD);
tip.shadow_mc.lineTo(0+sD, 0+sD);
tip.shadow_mc.endFill();

}


public function removeTip():Void {
clearInterval(pauseInterval);
clearInterval(removeInterval);
//die();
tip.swapDepths(10005); //some sort of hack found on AS.org
tip.removeMovieClip();
delete this;
}



public function die():Void {
clearInterval(removeInterval);
delete tip;
}
}

[jahepi]

Hola Raziel !

Pues no esta en As3.0 ni tampoco utiliza paquetes, algo que se me paso decirte es que el archivo debe tener el mismo nombre que la clase, si tu clase se llama ToolTip, el archivo debes de guardarlo como ToolTip.as


Un saludote !

[Raziel]

dejame intentar eso jahepi...
oie, si mi archivo es original de ActionScript 1.0 no va a jalar?

[Raziel]

demoños, ya renombre el script a ToolTip.as yme dice que:

The class or interface 'ToolTip' could not be loaded

[jahepi]

Hola Raziel !

Si tu proyecto esta en as1.0 esa es la razón del problema, debes cambiarlo a as2.0.

Un saludote !

[Raziel]

la cosa es...
ahoritaestoy haciendo una prueba en un archivo aparte, en action Script 2.0...
y pasa lo mismo!..
te juro que ya estoy desesperada, he intentado como 10 tooltips diferentes y no lo puedo echar a andar.... :( y espara esta semana... es lo unico que me falta para terminar mi propuesta....

si sabesde algo que jale para todo yentodos los niveles de instanca (movie clipsdentro de otroso botones dentro de movie clips) te lo agradeceria infinito!!...

[jahepi]

Hola Raziel !

Estaba viendo el código de la clase y hay un pequeño error en la definición del constructor, debes de cambiarlo de esto:

Código PHP:

  function ToolTip() {
} 
   

a:

Código PHP:

  public function ToolTip() {
} 
   

Con eso ya no debes de tener problemas.

Un saludote !