Cargar múltiples MC

[dvpareja]

Buenas tardes a todos,

Estoy tratando de importar a escena una serie de clips a los que he nombrado de la siguiente forma:

cartas_0_0
cartas_0_1
cartas_0_2
.
.
.
cartas_9_4

Es una baraja de 10 palos con 5 cartas por palo.

Al ser 50 MC los que quiero importar, no es cuestión de ir metiéndolos uno a uno. Con AS2 podía usar nombres de variables dinámicos, pero con AS3 no sé como hacerlo. Llevo horas buscando en internet y he encontrado clases en AS3 que me permiten importar un clip, he estado jugando con ellas y tengo algo como esto:

Código actionscript:

package {
    import flash.display.MovieClip;
    import flash.display.Sprite;
    //
    public class Main extends MovieClip {
        private var _root:MovieClip;
        private var cardInstance_:Sprite;
        private var cartas_:Sprite;
 
            
        //
        public function Main(ruta:MovieClip) {
            _root = ruta;
            //
            var i:int;
            var j:int;
            var a;
                for (i=0;i<=9;i++){
                    for (j=0;j<=4;j++){
                        
                        cardInstance_ = new Sprite();
                        cardInstance_.name = "cardInstance_" + i + "_" + j;
                        cartas_ = new Sprite();
                        cartas_.name = "cartas_" + i + "_" + j;
                        trace (cartas_.name);
                        addChild( cardInstance_ );
                        addChild( cartas_ );
                        getChildByName("cardInstance_"+i+"_"+j).x = 500;
                        getChildByName("cardInstance_"+i+"_"+j).y = 20;
                        _root.addChild(getChildByName("cardInstance_"+i+"_"+j));
        
                    }
                }
        }
    }
}
 

Entiendo que algo me debe faltar porque aunque no me da error de compilación, no se muestran las cartas.

Gracias de antemano por su ayuda

[mortiprogramador]

Hola
as3 y usan _root!!
primera vez que veo eso!!

bueno, pues en as3 hay varios modos, pero el más 'similar'
para con as2 sería este

Código actionscript:

//res es un movieclip de librería que esta exportado y en Class tiene el valor 'res'
var ClassReference:Class = getDefinitionByName("res") as Class;
        var mc:Object = new ClassReference(); //mc es la instancia creada
        mc.y = 100; // asigno posición en y
        mc.caja.text = 'hola'; //asigno valor a campo de texto del movieclip
        addChild(DisplayObject(mc)); //lo agrego al stage
 

y pues claro, esto estaría en un for de tantas cartas como necesites,
y el "res" como son N cartas, pues usaría un array, y aprovechando el for,
pues pondría ese array como parámetro del getDefinitionByName
saludos

[dvpareja]

Muchas gracias por tu respuesta, el código me quedó así y funciona perfectamente

Código ACTIONSCRIPT:

package {
    import flash.utils.*;
    import flash.display.MovieClip;
    import flash.display.DisplayObject; 
    
    public class Main extends MovieClip {
      private var ClassReference:Class; 
      private var mc:Object; 
      private var mc_Array:Array;
        
        public function Main():void {
 
        var mc_Array:Array = new Array(); //mc_Array es una matriz que contiene todos los mc ordenados
        //cartas_i_j es un movieclip de librería que esta exportado y en Class tiene el valor 'cartas_i_j'
            for (var i:Number=0;i<=9;i++){
                for (var j:Number=1;j<=5;j++){
                    var ClassReference:Class = getDefinitionByName("cartas_"+i+"_"+j) as Class;
                    var mc:MovieClip = new ClassReference(); //mc es la instancia creada
                    mc_Array.push([mc]); // introduczo los mc en mc_Array
                }
            }
            DesordenarArray(mc_Array); // Desordeno el Array
            
            for (var n=1;n<mc_Array.length;n++) {
            // AQUI QUIERO MOSTRAR LOS CLIPS
            }    
                  
        } // end Main
 
        private function DesordenarArray(array):void {
               var elementos=array.length;
               for (var i=elementos-1;i>1;i--){ 
                  var alea:int=Math.floor(i*Math.random()); 
                  var temp:Object=array[i]; 
                  array[i]=array[alea]; 
                  array[alea]=temp; 
                }
            }
 
 
    } // end Class
} // end Package
 

El problema que me surge ahora es que si uso

Código ACTIONSCRIPT:

addChild(DisplayObject(mc_Array[n]));
 

para agregar las cartas desordenadas, me da este error:

TypeError: Error #1034: Error de conversión forzada: no se puede convertir []@30ffaf1 en flash.display.DisplayObject.

¿Me podríais decir qué hago mal?

Gracias de nuevo

[dvpareja]

Ok, solucionado este problema, el código me quedó así (acepto sugerencias)

Código ACTIONSCRIPT:

package {
    import flash.utils.*;
    import flash.display.MovieClip;
    import flash.display.DisplayObject;
    
    public class Main extends MovieClip {
      public var ClassReference:Class; 
      public var mc:Object; 
      public var mc_Array:Array;
        
        public function Main():void {
 
        var mc_Array:Array = new Array(); //mc_Array es una matriz que contiene todos los mc ordenados
        //cartas_i_j es un movieclip de librería que esta exportado y en Class tiene el valor 'cartas_i_j'
            for (var i:Number=0;i<=9;i++){
                for (var j:Number=1;j<=5;j++){
                    var ClassReference:Class = getDefinitionByName("cartas_"+i+"_"+j) as Class;
                    // introduzco en un Array todas las instancias de los movieClip
                     mc_Array.push({mc:new ClassReference(),name:"cardInstance_"+i+"_"+j}); 
                }
            }
            DesordenarArray(mc_Array); // Desordeno el Array
            
            for (var n=0;n<mc_Array.length;n++) {    // Posiciono las cartas en la Escena Convenida
                mc_Array [n].mc.x = 500;
                mc_Array [n].mc.y = 20+n;
                addChild(mc_Array [n].mc); 
                // trace (mc_Array [n].mc.name)
            }    
                  
        } // end Main
 
        private function DesordenarArray(array):void {
               var elementos=array.length;
               for (var i=elementos-1;i>1;i--){ 
                  var alea:int=Math.floor(i*Math.random()); 
                  var temp:Object=array[i]; 
                  array[i]=array[alea]; 
                  array[alea]=temp; 
                }
            }
 
 
    } // end Class
} // end Package
 

Sin embargo, no me hace caso a la hora de darle nombre a las instancias que agrego en al Array, me pone el nombre genérico de Instance1, Instance2 ....

¿Sabe alguien como darle el nombre a la instancia antes de desordenar el Array?

[TMeister]

Cambia esto

Código Actionscript:

mc_Array.push({mc:new ClassReference(),name:"cardInstance_"+i+"_"+j});
 

por

Código Actionscript:

var mc_tmp = new ClassReference();
mc_tmp.name = "cardInstance_"+i+"_"+j
mc_Array.push({mc: mc_tmp});
 

Similar pero no lo mismo =)

[dvpareja]

Muchas Gracias a todos. Arreglado !!