Utf-8

[Artepop]

Hola tengo este script en asp:

Código:

<%OPTION EXPLICIT%>

<%
dim cuantos
dim muestra
dim conexion
dim sql
dim archivo_creado
dim fso
dim archivo
dim rs
dim basedatos
cuantos=0
muestra = 100
archivo_creado= "noticias.xml"
basedatos = "datos/noticias.mdb"
set conexion=Server.CreateObject("ADODB.connection")
conexion.provider="Microsoft.Jet.OLEDB.4.0;"
conexion.open server.mappath(basedatos)
sql="select * from entradas order by id desc"
set fso = createobject("scripting.filesystemobject")
Set archivo = fso.CreateTextFile(server.mappath(archivo_creado), true)
set rs=conexion.Execute(sql)
archivo.WriteLine("<?xml version=""1.0"" encoding=""UTF-8""?>")
archivo.WriteLine("<rss version=""2.0"">")
archivo.WriteLine("<channel>")
archivo.WriteLine("<title>www.MFO.com.es</title>")
archivo.WriteLine("<link>http://www.mfo.com.es/noticias-xml.asp</link>")
archivo.WriteLine("<description>Ordenando la web hacia su máxima potencia, proyectado por Miguel Fernández Oviedo.</description>")
do while not rs.EOF and cuantos < muestra
archivo.WriteLine("<item>")
archivo.WriteLine("<title>"&rs("titulo")&"</title>")
archivo.WriteLine("<link>http://www.mfo.com.es/noticias_ver.asp?id="&rs("id")&"</link>")
archivo.WriteLine("<description>"&rs("subtitulo")&"</description>")
archivo.WriteLine("</item>")
rs.MoveNext()
cuantos=cuantos+1
loop
rs.close()
conexion.close()
archivo.WriteLine("</channel>")
archivo.WriteLine("</rss>")
archivo.close
%>

<%
Response.Write "<meta http-equiv=refresh content=0;URL=noticias.xml>"
%>

Este entra en la base de datos Access, crea un documento XML con las entradas de la base de datos y finalmente redirige al documento recientemente creado, osea a noticias.xml

Hasta ahi todo bien, pero quiero poner en el script una orden que al crear el documento lo cree codificado en UTF-8

¿?

Muchas gracias.

[David]

Puedes usar el ADODB.Stream:
http://gchandra.wordpress.com/2004/0...les-using-asp/
O usar estas funciones de codificación/decodificación UTF-8:
http://www.codetoad.com/asp_utf8.asp

[Artepop]

¿Cómo seria para montarlo en el script que puse?

[Adler]

Hola

No te has parado ni un minuto. En el caso que te indica David con funciones, solo has de hacer

archivo.WriteLine("<description>"&EncodeUTF8("Ordenando la web hacia su máxima potencia, proyectado por Miguel Fernández Oviedo.")&"</description>")

Suerte

[Artepop]

No VA !!! - Lo crea por la mitad, hasta description...

[Adler]

Hola

Sigue dandole vueltas que sí que funciona

Suerte

[Artepop]

Hola, monte este y funciona OK 100%

Código:

<%
const adTypeBinary = 1
const adSaveCreateOverwrite = 2
const adModeReadWrite = 3
Set objStream = server.CreateObject("ADODB.Stream")
objStream.Open
objStream.CharSet = "UTF-8"
set oConn=Server.CreateObject("ADODB.Connection")
set rs=Server.CreateObject("ADODB.Recordset")
oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source="&Server.MapPath("datos/noticias.mdb")&";"
SQL="SELECT TOP 1 * FROM entradas ORDER BY id DESC"
rs.Open SQL, oConn
objStream.WriteText("<?xml version=""1.0"" encoding=""UTF-8""?>")
objStream.WriteText("<rss version=""2.0"">")
objStream.WriteText("<channel>")
objStream.WriteText("<title>www.MFO.com.es</title>")
objStream.WriteText("<link>http://www.mfo.com.es/</link>")
objStream.WriteText("<description>Ordenando la web hacia su máxima potencia, proyectado por Miguel Fernández Oviedo.</description>")
objStream.WriteText("<language>es-es</language>")
objStream.WriteText("<webMaster>[email protected] (Miguel Fernández Oviedo)</webMaster>")
objStream.WriteText("<lastBuildDate>"&(rs("pubDate"))&"</lastBuildDate>")
rs.close
oConn.close
set oConn=Server.CreateObject("ADODB.Connection")
set rs=Server.CreateObject("ADODB.Recordset")
oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source="&Server.MapPath("datos/noticias.mdb")&";"
SQL="SELECT * FROM entradas ORDER BY id DESC"
rs.Open SQL, oConn
do while not rs.eof
objStream.WriteText("<item>")
objStream.WriteText("<title>"&(rs("titulo"))&"</title>")
objStream.WriteText("<link>http://www.mfo.com.es/noticias_ver.asp?id="&(rs("id"))&"</link>")
objStream.WriteText("<description>"&(rs("subtitulo"))&"</description>")
objStream.WriteText("<comments>http://www.mfo.com.es/noticias_ver.asp?id="&(rs("id"))&"#comentarios</comments>")
objStream.WriteText("<pubDate>"&(rs("pubDate"))&"</pubDate>")
objStream.WriteText("</item>")
rs.movenext
loop
objStream.WriteText("</channel>")
objStream.WriteText("</rss>")
objStream.SaveToFile server.mappath(".") & "/noticias.xml" , adSaveCreateOverWrite
rs.close
oConn.close
objStream.Close
%>

<%
Response.Status="301 Moved Permanently"
Response.AddHeader "Location", "noticias.xml"
%>

Muchas gracias a tod@s. Miguel
PD: Cuando me sea posible lo pondre en mi web bien explicado.

[Artepop]

Aqui esta listo y explicado dentro de mi pequeño conocimiento:
http://www.mfo.com.es/noticias_ver.asp?id=25
¡Sugerencias para mejorarlo! - Muchas gracias.

[Adler]

Hola

Como sugerencia, podrías usar getrows() en noticias_xml.asp. De esa manera la consulta sería más rápida.

Código asp:

Dim titulo, id, descripcion, fecha
titulo = 0
id = 1
descripcion = 2
fecha = 3
const adTypeBinary = 1
const adSaveCreateOverwrite = 2
const adModeReadWrite = 3
Set objStream = server.CreateObject("ADODB.Stream")
objStream.Open
objStream.CharSet = "UTF-8"
objStream.WriteText("<?xml version=""1.0"" encoding=""UTF-8""?>")
objStream.WriteText("<rss version=""2.0"">")
objStream.WriteText("<channel>")
objStream.WriteText("<title>Título de tu sitio web</title>")
objStream.WriteText("<link>http://www.tusitioweb.com/</link>")
objStream.WriteText("<description>Descripción de tu sitio web.</description>")
set oConn=Server.CreateObject("ADODB.Connection")
set rs=Server.CreateObject("ADODB.Recordset")
oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source="&Server.MapPath("noticias.mdb")&";"
SQL="SELECT titulo, id, descripcion, fecha FROM entradas ORDER BY id DESC"
rs.Open SQL, oConn
registros = rs.getrows()
rs.close
oConn.close
For i = 0 to UBound(registros,2)
objStream.WriteText("<item>")
objStream.WriteText("<title>"&(registos(titulo,i))&"</title>")
objStream.WriteText("<link>noticias_ver.asp?id="&(registos(id,i))&"</link>")
objStream.WriteText("<description>"&(registos(descripcion,i))&"</description>")
objStream.WriteText("<pubDate>"&(registos(fecha,i))&"</pubDate>")
objStream.WriteText("</item>")
Next 'i
objStream.WriteText("</channel>")
objStream.WriteText("</rss>")
objStream.SaveToFile server.mappath(".") & "/noticias.xml" , adSaveCreateOverWrite
objStream.Close
 
Response.Status="301 Moved Permanently"
Response.AddHeader "Location", "noticias.xml"
 

Suerte