Excel mostrarlo en la web con ASP

[lfichelson]

Hola gente, soy nuevo en esto y estoy tratando de ver de que manera puedo mostrar una planilla EXCEL que contiene varias solapas, mediante un HTML que levante un ASP...me explico?...Gracias.
Para resumirles, necesito que una persona levante un excel desde un lugar y otra lo pueda ver e imprimir desde otra ubicacion...gracias

[Myakire]

1) Haces una página con tastas pestañas como el archivo Excel tenga (CSS)
2) Cada pestaña que abra su correspondiente del Excel, simplemente lo lees como una tabla:

Código ASP:

<%
    Dim sSourceXLS
 
    sSourceXLS = Server.MapPath(".") & "\Excel\RollosCosteados.xls"
 
    Dim oConn
    Set oConn = Server.CreateObject("ADODB.Connection")
    oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
               "Data Source=" & sSourceXLS & ";" & _
               "Extended Properties=""Excel 8.0;HDR=YES;"""
 
    Dim oRS 
    Set oRS = Server.CreateObject("ADODB.Recordset")
    oRS.Open "Select * from [Rollos$A1:Y1000]", oConn, 1, 3
    
        %>
        <table width="100%" border="1">
        <%
    Do While Not (oRS.EOF)
        %><tr><%
        For i = 0 To 24
                    %><td><%=oRS.Fields(i).Value%><%
        Next
        oRS.MoveNext
    Loop
        %>
        </table>
        <%
    
    oRS.Close
    Set oRS = Nothing
    
    oConn.Close
    Set oConn = Nothing
%>
 

Para lo de imprimir ..., pues no, si lo presentas en ASP, entonces lo tendría que imprimir desde su browser, quizá lo que quieres no es verlo sino simplemente subirlo al servidor (un upload, pues) -"que una persona levante un excel desde un lugar"- (sic) y descargarlo -"otra lo pueda ver e imprimir desde otra ubicacion"- (sic), lo que sería con un simple:

Código ASP:

Response.Buffer = True
Dim strFilePath, strFileSize, strFileName
Const adTypeBinary = 1
strFilePath = Request.QueryString("File")
strFileSize = Request.QueryString("Size")
strFileName = Request.QueryString("Name")
Response.Clear
 
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
objStream.Type = adTypeBinary
objStream.LoadFromFile strFilePath
ContentType = "application/vnd.ms-excel"
Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
Response.AddHeader "Content-Length", strFileSize
Response.Charset = "UTF-8"
Response.ContentType = ContentType
Response.BinaryWrite objStream.Read
Response.Flush
objStream.Close
Set objStream = Nothing