Al crear PDF dinámico con FPDF me arroja un archivo en blanco

[rProgged]

Holas,

Tengo el siguiente problema: estoy intentando crear un archivo pdf con FPDF en forma dinámica, sin embargo lo que me entrega es un archivo pdf completamente en blanco.

El código que uso es el siguiente:

Código:

<%@language=vbscript%>
<!--#include file="fpdf.asp"-->
<!--#include file="conexiones/sspi.conn.inc.asp"--><%
sqlSelect = "SELECT nombre_usuario, rut_usuario, email_usuario FROM usuario"
set objUsuario = conn.execute(sqlSelect)
if not ( objUsuario.EOF ) then
	'Obtención de los registros del recordset
	dim tblUsuario
	tbl_nombre_usuario = 0
	tbl_rut_usuario = 1
	tbl_email_usuario = 2
	tblUsuario = objUsuario.GetRows
	objUsuario.Close
	set objUsuario = nothing
	conn.close
	set conn = nothing
	'Creación del documento PDF
	Set pdf = CreateJsObject("FPDF")
	pdf.CreatePDF "P","pt","Letter"
	pdf.SetPath("fpdf/")
	pdf.SetFont "Arial","",16
	pdf.Open()
	pdf.AddPage()
	pdf.Image "images/logo_chico.jpg", 20, 10, 120, empty, "JPG", "http://www.ucorp.cl"
	pdf.Cell 100, 100, "Prueba de creación de PDF's on-line"
	alto = 25
	cY = 150
        'lo limito solo a 10 debido a que no he programado aún el cambio de página
	'for j = 0 to ubound(tblUsuario,2)
	for j = 0 to 10
		pdf.setXY 100, cY
		pdf.Cell 250, alto, tblUsuario(tbl_nombre_usuario, j), 1, 1, "C"
		pdf.SetX 350
		pdf.Cell 100, alto, tblUsuario(tbl_rut_usuario, j), 1, 1, "C"
		pdf.SetX 450
		pdf.Cell 150, alto, tblUsuario(tbl_email_usuario, j), 1, 1, "C"
		cY = cY + alto
	next
	pdf.Output()
	pdf.Close()
else
	response.write "No se encontraron usuarios disponibles"
end if %>

No entiendo lo que pasa, he intentado con los ejemplos de la página e iba todo bien, pero al dinamizar obtengo este problema

¿Alguna idea de lo que pueda estar pasando?, de antemano muchas gracias por la ayuda.

Atte,

Rodrigo
Chile

[rProgged]

Ja, ya encontré el error, lo posteo por si a alguien le sirve el ejemplo. El error es en la siguiente línea:

pdf.Image "images/logo_chico.jpg", 20, 25, 120, empty, "JPG", "http://www.ucorp.cl"

Lo que ocurre es que fpdf redimenciona las imágenes cuando no le das o el ancho o el alto, de forma de mantener el aspecto. Entonces yo le estoy pasando el parámetro como sin definir (empty) pero no lo acepta, para hacer eso debo pasar el parámetro como 0, quedaría:

pdf.Image "images/logo_chico.jpg", 20, 25, 120, 0, "JPG", "http://www.ucorp.cl"

Espero le sirva a alguien.

Saludos desde Sudamérica,

Rodrigo
Chile