Comparaciones con CInt()

[PosProdukcion]

Hola, me ocurre a veces que comparaciones que hasta ahora estaban funcionando bien, por ejemplo, If var1 = var2 Then...., de repente, me dan False, y estoy obligado a poner If CInt(var1) = CInt(var2) Then.....

Lo más raro es que algunas que otros días funcionaban ok, ahora me fallan, ¿por qué ocurre esto si se que contienen los mismos valores? El problema es que no siempre puedo poner CInt() porque son variables que según desde donde se llame pueden contener tipos distintos

Gracias

[Myakire]

Podrías usar una función genérica. Aquí te pongo algo rápido:

Código:

<%
Function SonIguales(A,B)
   If VarType(A) <> VarType(B) Then
      SonIguales = False
   Else
      Select Case VarType(A)
        Case 0,1       
	     SonIguales = True                   'Empty, Null
	Case 2,3,4,5,6 
	     SonIguales = CDbl(A)=CDbl(B)        'Numericos
	Case 7
	     SonIguales = CDate(A) = CDate(B)    'Fechas
	Case 8 
	     SonIguales = CStr(A) = CStr(B)      'String
	Case 11 
	     SonIguales = CBool(A) = CBool(B)    'Boolean
	End Select
   End If
End Function

Response.Write SonIGuales(5,5) & "<br>" 
Response.Write SonIGuales(5.65,5.65) & "<br>" 
Response.Write SonIGuales(Date,Date) & "<br>" 
Response.Write SonIGuales("5","5") & "<br>" 
Response.Write SonIGuales(true,true) & "<br>" 

Response.Write SonIGuales(5,6) & "<br>" 
Response.Write SonIGuales(5.65,5.5) & "<br>" 
Response.Write SonIGuales(Date,Time) & "<br>" 
Response.Write SonIGuales("5",6) & "<br>" 
Response.Write SonIGuales(true,false) & "<br>" 
%>

[PosProdukcion]

Muchas gracias, me sirvió, pero con una modificación:

Código:

        If EsNulo(A) and EsNulo(B) Then
            Iguales = True
        ElseIf EsNulo(A) or EsNulo(B) Then
            Iguales = False
        ElseIf VarType(A) <> VarType(B) Then
            Iguales = CStr(A) = CStr(B) 

No se por qué, a veces los valores enteros leidos de BD los toma como String, y al comparar un entero con un string me da False...

Lo mas raro es que comparaciones que antes daban ok ahora me dan mal resultado!!

Gracias por tu ayuda