El siguiente código sirve para realizar una busqueda usando el catalogo generado por el Index Server.
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">
<title>Index Server Example Search Results Page</title>
</head>
<body>
<%
Dim sSearchString
Dim oQuery
sSearchString = Request.Form("query")
Const SEARCH_CATALOG = "catalog_name" 'tienes que cambiar esta linea
%>
<%
Set oQuery = Server.CreateObject("IXSSO.Query") 'este componente se puede usar solo tienes instalado el Index Server
oQuery.Catalog = SEARCH_CATALOG
oQuery.Query = "@all " & sSearchString & " AND NOT #path *_* AND NOT #path *downloads* AND NOT #path *images* AND NOT #filename *.class AND NOT #filename *.asa AND NOT #filename *.css AND NOT #filename *postinfo.html"
oQuery.MaxRecords = 200
oQuery.SortBy = "rank[d]"
oQuery.Columns = "DocAuthor, vpath, doctitle, FileName, Path, Write, Size, Rank, Create, Characterization, DocCategory"
Set oRS = oQuery.CreateRecordSet("nonsequential")
%>
<%
If oRS.EOF Then
Response.Write "No se encontrarón páginas para la búsqueda de <i>" & sSearchString & "</i>"
Else
Do While Not oRS.EOF
Response.write "<b>FileName:</b> " & oRS("FileName") & "<br>"
Response.write "<b>doctitle:</b> " & oRS("doctitle") & "<br>"
Response.write "<b>Size:</b> " & oRS("Size") & "<br>"
Response.write "<b>Create:</b> " & oRS("Create") & "<br>"
Response.write "<b>Write:</b> " & oRS("Write") & "<br>"
Response.write "<b>Characterization:</b> " & oRS("Characterization") & "<hr>"
oRS.MoveNext
Loop
End If
%>
<%
Set oRS = nothing
Set oQuery = nothing
%>
</body>
</html>
Cada servidor tiene un nombre para su catalogo generado por el Index Server. Para saber el nombre de tu catalogo debes usar la consola administrativa del Index Server para encontrar el nombre exacto.
Al tener ese nombre de catalogo, edita este código y cambia el valor de la constante 'SEARCH_CATALOG'.
