[SOLUCIONADO] Error al enviar mails con CDO.Message

[neofilo]

Hola a todos, tengo contratado con 1&1 un dominio y una dirección de email, quiero enviar un email desde ASP pero me da error.

CDO.Message.1 error '80040220'

No es válido el valor de configuración "SendUsing".

/registro-usuario2.asp, línea 134



estoy usando este codigo

Código:

Dim objMail 
Set objMail = Server.CreateObject("CDO.Message") 
Set objConfig = Server.CreateObject("CDO.Configuration") 
schema = "http://schemas.microsoft.com/cdo/configuration/"



'Configuracion: 

objConfig.Fields(schema & "cdoSendUsingMethod") = cdoSendUsingPort



objConfig.Fields(schema & "cdoSMTPServer" )="smtp.1and1.es" 

objConfig.Fields(schema & "cdoSMTPServerPort" )=25 

objConfig.Fields(schema & "cdoSMTPAuthenticate")=cdoBasic 

objConfig.Fields(schema & "cdoSendUserName") = "[email protected]"

objConfig.Fields(schema & "cdoSendPassword") = "xxxxxxxx"



'Update configuration 

objConfig.Fields.Update 

Set objMail.Configuration = objConfig 



objMail.From =" [email protected] " 

objMail.To = "[email protected]" 

objMail.Subject ="Información" 

objMail.TextBody="Ejemplo de CDO.message" 

objMail.Send 



If Err.Number = 0 Then

  Response.Write("Mail enviado")

Else

  Response.Write("Error enviado mail. Coigo: " & Err.Number)

  Err.Clear

End If

Set objMail=Nothing 

Set objConfig=Nothing

el error está en esta linea objMail.Send

me estoy desesperando, a ver si alguien me puede echar una mano.

Por cierto, uso IIS7 como servidor Web por si sirve de informacion.

[neofilo]

Me respondo a mi Mismo:

Lo he conseguido de la siguiente forma:

Código:

Dim ObjSendMail
Set ObjSendMail = CreateObject("CDO.Message")

'This section provides the configuration information for the remote SMTP server.

ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 'Send the message using the network (SMTP over the network).
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") ="smtp.1and1.es"
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False 'Use SSL for the connection (True or False)
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

' If your server requires outgoing authentication uncomment the lines bleow and use a valid email address and password.
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 'basic (clear-text) authentication
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") ="[email protected]"
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") ="XXXXXXX."

ObjSendMail.Configuration.Fields.Update

'End remote SMTP server configuration section==

ObjSendMail.To = "[email protected]"
ObjSendMail.Subject = "Asunto"
ObjSendMail.From = "Procede de <[email protected]>"


'ObjSendMail.HTMLBody = "this is the body"
ObjSendMail.TextBody = "Este es el cuerpo del mensaje"

ObjSendMail.Send

Set ObjSendMail = Nothing

[frealpema]

la solución de neofilo es correcta.... gracias!!!!,

ademas esta configuración la aplique, en una red con proxy

así que ya pueden imaginarse

que en estas lineas

ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") ="***.***.***.***" 'ip del proxy
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = **** ' puerto por donde escucha las solicitudes del smtp

es valido aclarar que la configuracion del proxy el direccionamiento esta de la siguiente manera manera, el proxy recibe la solicitud por el puerto configurado en él, por ejemplo

192.168.1.254 4425

y luego esa solicitud la direcciona al servidor de correos en internet mail.miempresa.com 25

y listo funciona de maravilla


pregunta hay alguna manera de bajar esas librerias, para no depender de microsoft ??

http://schemas.microsoft.com/cdo/configuration

es cierto esta configuración, necesariamente necesita internet por lo del envio del mail, pero que pasara cuando pase el tiempo y mas adelante estas librerias no esten disponibles...

ahiiii siiiiiiii nadaremos.... jejeje

gracias!!!