Mail con formato html con CDOSYS

[angel_dope]

Hola a todos, tenia una página que enviaba correos con formato html mediante CDONTS, al cambiar a un servidor con W2K3 he tenido que usar CDOSYS para que funcione (el cdonts no hay forma de hacerlo funcionar) peeeero, ahora me envia los correos como texto plano, sacando todo el código html del cuerpo tal cual. Que hay que modificar en el código para que vuelva a salir con el formato que toca??

Código PHP:

          texto2 = "Un usuario ha solicitado el registro en la web. Los datos introducidos son los siguientes:<br><br>"
        texto2 = texto2 & "Empresa: " & rs2("empresa")
        texto2 = texto2 & "<br>Cif: " & rs2("cifempresa")
        texto2 = texto2 & "<br>Email: " & rs2("usuario")
        texto2 = texto2 & "<br>Clave: " & rs2("Password")
        texto2 = texto2 & "<br>Nombre: " & rs2("nombre")
        texto2 = texto2 & "<br>Apellidos: " & rs2("apellidos")
        texto2 = texto2 & "<br>Telefono: " & rs2("telefono")
        texto2 = texto2 & "<br>Servicios: "
        servicio = rs2("servicios")
        if len(servicio) > 0 then
            hay_servicios = 1
            servicios = split(servicio, ", ")
            for i=0 to ubound(servicios)
                set rs3 = Server.CreateObject("ADODB.Recordset")
                rs3.CursorType = 1
                rs3.LockType = 3
                sql3 = "Select contenido from servicios where idservicio = " & servicios(i) 
                rs3.Open sql3, conex 
                texto2 = texto2 & rs3("contenido") & ", "
                rs3.close
            next
        end if
        texto2 = texto2 & "<br><br>Se han enviado correos de información a los responsables de estos servicios para que informen al usuario.<br> También le ha sido enviado un correo al usuario para informarle de la correcta recepción de sus datos quedando a la espera de la validación, o no, del usuario.<br>"
        texto2 = texto2 & "Para acceder a la validación de usuario pulse <a href='validar.asp?idusuario=" & rs2("idusuario") &"'>aqui</a>"
 
    dim Mailer2
    set Mailer2 = server.createobject("CDO.Message") 
    
    Mailer2.From = "[email protected]"
    Mailer2.To =  "[email protected]"
    Mailer2.TextBody = Texto2
    Mailer2.Subject = "Petición Registro Web"
    with Mailer2.Configuration
        .Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        .Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.dominio.com"
        .Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
        .Fields.Update
    end with
    Mailer2.Send
    set Mailer2 = Nothing
    CDOSYS_Mailer = true 
   

Como vereis, en este ejemplo que pongo el codigo html que mete es muy sencillito, pero aun asi necesario para verlo con más claridad y poder pulsar el enlace que crea. Y en otras páginas se meten imagenes, formatos de texto etc etc y claro, no es plan de que al usuario le llegue un chorizo de texto. Gracias por adelantado, salu2

[Shiryu_Libra]

no te podria servir esta PAGINA como ejemplo, angel??

suerte

[angel_dope]

Nop, aqui explica como usar el CDONTS, pero yo ahora uso CDOSYS, puesto que no consigo hacer funcionar cdonts en el nuevo servidor.

[Shiryu_Libra]

mmm... se me afigura que pudieras entonces usar este otro entonces

Código:

<%
response.Write "preparando para enviar<br/>"

dim obj
Set obj=Server.CreateObject("CDO.Message")

obj.From="[email protected]"
obj.To="[email protected]"

obj.Subject="Mas pruebas de correos mediante CDO del IIS"
obj.HtmlBody="prueba de envio"
obj.Send

set obj=nothing
response.Write "enviado..."

%>

pudieras intentarlo

suerte compañero

[angel_dope]

Gracias, no habia visto tu mensaje aun y esta mañana lo he encontrado buscando por ahi. Como has puesto en el código. Hay que cambiar Mailer2.TextBody por Mailer2.HtmlBody y ya está. Gracias