cargar casa.jpg en flash

[arnaldo]

Hola, yo again, quiero cargar casa.jpg en una pelicula flash.
os agradesco.

[webgeri]

hace un MovieClip vacio le pones nombre de instancia por ej. contenedor

y cargas el .jpg asi

Código HTML:

contenedor.loadMovie("casa.jpg")

aqui tienes mas informacion del tema
LoadMovie
diccionario de actionscript macromedia Load Movie

con LoadMovie puedes cargar swf o jpg

recuerda siempre que el jpg o swf se ubica con su esquina superior izq.
en la posicion del MC donde lo cargas

sldos

[stock]

aqui teneis un ejemplo com ActionScript 2

Código PHP:

  var myContenidos:MovieClipLoader = new MovieClipLoader();
var myListener:Object = new Object();
 
myContenidos.addListener(myListener);
myContenidos.loadClip("imagen4.jpg",mcDestino); 
   

[arnaldo]

Gracias por la ayuda, pero ahi un pequeño problema, como puedo hacer para que me muestre un preload antes de mostrar la imagen, ya que la muestra de un tiron. please.

[radarcba]

Lo que tenes que hacer es armar un swf con la foto unicamente y hacerle el preload, despues cargas con los metodos que te enviaron webgeri o stock.
Acordate que tenes otra opcion que es la de usar loadMovieNum("nombre.swf",nivel);
Si queres saber mas como usar loadMovieNum() o loadMovie() te recomiendo que visites este post. http://www.forosdelweb.com/showthrea...r+loadMovieNum
Espero que te sirva mi ayuda. Nos vemos.

[webgeri]

para preguntar los datos de la precarga de un .jpg que cargas con loadMovie
en un contenedor preguntas los datos del contenedor poniendo contenedor.getBytesLoaded() por ej. asi el codigo donde prgeuntas los bytes cargados

Código:

if (contenedor.getBytesLoaded()<contenedor.getBytesTotal()) {
		carga = (contenedor.getBytesLoaded()/contenedor.getBytesTotal())*100;
		cargador_mc._xscale = carga;
		porcentaje = Math.floor(carga)+" % cargado";
}

bueno cualquier duda consutla sldos

[stock]

Hola amigo, acabo de terminar una clase que es exactamente para esto

1.- Crea un archivo llamado Cargador.as y pega esto

Código PHP:

  /*
 * Author: Crysfel Villa
 * Created: Saturday, August 13, 2005 6:45:23 PM
 * Modified: Saturday, August 13, 2005 6:45:23 PM
 * Version:  1.0
 */
 
class Cargador extends MovieClipLoader{
    private var mcCargando:MovieClip;
    private var mcTarget:MovieClip;
    private var bytesCargados:Number;
    
    public function Cargador(cargador:MovieClip){
        mcCargando = cargador;
        trace(mcCargando);
    }
    
    public function myLoadClip(url:String,target:MovieClip):Void{
        var myListener:Object = new Object(); 
        mcTarget = target;
        this.addListener(myListener);
        this.loadClip(url,target);
        trace("hacemos el loadClip");
    }
    
    public function onLoadStart ( target_mc:MovieClip ):Void
    {
        //trace("no hacemos nada en este evento :)");
    }
    
    //Cuando haces el TestMovie no funciona :( porque??
    //no lo se, pero cuando lo subes a la web, funciona perfecto :)
    public function onLoadProgress(target:MovieClip,loadedBytes:Number,totalBytes:Number):Void
    {
        bytesCargados = Math.floor((loadedBytes*100)/totalBytes);
        mcCargando.gotoAndStop(bytesCargados);
    }
    
    public function onLoadComplete(target_mc:MovieClip):Void
    {
        mcCargando._visible = false;
        mcCargando.removeMovieClip();
        trace("Termino la carga");
    }
    
    public function onLoadInit ( target_mc:MovieClip ):Void
    {
        //trace("no hacemos nada en este evento");
    }
    
    public function onLoadError ( target:MovieClip, error:String ):Void
    {
        trace ("No se pudo cargar el objeto en = " + target);
        trace ("ERROR  = " + error);
    }
    
} 
   

Ok, luego en el FLA necesitas crear la animacion de la barra cargadora, ponerlo en escena e instanciarlo, (tu animacion debe ocupar 100 frames), luego en algun frame, pones este code

Código PHP:

  import Cargador;
mcAnimCargador._visible = false;
 
btn.onRelease = function():Void{
    mcAnimCargador._visible = true;
    var c:Cargador = new Cargador(mcAnimCargador);
    c.myLoadClip("imagen.jpg",mcDestino);
 
} 
   

con ese codigo, cuando presiones el boton llamado btn se cargara la imagen y aparecera el cargador

bueno, espero te sirva tanto como ami

have funn

PD: comentarios o sugerencias, postea

[radarcba]

Muy bueno Stock. Ya me voy a hacer un tiempo para probarla.

[arnaldo]

Wow genial, muchas gracias a todos.